config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 so_version = abi_version.split('.')[0]
  33
  34 # extract all version information into the build configuration
  35 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  36 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  37 if pver.get(2).contains('-rc')
  38         rc_ver = pver.get(2).split('-rc')
  39         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  40         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  41         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  42 else
  43         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  44         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  45 # for actual, non-rc releases, set the release value to 99 to ensure releases
  46 # have higher version numbers than their respective release candidates
  47         dpdk_conf.set('RTE_VER_RELEASE', 99)
  48 endif
  49
  50 pmd_subdir_opt = get_option('drivers_install_subdir')
  51 if pmd_subdir_opt.contains('<VERSION>')
  52         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  53 endif
  54 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  55 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  56
  57 # driver .so files often depend upon the bus drivers for their connect bus,
  58 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  59 # to be in the library path, so symlink the drivers from the main lib directory.
  60 if not is_windows
  61         meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  62                         get_option('libdir'),
  63                         pmd_subdir_opt)
  64 endif
  65
  66 # set the machine type and cflags for it
  67 if meson.is_cross_build()
  68         machine = host_machine.cpu()
  69 else
  70         machine = get_option('machine')
  71 endif
  72
  73 # machine type 'default' is special, it defaults to the per arch agreed common
  74 # minimal baseline needed for DPDK.
  75 # That might not be the most optimized, but the most portable version while
  76 # still being able to support the CPU features required for DPDK.
  77 # This can be bumped up by the DPDK project, but it can never be an
  78 # invariant like 'native'
  79 if machine == 'default'
  80         if host_machine.cpu_family().startswith('x86')
  81                 # matches the old pre-meson build systems default
  82                 machine = 'corei7'
  83         elif host_machine.cpu_family().startswith('arm')
  84                 machine = 'armv7-a'
  85         elif host_machine.cpu_family().startswith('aarch')
  86                 # arm64 manages defaults in config/arm/meson.build
  87                 machine = 'default'
  88         elif host_machine.cpu_family().startswith('ppc')
  89                 machine = 'power8'
  90         endif
  91 endif
  92
  93 dpdk_conf.set('RTE_MACHINE', machine)
  94 machine_args = []
  95
  96 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  97 if host_machine.cpu_family().startswith('ppc')
  98         machine_args += '-mcpu=' + machine
  99         machine_args += '-mtune=' + machine
 100 else
 101         machine_args += '-march=' + machine
 102 endif
 103
 104 toolchain = cc.get_id()
 105 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 106 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 107
 108 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 109 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 110
 111 if not is_windows
 112         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 113 endif
 114
 115 # use pthreads if available for the platform
 116 if not is_windows
 117         add_project_link_arguments('-pthread', language: 'c')
 118         dpdk_extra_ldflags += '-pthread'
 119 endif
 120
 121 # on some OS, maths functions are in a separate library
 122 if cc.find_library('m', required : false).found()
 123         # some libs depend on maths lib
 124         add_project_link_arguments('-lm', language: 'c')
 125         dpdk_extra_ldflags += '-lm'
 126 endif
 127
 128 if is_linux
 129         link_lib = 'dl'
 130 else
 131         link_lib = ''
 132 endif
 133
 134 # if link_lib is empty, do not add it to project properties
 135 if link_lib != ''
 136         add_project_link_arguments('-l' + link_lib, language: 'c')
 137         dpdk_extra_ldflags += '-l' + link_lib
 138 endif
 139
 140 # check for libraries used in multiple places in DPDK
 141 has_libnuma = 0
 142 find_libnuma = true
 143 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 144         # don't look for libnuma if explicitly disabled in cross build
 145         find_libnuma = false
 146 endif
 147 if find_libnuma
 148         numa_dep = cc.find_library('numa', required: false)
 149         if numa_dep.found() and cc.has_header('numaif.h')
 150                 dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 151                 has_libnuma = 1
 152                 add_project_link_arguments('-lnuma', language: 'c')
 153                 dpdk_extra_ldflags += '-lnuma'
 154         endif
 155 endif
 156
 157 has_libfdt = 0
 158 fdt_dep = cc.find_library('libfdt', required: false)
 159 if fdt_dep.found() and cc.has_header('fdt.h')
 160         dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 161         has_libfdt = 1
 162         add_project_link_arguments('-lfdt', language: 'c')
 163         dpdk_extra_ldflags += '-lfdt'
 164 endif
 165
 166 libexecinfo = cc.find_library('libexecinfo', required: false)
 167 if libexecinfo.found() and cc.has_header('execinfo.h')
 168         add_project_link_arguments('-lexecinfo', language: 'c')
 169         dpdk_extra_ldflags += '-lexecinfo'
 170 endif
 171
 172 # check for libbsd
 173 libbsd = dependency('libbsd', required: false, method: 'pkg-config')
 174 if libbsd.found()
 175         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 176 endif
 177
 178 # check for pcap
 179 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 180 if not pcap_dep.found()
 181         # pcap got a pkg-config file only in 1.9.0
 182         pcap_dep = cc.find_library('pcap', required: false)
 183 endif
 184 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 185         dpdk_conf.set('RTE_PORT_PCAP', 1)
 186         dpdk_extra_ldflags += '-lpcap'
 187 endif
 188
 189 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 190 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 191         atomic_dep = cc.find_library('atomic', required: true)
 192         add_project_link_arguments('-latomic', language: 'c')
 193         dpdk_extra_ldflags += '-latomic'
 194 endif
 195
 196 # add -include rte_config to cflags
 197 add_project_arguments('-include', 'rte_config.h', language: 'c')
 198
 199 # enable extra warnings and disable any unwanted warnings
 200 warning_flags = [
 201         # -Wall is added by meson by default, so add -Wextra only
 202         '-Wextra',
 203
 204         # additional warnings in alphabetical order
 205         '-Wcast-qual',
 206         '-Wdeprecated',
 207         '-Wformat',
 208         '-Wformat-nonliteral',
 209         '-Wformat-security',
 210         '-Wmissing-declarations',
 211         '-Wmissing-prototypes',
 212         '-Wnested-externs',
 213         '-Wold-style-definition',
 214         '-Wpointer-arith',
 215         '-Wsign-compare',
 216         '-Wstrict-prototypes',
 217         '-Wundef',
 218         '-Wwrite-strings',
 219
 220         # globally disabled warnings
 221         '-Wno-address-of-packed-member',
 222         '-Wno-packed-not-aligned',
 223         '-Wno-missing-field-initializers'
 224 ]
 225 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 226 # FIXME: Bugzilla 396
 227         warning_flags += '-Wno-zero-length-bounds'
 228 endif
 229 if not dpdk_conf.get('RTE_ARCH_64')
 230 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 231         warning_flags += '-Wno-pointer-to-int-cast'
 232 endif
 233 if cc.get_id() == 'intel'
 234         warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 235         foreach i:warning_ids
 236                 warning_flags += '-diag-disable=@0@'.format(i)
 237         endforeach
 238 endif
 239 foreach arg: warning_flags
 240         if cc.has_argument(arg)
 241                 add_project_arguments(arg, language: 'c')
 242         endif
 243 endforeach
 244
 245 # set other values pulled from the build options
 246 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 247 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 248 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 249 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 250 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 251 # values which have defaults which may be overridden
 252 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 253 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 254 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 255 if dpdk_conf.get('RTE_ARCH_64')
 256         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 257 else # for 32-bit we need smaller reserved memory areas
 258         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 259 endif
 260
 261
 262 compile_time_cpuflags = []
 263 subdir(arch_subdir)
 264 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 265
 266 # apply cross-specific options
 267 if meson.is_cross_build()
 268         # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 269         cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 270         if cross_max_lcores != 0
 271                 message('Setting RTE_MAX_LCORE from cross file')
 272                 dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 273         endif
 274         cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 275         if cross_max_numa_nodes != 0
 276                 message('Setting RTE_MAX_NUMA_NODES from cross file')
 277                 dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 278         endif
 279 endif
 280
 281 # set the install path for the drivers
 282 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 283
 284 install_headers(['rte_config.h'],
 285                 subdir: get_option('include_subdir_arch'))
 286
 287 # enable VFIO only if it is linux OS
 288 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 289
 290 # specify -D_GNU_SOURCE unconditionally
 291 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 292
 293 # specify -D__BSD_VISIBLE for FreeBSD
 294 if is_freebsd
 295         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 296 endif
 297
 298 if is_windows
 299         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 300         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 301
 302         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 303         if cc.get_id() == 'gcc'
 304                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 305         endif
 306
 307         # Disable secure CRT deprecated warnings for clang
 308         if cc.get_id() == 'clang'
 309                 add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 310         endif
 311
 312         add_project_link_arguments('-lws2_32', language: 'c')
 313
 314         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 315         # in Windows SDK, while MinGW exports it by advapi32.a.
 316         if is_ms_linker
 317                 add_project_link_arguments('-lmincore', language: 'c')
 318         endif
 319
 320         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 321         add_project_link_arguments('-ldbghelp', language: 'c')
 322 endif
 323
 324 if get_option('b_lto')
 325         if cc.has_argument('-ffat-lto-objects')
 326                 add_project_arguments('-ffat-lto-objects', language: 'c')
 327         else
 328                 error('compiler does not support fat LTO objects - please turn LTO off')
 329         endif
 330         # workaround for gcc bug 81440
 331         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 332                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 333                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 334         endif
 335 endif
 336
 337 if get_option('default_library') == 'both'
 338         error( '''
 339     Unsupported value "both" for "default_library" option.
 340
 341     NOTE: DPDK always builds both shared and static libraries.  Please set
 342     "default_library" to either "static" or "shared" to select default linkage
 343     for apps and any examples.''')
 344 endif