From: Luca Boccassi <bluca@debian.org>
Date: Tue, 18 Sep 2018 14:58:14 +0000 (+0100)
Subject: net/tap: add in meson build
X-Git-Url: http://git.droids-corp.org/?a=commitdiff_plain;h=095cae366804c0a6c420c383c7e34983d2793708;p=dpdk.git

net/tap: add in meson build

Use same autoconf generation mechanism as the MLX4/5 PMDs

Signed-off-by: Luca Boccassi <bluca@debian.org>
---

diff --git a/drivers/net/meson.build b/drivers/net/meson.build
index 9c28ed4da4..499949ca6a 100644
--- a/drivers/net/meson.build
+++ b/drivers/net/meson.build
@@ -25,6 +25,7 @@ drivers = ['af_packet',
 	'sfc',
 	'softnic',
 	'szedata2',
+	'tap',
 	'thunderx',
 	'vhost',
 	'virtio']
diff --git a/drivers/net/tap/meson.build b/drivers/net/tap/meson.build
new file mode 100644
index 0000000000..37f65b75c2
--- /dev/null
+++ b/drivers/net/tap/meson.build
@@ -0,0 +1,41 @@
+# SPDX-License-Identifier: BSD-3-Clause
+# Copyright 2018 Luca Boccassi <bluca@debian.org>
+
+sources = files(
+	'rte_eth_tap.c',
+	'tap_bpf_api.c',
+	'tap_flow.c',
+	'tap_intr.c',
+	'tap_netlink.c',
+	'tap_tcmsgs.c',
+)
+
+deps = ['bus_vdev', 'gso', 'hash']
+
+cflags += '-DTAP_MAX_QUEUES=16'
+
+# To maintain the compatibility with the make build system
+# tap_autoconf.h file is still generated.
+# input array for meson symbol search:
+# [ "MACRO to define if found", "header for the search",
+#   "enum/define", "symbol to search" ]
+#
+args = [
+	[ 'HAVE_TC_FLOWER', 'linux/pkt_cls.h',
+	  'TCA_FLOWER_UNSPEC' ],
+	[ 'HAVE_TC_VLAN_ID', 'linux/pkt_cls.h',
+	  'TCA_FLOWER_KEY_VLAN_PRIO' ],
+	[ 'HAVE_TC_BPF', 'linux/pkt_cls.h',
+	  'TCA_BPF_UNSPEC' ],
+	[ 'HAVE_TC_BPF_FD', 'linux/pkt_cls.h',
+	  'TCA_BPF_FD' ],
+	[ 'HAVE_TC_ACT_BPF', 'linux/tc_act/tc_bpf.h',
+	  'TCA_ACT_BPF_UNSPEC' ],
+	[ 'HAVE_TC_ACT_BPF_FD', 'linux/tc_act/tc_bpf.h',
+	  'TCA_ACT_BPF_FD' ],
+]
+config = configuration_data()
+foreach arg:args
+	config.set(arg[0], cc.has_header_symbol(arg[1], arg[2]))
+endforeach
+configure_file(output : 'tap_autoconf.h', configuration : config)