config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4 # Copyright(c) 2021 PANTHEON.tech s.r.o.
   5
   6 # common flags to all aarch64 builds, with lowest priority
   7 flags_common = [
   8         # Accelerate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
   9         # to determine the best threshold in code. Refer to notes in source file
  10         # (lib/eal/arm/include/rte_memcpy_64.h) for more info.
  11         ['RTE_ARCH_ARM64_MEMCPY', false],
  12         #    ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  13         #    ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  14         # Leave below RTE_ARM64_MEMCPY_xxx options commented out,
  15         # unless there are strong reasons.
  16         #    ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  17         #    ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  18         #    ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  19
  20         ['RTE_SCHED_VECTOR', false],
  21         ['RTE_ARM_USE_WFE', false],
  22         ['RTE_ARCH_ARM64', true],
  23         ['RTE_CACHE_LINE_SIZE', 128]
  24 ]
  25
  26 ## Part numbers are specific to Arm implementers
  27 # implementer specific aarch64 flags have middle priority
  28 #     (will overwrite common flags)
  29 # part number specific aarch64 flags have higher priority
  30 #     (will overwrite both common and implementer specific flags)
  31 implementer_generic = {
  32     'description': 'Generic armv8',
  33     'flags': [
  34         ['RTE_MACHINE', '"armv8a"'],
  35         ['RTE_USE_C11_MEM_MODEL', true],
  36         ['RTE_MAX_LCORE', 256],
  37         ['RTE_MAX_NUMA_NODES', 4]
  38     ],
  39     'part_number_config': {
  40         'generic': {'machine_args': ['-march=armv8-a+crc', '-moutline-atomics']}
  41     }
  42 }
  43
  44 part_number_config_arm = {
  45     '0xd03': {'machine_args':  ['-mcpu=cortex-a53']},
  46     '0xd04': {'machine_args':  ['-mcpu=cortex-a35']},
  47     '0xd07': {'machine_args':  ['-mcpu=cortex-a57']},
  48     '0xd08': {'machine_args':  ['-mcpu=cortex-a72']},
  49     '0xd09': {'machine_args':  ['-mcpu=cortex-a73']},
  50     '0xd0a': {'machine_args':  ['-mcpu=cortex-a75']},
  51     '0xd0b': {'machine_args':  ['-mcpu=cortex-a76']},
  52     '0xd0c': {
  53         'machine_args':  ['-march=armv8.2-a+crypto', '-mcpu=neoverse-n1'],
  54         'flags': [
  55             ['RTE_MACHINE', '"neoverse-n1"'],
  56             ['RTE_ARM_FEATURE_ATOMICS', true],
  57             ['RTE_MAX_MEM_MB', 1048576],
  58             ['RTE_MAX_LCORE', 160],
  59             ['RTE_MAX_NUMA_NODES', 2]
  60         ]
  61     },
  62     '0xd49': {
  63         'machine_args':  ['-march=armv8.5-a+crypto+sve2'],
  64         'flags': [
  65             ['RTE_MACHINE', '"neoverse-n2"'],
  66             ['RTE_ARM_FEATURE_ATOMICS', true],
  67             ['RTE_MAX_LCORE', 64],
  68             ['RTE_MAX_NUMA_NODES', 1]
  69         ]
  70     }
  71 }
  72 implementer_arm = {
  73     'description': 'Arm',
  74     'flags': [
  75         ['RTE_MACHINE', '"armv8a"'],
  76         ['RTE_USE_C11_MEM_MODEL', true],
  77         ['RTE_CACHE_LINE_SIZE', 64],
  78         ['RTE_MAX_LCORE', 64],
  79         ['RTE_MAX_NUMA_NODES', 4]
  80     ],
  81     'part_number_config': part_number_config_arm
  82 }
  83
  84 flags_part_number_thunderx = [
  85     ['RTE_MACHINE', '"thunderx"'],
  86     ['RTE_USE_C11_MEM_MODEL', false]
  87 ]
  88 implementer_cavium = {
  89     'description': 'Cavium',
  90     'flags': [
  91         ['RTE_MAX_VFIO_GROUPS', 128],
  92         ['RTE_MAX_LCORE', 96],
  93         ['RTE_MAX_NUMA_NODES', 2]
  94     ],
  95     'part_number_config': {
  96         '0xa1': {
  97             'machine_args': ['-mcpu=thunderxt88'],
  98             'flags': flags_part_number_thunderx
  99         },
 100         '0xa2': {
 101             'machine_args': ['-mcpu=thunderxt81'],
 102             'flags': flags_part_number_thunderx
 103         },
 104         '0xa3': {
 105             'machine_args': ['-mcpu=thunderxt83'],
 106             'flags': flags_part_number_thunderx
 107         },
 108         '0xaf': {
 109             'machine_args': ['-march=armv8.1-a+crc+crypto', '-mcpu=thunderx2t99'],
 110             'flags': [
 111                 ['RTE_MACHINE', '"thunderx2"'],
 112                 ['RTE_ARM_FEATURE_ATOMICS', true],
 113                 ['RTE_USE_C11_MEM_MODEL', true],
 114                 ['RTE_CACHE_LINE_SIZE', 64],
 115                 ['RTE_MAX_LCORE', 256]
 116             ]
 117         },
 118         '0xb2': {
 119             'machine_args': ['-march=armv8.2-a+crc+crypto+lse', '-mcpu=octeontx2'],
 120             'flags': [
 121                 ['RTE_MACHINE', '"octeontx2"'],
 122                 ['RTE_ARM_FEATURE_ATOMICS', true],
 123                 ['RTE_USE_C11_MEM_MODEL', true],
 124                 ['RTE_MAX_LCORE', 36],
 125                 ['RTE_MAX_NUMA_NODES', 1]
 126             ]
 127         }
 128     }
 129 }
 130
 131 implementer_ampere = {
 132     'description': 'Ampere Computing',
 133     'flags': [
 134         ['RTE_MACHINE', '"emag"'],
 135         ['RTE_CACHE_LINE_SIZE', 64],
 136         ['RTE_MAX_LCORE', 32],
 137         ['RTE_MAX_NUMA_NODES', 1]
 138     ],
 139     'part_number_config': {
 140         '0x0': {'machine_args':  ['-march=armv8-a+crc+crypto', '-mtune=emag']}
 141     }
 142 }
 143
 144 implementer_hisilicon = {
 145     'description': 'HiSilicon',
 146     'flags': [
 147         ['RTE_USE_C11_MEM_MODEL', true],
 148         ['RTE_CACHE_LINE_SIZE', 128]
 149     ],
 150     'part_number_config': {
 151         '0xd01': {
 152             'machine_args': ['-march=armv8.2-a+crypto', '-mtune=tsv110'],
 153             'flags': [
 154                 ['RTE_MACHINE', '"Kunpeng 920"'],
 155                 ['RTE_ARM_FEATURE_ATOMICS', true],
 156                 ['RTE_MAX_LCORE', 256],
 157                 ['RTE_MAX_NUMA_NODES', 8]
 158             ]
 159         },
 160         '0xd02': {
 161             'machine_args': ['-march=armv8.2-a+crypto+sve'],
 162             'flags': [
 163                 ['RTE_MACHINE', '"Kunpeng 930"'],
 164                 ['RTE_ARM_FEATURE_ATOMICS', true],
 165                 ['RTE_MAX_LCORE', 1280],
 166                 ['RTE_MAX_NUMA_NODES', 16]
 167             ]
 168         }
 169     }
 170 }
 171
 172 implementer_qualcomm = {
 173     'description': 'Qualcomm',
 174     'flags': [
 175         ['RTE_MACHINE', '"armv8a"'],
 176         ['RTE_USE_C11_MEM_MODEL', true],
 177         ['RTE_CACHE_LINE_SIZE', 64],
 178         ['RTE_MAX_LCORE', 64],
 179         ['RTE_MAX_NUMA_NODES', 1]
 180     ],
 181     'part_number_config': {
 182         '0xc00': {'machine_args':  ['-march=armv8-a+crc']}
 183     }
 184 }
 185
 186 ## Arm implementers (ID from MIDR in Arm Architecture Reference Manual)
 187 implementers = {
 188     'generic': implementer_generic,
 189     '0x41': implementer_arm,
 190     '0x43': implementer_cavium,
 191     '0x48': implementer_hisilicon,
 192     '0x50': implementer_ampere,
 193     '0x51': implementer_qualcomm
 194 }
 195
 196 # SoC specific aarch64 flags have the highest priority
 197 #     (will overwrite all other flags)
 198 soc_generic = {
 199     'description': 'Generic un-optimized build for all aarch64 machines',
 200     'implementer': 'generic',
 201     'part_number': 'generic'
 202 }
 203
 204 soc_armada = {
 205     'description': 'Marvell ARMADA',
 206     'implementer': '0x41',
 207     'part_number': '0xd08',
 208     'flags': [
 209         ['RTE_MAX_LCORE', 16],
 210         ['RTE_MAX_NUMA_NODES', 1]
 211     ],
 212     'numa': false
 213 }
 214
 215 soc_bluefield = {
 216     'description': 'NVIDIA BlueField',
 217     'implementer': '0x41',
 218     'part_number': '0xd08',
 219     'flags': [
 220         ['RTE_MAX_LCORE', 16],
 221         ['RTE_MAX_NUMA_NODES', 1]
 222     ],
 223     'numa': false
 224 }
 225
 226 soc_cn10k = {
 227     'description' : 'Marvell OCTEON 10',
 228     'implementer' : '0x41',
 229     'flags': [
 230         ['RTE_MAX_LCORE', 24],
 231         ['RTE_MAX_NUMA_NODES', 1]
 232     ],
 233     'part_number': '0xd49',
 234     'numa': false
 235 }
 236
 237 soc_dpaa = {
 238     'description': 'NXP DPAA',
 239     'implementer': '0x41',
 240     'part_number': '0xd08',
 241     'flags': [
 242         ['RTE_MACHINE', '"dpaa"'],
 243         ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false],
 244         ['RTE_MAX_LCORE', 16],
 245         ['RTE_MAX_NUMA_NODES', 1]
 246     ],
 247     'numa': false
 248 }
 249
 250 soc_emag = {
 251     'description': 'Ampere eMAG',
 252     'implementer': '0x50',
 253     'part_number': '0x0'
 254 }
 255
 256 soc_graviton2 = {
 257     'description': 'AWS Graviton2',
 258     'implementer': '0x41',
 259     'part_number': '0xd0c',
 260     'numa': false
 261 }
 262
 263 soc_kunpeng920 = {
 264     'description': 'HiSilicon Kunpeng 920',
 265     'implementer': '0x48',
 266     'part_number': '0xd01',
 267     'numa': true
 268 }
 269
 270 soc_kunpeng930 = {
 271     'description': 'HiSilicon Kunpeng 930',
 272     'implementer': '0x48',
 273     'part_number': '0xd02',
 274     'numa': true
 275 }
 276
 277 soc_n1sdp = {
 278     'description': 'Arm Neoverse N1SDP',
 279     'implementer': '0x41',
 280     'part_number': '0xd0c',
 281     'flags': [
 282         ['RTE_MAX_LCORE', 4]
 283     ],
 284     'numa': false
 285 }
 286
 287 soc_n2 = {
 288     'description': 'Arm Neoverse N2',
 289     'implementer': '0x41',
 290     'part_number': '0xd49',
 291     'numa': false
 292 }
 293
 294 soc_octeontx2 = {
 295     'description': 'Marvell OCTEON TX2',
 296     'implementer': '0x43',
 297     'part_number': '0xb2',
 298     'numa': false
 299 }
 300
 301 soc_stingray = {
 302     'description': 'Broadcom Stingray',
 303     'implementer': '0x41',
 304     'flags': [
 305         ['RTE_MAX_LCORE', 16],
 306         ['RTE_MAX_NUMA_NODES', 1]
 307     ],
 308     'part_number': '0xd08',
 309     'numa': false
 310 }
 311
 312 soc_thunderx2 = {
 313     'description': 'Marvell ThunderX2 T99',
 314     'implementer': '0x43',
 315     'part_number': '0xaf'
 316 }
 317
 318 soc_thunderxt88 = {
 319     'description': 'Marvell ThunderX T88',
 320     'implementer': '0x43',
 321     'part_number': '0xa1'
 322 }
 323
 324 '''
 325 Start of SoCs list
 326 generic:     Generic un-optimized build for all aarch64 machines.
 327 armada:      Marvell ARMADA
 328 bluefield:   NVIDIA BlueField
 329 cn10k:       Marvell OCTEON 10
 330 dpaa:        NXP DPAA
 331 emag:        Ampere eMAG
 332 graviton2:   AWS Graviton2
 333 kunpeng920:  HiSilicon Kunpeng 920
 334 kunpeng930:  HiSilicon Kunpeng 930
 335 n1sdp:       Arm Neoverse N1SDP
 336 n2:          Arm Neoverse N2
 337 octeontx2:   Marvell OCTEON TX2
 338 stingray:    Broadcom Stingray
 339 thunderx2:   Marvell ThunderX2 T99
 340 thunderxt88: Marvell ThunderX T88
 341 End of SoCs list
 342 '''
 343 # The string above is included in the documentation, keep it in sync with the
 344 # SoCs list below.
 345 socs = {
 346     'generic': soc_generic,
 347     'armada': soc_armada,
 348     'bluefield': soc_bluefield,
 349     'cn10k' : soc_cn10k,
 350     'dpaa': soc_dpaa,
 351     'emag': soc_emag,
 352     'graviton2': soc_graviton2,
 353     'kunpeng920': soc_kunpeng920,
 354     'kunpeng930': soc_kunpeng930,
 355     'n1sdp': soc_n1sdp,
 356     'n2': soc_n2,
 357     'octeontx2': soc_octeontx2,
 358     'stingray': soc_stingray,
 359     'thunderx2': soc_thunderx2,
 360     'thunderxt88': soc_thunderxt88
 361 }
 362
 363 dpdk_conf.set('RTE_ARCH_ARM', 1)
 364 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 365
 366 if dpdk_conf.get('RTE_ARCH_32')
 367     # armv7 build
 368     dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 369     dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 370     # the minimum architecture supported, armv7-a, needs the following,
 371     machine_args += '-mfpu=neon'
 372 else
 373     # aarch64 build
 374     soc = get_option('platform')
 375     soc_config = {}
 376     if not meson.is_cross_build()
 377         if machine == 'generic'
 378             # generic build
 379             if soc != ''
 380                 error('Building for a particular platform is unsupported with generic build.')
 381             endif
 382             implementer_id = 'generic'
 383             part_number = 'generic'
 384         elif soc != ''
 385             soc_config = socs.get(soc, {'not_supported': true})
 386         else
 387             # native build
 388             # The script returns ['Implementer', 'Variant', 'Architecture',
 389             # 'Primary Part number', 'Revision']
 390             detect_vendor = find_program(join_paths(meson.current_source_dir(),
 391                                                     'armv8_machine.py'))
 392             cmd = run_command(detect_vendor.path())
 393             if cmd.returncode() == 0
 394                 cmd_output = cmd.stdout().to_lower().strip().split(' ')
 395                 implementer_id = cmd_output[0]
 396                 part_number = cmd_output[3]
 397             else
 398                 error('Error when getting Arm Implementer ID and part number.')
 399             endif
 400         endif
 401     else
 402         # cross build
 403         soc = meson.get_cross_property('platform', '')
 404         if soc == ''
 405             error('Arm SoC must be specified in the cross file.')
 406         endif
 407         soc_config = socs.get(soc, {'not_supported': true})
 408     endif
 409
 410     soc_flags = []
 411     if soc_config.has_key('not_supported')
 412         error('SoC @0@ not supported.'.format(soc))
 413     elif soc_config != {}
 414         implementer_id = soc_config['implementer']
 415         implementer_config = implementers[implementer_id]
 416         part_number = soc_config['part_number']
 417         soc_flags = soc_config.get('flags', [])
 418         if not soc_config.get('numa', true)
 419             has_libnuma = 0
 420         endif
 421
 422         disable_drivers += ',' + soc_config.get('disable_drivers', '')
 423         enable_drivers += ',' + soc_config.get('enable_drivers', '')
 424     endif
 425
 426     if implementers.has_key(implementer_id)
 427         implementer_config = implementers[implementer_id]
 428     else
 429         error('Unsupported Arm implementer: @0@. '.format(implementer_id) +
 430               'Please add support for it or use the generic ' +
 431               '(-Dmachine=generic) build.')
 432     endif
 433
 434     message('Arm implementer: ' + implementer_config['description'])
 435     message('Arm part number: ' + part_number)
 436
 437     part_number_config = implementer_config['part_number_config']
 438     if part_number_config.has_key(part_number)
 439         # use the specified part_number machine args if found
 440         part_number_config = part_number_config[part_number]
 441     else
 442         # unknown part number
 443         error('Unsupported part number @0@ of implementer @1@. '
 444               .format(part_number, implementer_id) +
 445               'Please add support for it or use the generic ' +
 446               '(-Dmachine=generic) build.')
 447     endif
 448
 449     # add/overwrite flags in the proper order
 450     dpdk_flags = flags_common + implementer_config['flags'] + part_number_config.get('flags', []) + soc_flags
 451
 452     # apply supported machine args
 453     machine_args = [] # Clear previous machine args
 454     foreach flag: part_number_config['machine_args']
 455         if cc.has_argument(flag)
 456             machine_args += flag
 457         endif
 458     endforeach
 459
 460     # apply flags
 461     foreach flag: dpdk_flags
 462         if flag.length() > 0
 463             dpdk_conf.set(flag[0], flag[1])
 464         endif
 465     endforeach
 466 endif
 467 message('Using machine args: @0@'.format(machine_args))
 468
 469 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 470     cc.get_define('__aarch64__', args: machine_args) != '')
 471     compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 472 endif
 473
 474 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 475     compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 476 endif
 477
 478 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 479     compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 480     'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 481 endif