config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # for checking defines we need to use the correct compiler flags
   6 march_opt = '-march=@0@'.format(machine)
   7
   8 arm_force_native_march = false
   9 arm_force_default_march = (machine == 'default')
  10
  11 flags_common_default = [
  12         # Accelarate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
  13         # to determine the best threshold in code. Refer to notes in source file
  14         # (lib/librte_eal/common/include/arch/arm/rte_memcpy_64.h) for more info.
  15         ['RTE_ARCH_ARM64_MEMCPY', false],
  16         #       ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  17         #       ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  18         # Leave below RTE_ARM64_MEMCPY_xxx options commented out, unless there're
  19         # strong reasons.
  20         #       ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  21         #       ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  22         #       ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  23
  24         ['RTE_LIBRTE_FM10K_PMD', false],
  25         ['RTE_LIBRTE_SFC_EFX_PMD', false],
  26         ['RTE_LIBRTE_AVP_PMD', false],
  27
  28         ['RTE_SCHED_VECTOR', false],
  29 ]
  30
  31 flags_generic = [
  32         ['RTE_MACHINE', '"armv8a"'],
  33         ['RTE_MAX_LCORE', 256],
  34         ['RTE_USE_C11_MEM_MODEL', true],
  35         ['RTE_CACHE_LINE_SIZE', 128]]
  36 flags_arm = [
  37         ['RTE_MACHINE', '"armv8a"'],
  38         ['RTE_MAX_LCORE', 16],
  39         ['RTE_USE_C11_MEM_MODEL', true],
  40         ['RTE_CACHE_LINE_SIZE', 64]]
  41 flags_cavium = [
  42         ['RTE_CACHE_LINE_SIZE', 128],
  43         ['RTE_MAX_NUMA_NODES', 2],
  44         ['RTE_MAX_LCORE', 96],
  45         ['RTE_MAX_VFIO_GROUPS', 128]]
  46 flags_dpaa = [
  47         ['RTE_MACHINE', '"dpaa"'],
  48         ['RTE_USE_C11_MEM_MODEL', true],
  49         ['RTE_CACHE_LINE_SIZE', 64],
  50         ['RTE_MAX_NUMA_NODES', 1],
  51         ['RTE_MAX_LCORE', 16]]
  52 flags_dpaa2 = [
  53         ['RTE_MACHINE', '"dpaa2"'],
  54         ['RTE_USE_C11_MEM_MODEL', true],
  55         ['RTE_CACHE_LINE_SIZE', 64],
  56         ['RTE_MAX_NUMA_NODES', 1],
  57         ['RTE_MAX_LCORE', 16],
  58         ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false]]
  59 flags_default_extra = []
  60 flags_thunderx_extra = [
  61         ['RTE_MACHINE', '"thunderx"'],
  62         ['RTE_USE_C11_MEM_MODEL', false]]
  63 flags_thunderx2_extra = [
  64         ['RTE_MACHINE', '"thunderx2"'],
  65         ['RTE_CACHE_LINE_SIZE', 64],
  66         ['RTE_MAX_NUMA_NODES', 2],
  67         ['RTE_MAX_LCORE', 256],
  68         ['RTE_USE_C11_MEM_MODEL', true]]
  69 flags_octeontx2_extra = [
  70         ['RTE_MACHINE', '"octeontx2"'],
  71         ['RTE_MAX_NUMA_NODES', 1],
  72         ['RTE_MAX_LCORE', 24],
  73         ['RTE_EAL_IGB_UIO', false],
  74         ['RTE_USE_C11_MEM_MODEL', true]]
  75
  76 machine_args_generic = [
  77         ['default', ['-march=armv8-a+crc+crypto']],
  78         ['native', ['-march=native']],
  79         ['0xd03', ['-mcpu=cortex-a53']],
  80         ['0xd04', ['-mcpu=cortex-a35']],
  81         ['0xd07', ['-mcpu=cortex-a57']],
  82         ['0xd08', ['-mcpu=cortex-a72']],
  83         ['0xd09', ['-mcpu=cortex-a73']],
  84         ['0xd0a', ['-mcpu=cortex-a75']]]
  85
  86 machine_args_cavium = [
  87         ['default', ['-march=armv8-a+crc+crypto','-mcpu=thunderx']],
  88         ['native', ['-march=native']],
  89         ['0xa1', ['-mcpu=thunderxt88'], flags_thunderx_extra],
  90         ['0xa2', ['-mcpu=thunderxt81'], flags_thunderx_extra],
  91         ['0xa3', ['-mcpu=thunderxt83'], flags_thunderx_extra],
  92         ['0xaf', ['-mcpu=thunderx2t99'], flags_thunderx2_extra],
  93         ['0xb2', ['-mcpu=octeontx2'], flags_octeontx2_extra]]
  94
  95 ## Arm implementer ID (ARM DDI 0487C.a, Section G7.2.106, Page G7-5321)
  96 impl_generic = ['Generic armv8', flags_generic, machine_args_generic]
  97 impl_0x41 = ['Arm', flags_arm, machine_args_generic]
  98 impl_0x42 = ['Broadcom', flags_generic, machine_args_generic]
  99 impl_0x43 = ['Cavium', flags_cavium, machine_args_cavium]
 100 impl_0x44 = ['DEC', flags_generic, machine_args_generic]
 101 impl_0x49 = ['Infineon', flags_generic, machine_args_generic]
 102 impl_0x4d = ['Motorola', flags_generic, machine_args_generic]
 103 impl_0x4e = ['NVIDIA', flags_generic, machine_args_generic]
 104 impl_0x50 = ['AppliedMicro', flags_generic, machine_args_generic]
 105 impl_0x51 = ['Qualcomm', flags_generic, machine_args_generic]
 106 impl_0x53 = ['Samsung', flags_generic, machine_args_generic]
 107 impl_0x56 = ['Marvell', flags_generic, machine_args_generic]
 108 impl_0x69 = ['Intel', flags_generic, machine_args_generic]
 109 impl_dpaa = ['NXP DPAA', flags_dpaa, machine_args_generic]
 110 impl_dpaa2 = ['NXP DPAA2', flags_dpaa2, machine_args_generic]
 111
 112 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 113
 114 if not dpdk_conf.get('RTE_ARCH_64')
 115         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 116         dpdk_conf.set('RTE_ARCH_ARM', 1)
 117         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 118         # the minimum architecture supported, armv7-a, needs the following,
 119         # mk/machine/armv7a/rte.vars.mk sets it too
 120         machine_args += '-mfpu=neon'
 121 else
 122         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)
 123         dpdk_conf.set('RTE_ARCH_ARM64', 1)
 124
 125         machine = []
 126         cmd_generic = ['generic', '', '', 'default', '']
 127         cmd_output = cmd_generic # Set generic by default
 128         machine_args = [] # Clear previous machine args
 129         if arm_force_default_march and not meson.is_cross_build()
 130                 machine = impl_generic
 131                 impl_pn = 'default'
 132         elif not meson.is_cross_build()
 133                 # The script returns ['Implementer', 'Variant', 'Architecture',
 134                 # 'Primary Part number', 'Revision']
 135                 detect_vendor = find_program(join_paths(
 136                                 meson.current_source_dir(), 'armv8_machine.py'))
 137                 cmd = run_command(detect_vendor.path())
 138                 if cmd.returncode() == 0
 139                         cmd_output = cmd.stdout().to_lower().strip().split(' ')
 140                 endif
 141                 # Set to generic if variable is not found
 142                 machine = get_variable('impl_' + cmd_output[0], ['generic'])
 143                 if machine[0] == 'generic'
 144                         machine = impl_generic
 145                         cmd_output = cmd_generic
 146                 endif
 147                 impl_pn = cmd_output[3]
 148                 if arm_force_native_march == true
 149                         impl_pn = 'native'
 150                 endif
 151         else
 152                 impl_id = meson.get_cross_property('implementor_id', 'generic')
 153                 impl_pn = meson.get_cross_property('implementor_pn', 'default')
 154                 machine = get_variable('impl_' + impl_id)
 155         endif
 156
 157         # Apply Common Defaults. These settings may be overwritten by machine
 158         # settings later.
 159         foreach flag: flags_common_default
 160                 if flag.length() > 0
 161                         dpdk_conf.set(flag[0], flag[1])
 162                 endif
 163         endforeach
 164
 165         message('Implementer : ' + machine[0])
 166         foreach flag: machine[1]
 167                 if flag.length() > 0
 168                         dpdk_conf.set(flag[0], flag[1])
 169                 endif
 170         endforeach
 171
 172         foreach marg: machine[2]
 173                 if marg[0] == impl_pn
 174                         foreach flag: marg[1]
 175                                 if cc.has_argument(flag)
 176                                         machine_args += flag
 177                                 endif
 178                         endforeach
 179                         # Apply any extra machine specific flags.
 180                         foreach flag: marg.get(2, flags_default_extra)
 181                                 if flag.length() > 0
 182                                         dpdk_conf.set(flag[0], flag[1])
 183                                 endif
 184                         endforeach
 185                 endif
 186         endforeach
 187 endif
 188 message(machine_args)
 189
 190 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 191     cc.get_define('__aarch64__', args: machine_args) != '')
 192         dpdk_conf.set('RTE_MACHINE_CPUFLAG_NEON', 1)
 193         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 194 endif
 195
 196 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 197         dpdk_conf.set('RTE_MACHINE_CPUFLAG_CRC32', 1)
 198         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 199 endif
 200
 201 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 202         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
 203         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PMULL', 1)
 204         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA1', 1)
 205         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA2', 1)
 206         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 207         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 208 endif