config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8     error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14     set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'), abi_version_file).stdout().strip()
  26
  27 # Libraries have the abi_version as the filename extension
  28 # and have the soname be all but the final part of the abi_version.
  29 # e.g. v20.1 => librte_foo.so.20.1
  30 #    sonames => librte_foo.so.20
  31 so_version = abi_version.split('.')[0]
  32
  33 # extract all version information into the build configuration
  34 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  35 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  36 if pver.get(2).contains('-rc')
  37     rc_ver = pver.get(2).split('-rc')
  38     dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  39     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  40     dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  41 else
  42     dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  43     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  44 # for actual, non-rc releases, set the release value to 99 to ensure releases
  45 # have higher version numbers than their respective release candidates
  46     dpdk_conf.set('RTE_VER_RELEASE', 99)
  47 endif
  48
  49 pmd_subdir_opt = get_option('drivers_install_subdir')
  50 if pmd_subdir_opt.contains('<VERSION>')
  51     pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  52 endif
  53 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  54 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  55
  56 # driver .so files often depend upon the bus drivers for their connect bus,
  57 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  58 # to be in the library path, so symlink the drivers from the main lib directory.
  59 if not is_windows
  60     meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  61             get_option('libdir'), pmd_subdir_opt)
  62 endif
  63
  64 # init disable/enable driver lists that will be populated in different places
  65 disable_drivers = ''
  66 enable_drivers = ''
  67
  68 # set the machine type and cflags for it
  69 if meson.is_cross_build()
  70     machine = host_machine.cpu()
  71 else
  72     machine = get_option('machine')
  73 endif
  74
  75 # machine type 'generic' is special, it selects the per arch agreed common
  76 # minimal baseline needed for DPDK. Machine type 'default' is also supported
  77 # with the same meaning for backwards compatibility.
  78 # That might not be the most optimized, but the most portable version while
  79 # still being able to support the CPU features required for DPDK.
  80 # This can be bumped up by the DPDK project, but it can never be an
  81 # invariant like 'native'
  82 if machine == 'default' or machine == 'generic'
  83     if host_machine.cpu_family().startswith('x86')
  84         # matches the old pre-meson build systems generic machine
  85         machine = 'corei7'
  86     elif host_machine.cpu_family().startswith('arm')
  87         machine = 'armv7-a'
  88     elif host_machine.cpu_family().startswith('aarch')
  89         # arm64 manages generic config in config/arm/meson.build
  90         machine = 'generic'
  91     elif host_machine.cpu_family().startswith('ppc')
  92         machine = 'power8'
  93     endif
  94 endif
  95
  96 dpdk_conf.set('RTE_MACHINE', machine)
  97 machine_args = []
  98
  99 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 100 if host_machine.cpu_family().startswith('ppc')
 101     machine_args += '-mcpu=' + machine
 102     machine_args += '-mtune=' + machine
 103 else
 104     machine_args += '-march=' + machine
 105 endif
 106
 107 toolchain = cc.get_id()
 108 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 109 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 110
 111 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 112 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 113
 114 if not is_windows
 115     add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 116 endif
 117
 118 # use pthreads if available for the platform
 119 if not is_windows
 120     add_project_link_arguments('-pthread', language: 'c')
 121     dpdk_extra_ldflags += '-pthread'
 122 endif
 123
 124 # on some OS, maths functions are in a separate library
 125 if cc.find_library('m', required : false).found()
 126     # some libs depend on maths lib
 127     add_project_link_arguments('-lm', language: 'c')
 128     dpdk_extra_ldflags += '-lm'
 129 endif
 130
 131 if is_linux
 132     link_lib = 'dl'
 133 else
 134     link_lib = ''
 135 endif
 136
 137 # if link_lib is empty, do not add it to project properties
 138 if link_lib != ''
 139     add_project_link_arguments('-l' + link_lib, language: 'c')
 140     dpdk_extra_ldflags += '-l' + link_lib
 141 endif
 142
 143 # check for libraries used in multiple places in DPDK
 144 has_libnuma = 0
 145 find_libnuma = true
 146 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 147     # don't look for libnuma if explicitly disabled in cross build
 148     find_libnuma = false
 149 endif
 150 if find_libnuma
 151     numa_dep = cc.find_library('numa', required: false)
 152     if numa_dep.found() and cc.has_header('numaif.h')
 153         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 154         has_libnuma = 1
 155         add_project_link_arguments('-lnuma', language: 'c')
 156         dpdk_extra_ldflags += '-lnuma'
 157     endif
 158 endif
 159
 160 has_libfdt = 0
 161 fdt_dep = cc.find_library('libfdt', required: false)
 162 if fdt_dep.found() and cc.has_header('fdt.h')
 163     dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 164     has_libfdt = 1
 165     add_project_link_arguments('-lfdt', language: 'c')
 166     dpdk_extra_ldflags += '-lfdt'
 167 endif
 168
 169 libexecinfo = cc.find_library('libexecinfo', required: false)
 170 if libexecinfo.found() and cc.has_header('execinfo.h')
 171     add_project_link_arguments('-lexecinfo', language: 'c')
 172     dpdk_extra_ldflags += '-lexecinfo'
 173 endif
 174
 175 # check for libbsd
 176 libbsd = dependency('libbsd', required: false, method: 'pkg-config')
 177 if libbsd.found()
 178     dpdk_conf.set('RTE_USE_LIBBSD', 1)
 179 endif
 180
 181 # check for pcap
 182 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 183 if not pcap_dep.found()
 184     # pcap got a pkg-config file only in 1.9.0
 185     pcap_dep = cc.find_library('pcap', required: false)
 186 endif
 187 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 188     dpdk_conf.set('RTE_PORT_PCAP', 1)
 189     dpdk_extra_ldflags += '-lpcap'
 190 endif
 191
 192 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 193 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 194     atomic_dep = cc.find_library('atomic', required: true)
 195     add_project_link_arguments('-latomic', language: 'c')
 196     dpdk_extra_ldflags += '-latomic'
 197 endif
 198
 199 # add -include rte_config to cflags
 200 add_project_arguments('-include', 'rte_config.h', language: 'c')
 201
 202 # enable extra warnings and disable any unwanted warnings
 203 warning_flags = [
 204         # -Wall is added by meson by default, so add -Wextra only
 205         '-Wextra',
 206
 207         # additional warnings in alphabetical order
 208         '-Wcast-qual',
 209         '-Wdeprecated',
 210         '-Wformat',
 211         '-Wformat-nonliteral',
 212         '-Wformat-security',
 213         '-Wmissing-declarations',
 214         '-Wmissing-prototypes',
 215         '-Wnested-externs',
 216         '-Wold-style-definition',
 217         '-Wpointer-arith',
 218         '-Wsign-compare',
 219         '-Wstrict-prototypes',
 220         '-Wundef',
 221         '-Wwrite-strings',
 222
 223         # globally disabled warnings
 224         '-Wno-address-of-packed-member',
 225         '-Wno-packed-not-aligned',
 226         '-Wno-missing-field-initializers',
 227 ]
 228 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 229 # FIXME: Bugzilla 396
 230     warning_flags += '-Wno-zero-length-bounds'
 231 endif
 232 if not dpdk_conf.get('RTE_ARCH_64')
 233 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 234     warning_flags += '-Wno-pointer-to-int-cast'
 235 endif
 236 if cc.get_id() == 'intel'
 237     warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 238     foreach i:warning_ids
 239         warning_flags += '-diag-disable=@0@'.format(i)
 240     endforeach
 241 endif
 242 foreach arg: warning_flags
 243     if cc.has_argument(arg)
 244         add_project_arguments(arg, language: 'c')
 245     endif
 246 endforeach
 247
 248 # set other values pulled from the build options
 249 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 250 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 251 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 252 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 253 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 254 # values which have defaults which may be overridden
 255 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 256 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 257 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 258 if dpdk_conf.get('RTE_ARCH_64')
 259     dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 260 else # for 32-bit we need smaller reserved memory areas
 261     dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 262 endif
 263
 264
 265 compile_time_cpuflags = []
 266 subdir(arch_subdir)
 267 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 268
 269 # apply cross-specific options
 270 if meson.is_cross_build()
 271     # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 272     cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 273     if cross_max_lcores != 0
 274         message('Setting RTE_MAX_LCORE from cross file')
 275         dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 276     endif
 277     cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 278     if cross_max_numa_nodes != 0
 279         message('Setting RTE_MAX_NUMA_NODES from cross file')
 280         dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 281     endif
 282 endif
 283
 284 # set the install path for the drivers
 285 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 286
 287 install_headers(['rte_config.h'],
 288         subdir: get_option('include_subdir_arch'))
 289
 290 # enable VFIO only if it is linux OS
 291 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 292
 293 # specify -D_GNU_SOURCE unconditionally
 294 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 295
 296 # specify -D__BSD_VISIBLE for FreeBSD
 297 if is_freebsd
 298     add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 299 endif
 300
 301 if is_windows
 302     # VirtualAlloc2() is available since Windows 10 / Server 2016.
 303     add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 304
 305     # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 306     if cc.get_id() == 'gcc'
 307         add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 308     endif
 309
 310     # Disable secure CRT deprecated warnings for clang
 311     if cc.get_id() == 'clang'
 312         add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 313     endif
 314
 315     add_project_link_arguments('-lws2_32', language: 'c')
 316
 317     # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 318     # in Windows SDK, while MinGW exports it by advapi32.a.
 319     if is_ms_linker
 320         add_project_link_arguments('-lmincore', language: 'c')
 321     endif
 322
 323     add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 324     add_project_link_arguments('-ldbghelp', language: 'c')
 325 endif
 326
 327 if get_option('b_lto')
 328     if cc.has_argument('-ffat-lto-objects')
 329         add_project_arguments('-ffat-lto-objects', language: 'c')
 330     else
 331         error('compiler does not support fat LTO objects - please turn LTO off')
 332     endif
 333     # workaround for gcc bug 81440
 334     if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 335         add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 336         add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 337     endif
 338 endif
 339
 340 if get_option('default_library') == 'both'
 341     error( '''
 342  Unsupported value "both" for "default_library" option.
 343
 344  NOTE: DPDK always builds both shared and static libraries.  Please set
 345  "default_library" to either "static" or "shared" to select default linkage
 346  for apps and any examples.''')
 347 endif