config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 # e.g. v20.0.1 => librte_foo.so.20.0.1
  33 #      sonames => librte_foo.so.20.0
  34 abi_va = abi_version.split('.')
  35 so_version = abi_va.length() == 2 ? abi_va[0] : abi_va[0] + '.' + abi_va[1]
  36
  37 # extract all version information into the build configuration
  38 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  39 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  40 if pver.get(2).contains('-rc')
  41         rc_ver = pver.get(2).split('-rc')
  42         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  43         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  44         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  45 else
  46         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  47         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  48 # for actual, non-rc releases, set the release value to 99 to ensure releases
  49 # have higher version numbers than their respective release candidates
  50         dpdk_conf.set('RTE_VER_RELEASE', 99)
  51 endif
  52
  53 pmd_subdir_opt = get_option('drivers_install_subdir')
  54 if pmd_subdir_opt.contains('<VERSION>')
  55         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  56 endif
  57 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  58 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  59
  60 # driver .so files often depend upon the bus drivers for their connect bus,
  61 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  62 # to be in the library path, so symlink the drivers from the main lib directory.
  63 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  64                 get_option('libdir'),
  65                 pmd_subdir_opt)
  66
  67 # set the machine type and cflags for it
  68 if meson.is_cross_build()
  69         machine = host_machine.cpu()
  70 else
  71         machine = get_option('machine')
  72 endif
  73
  74 # machine type 'default' is special, it defaults to the per arch agreed common
  75 # minimal baseline needed for DPDK.
  76 # That might not be the most optimized, but the most portable version while
  77 # still being able to support the CPU features required for DPDK.
  78 # This can be bumped up by the DPDK project, but it can never be an
  79 # invariant like 'native'
  80 if machine == 'default'
  81         if host_machine.cpu_family().startswith('x86')
  82                 # matches the old pre-meson build systems default
  83                 machine = 'corei7'
  84         elif host_machine.cpu_family().startswith('arm')
  85                 machine = 'armv7-a'
  86         elif host_machine.cpu_family().startswith('aarch')
  87                 # arm64 manages defaults in config/arm/meson.build
  88                 machine = 'default'
  89         elif host_machine.cpu_family().startswith('ppc')
  90                 machine = 'power8'
  91         endif
  92 endif
  93
  94 dpdk_conf.set('RTE_MACHINE', machine)
  95 machine_args = []
  96
  97 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  98 if host_machine.cpu_family().startswith('ppc')
  99         machine_args += '-mcpu=' + machine
 100         machine_args += '-mtune=' + machine
 101 else
 102         machine_args += '-march=' + machine
 103 endif
 104
 105 toolchain = cc.get_id()
 106 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 107 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 108
 109 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 110
 111 if not is_windows
 112         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 113 endif
 114
 115 # use pthreads if available for the platform
 116 if not is_windows
 117         add_project_link_arguments('-pthread', language: 'c')
 118         dpdk_extra_ldflags += '-pthread'
 119 endif
 120
 121 # on some OS, maths functions are in a separate library
 122 if cc.find_library('m', required : false).found()
 123         # some libs depend on maths lib
 124         add_project_link_arguments('-lm', language: 'c')
 125         dpdk_extra_ldflags += '-lm'
 126 endif
 127
 128 # for linux link against dl, for bsd execinfo
 129 if is_linux
 130         link_lib = 'dl'
 131 elif is_freebsd
 132         link_lib = 'execinfo'
 133 else
 134         link_lib = ''
 135 endif
 136
 137 # if link_lib is empty, do not add it to project properties
 138 if link_lib != ''
 139         add_project_link_arguments('-l' + link_lib, language: 'c')
 140         dpdk_extra_ldflags += '-l' + link_lib
 141 endif
 142
 143 # check for libraries used in multiple places in DPDK
 144 has_libnuma = 0
 145 numa_dep = cc.find_library('numa', required: false)
 146 if numa_dep.found() and cc.has_header('numaif.h')
 147         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 148         has_libnuma = 1
 149         add_project_link_arguments('-lnuma', language: 'c')
 150         dpdk_extra_ldflags += '-lnuma'
 151 endif
 152
 153 # check for libbsd
 154 libbsd = dependency('libbsd', required: false)
 155 if libbsd.found()
 156         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 157 endif
 158
 159 # check for pcap
 160 pcap_dep = dependency('pcap', required: false)
 161 if pcap_dep.found()
 162         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 163         # an internal pcap-config finder, which is not compatible with
 164         # cross-compilation, so try to fallback to find_library
 165         pcap_dep = cc.find_library('pcap', required: false)
 166 endif
 167 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 168         dpdk_conf.set('RTE_PORT_PCAP', 1)
 169         dpdk_extra_ldflags += '-lpcap'
 170 endif
 171
 172 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 173 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 174         atomic_dep = cc.find_library('atomic', required: true)
 175         add_project_link_arguments('-latomic', language: 'c')
 176         dpdk_extra_ldflags += '-latomic'
 177 endif
 178
 179 # add -include rte_config to cflags
 180 add_project_arguments('-include', 'rte_config.h', language: 'c')
 181
 182 # enable extra warnings and disable any unwanted warnings
 183 warning_flags = [
 184         # -Wall is added by meson by default, so add -Wextra only
 185         '-Wextra',
 186
 187         # additional warnings in alphabetical order
 188         '-Wcast-qual',
 189         '-Wdeprecated',
 190         '-Wformat-nonliteral',
 191         '-Wformat-security',
 192         '-Wmissing-declarations',
 193         '-Wmissing-prototypes',
 194         '-Wnested-externs',
 195         '-Wold-style-definition',
 196         '-Wpointer-arith',
 197         '-Wsign-compare',
 198         '-Wstrict-prototypes',
 199         '-Wundef',
 200         '-Wwrite-strings',
 201
 202         # globally disabled warnings
 203         '-Wno-address-of-packed-member',
 204         '-Wno-packed-not-aligned',
 205         '-Wno-missing-field-initializers'
 206 ]
 207 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 208 # FIXME: Bugzilla 396
 209         warning_flags += '-Wno-zero-length-bounds'
 210 endif
 211 if not dpdk_conf.get('RTE_ARCH_64')
 212 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 213         warning_flags += '-Wno-pointer-to-int-cast'
 214 endif
 215 if cc.get_id() == 'intel'
 216         warning_ids = [188, 2203, 2279, 2557, 3179, 3656]
 217         foreach i:warning_ids
 218                 warning_flags += '-diag-disable=@0@'.format(i)
 219         endforeach
 220 endif
 221 foreach arg: warning_flags
 222         if cc.has_argument(arg)
 223                 add_project_arguments(arg, language: 'c')
 224         endif
 225 endforeach
 226
 227 # set other values pulled from the build options
 228 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 229 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 230 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 231 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 232 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 233 # values which have defaults which may be overridden
 234 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 235 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 236 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 237 if dpdk_conf.get('RTE_ARCH_64')
 238         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 239 else # for 32-bit we need smaller reserved memory areas
 240         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 241 endif
 242
 243
 244 compile_time_cpuflags = []
 245 subdir(arch_subdir)
 246 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 247
 248 # set the install path for the drivers
 249 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 250
 251 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 252
 253 # enable VFIO only if it is linux OS
 254 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 255
 256 # specify -D_GNU_SOURCE unconditionally
 257 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 258
 259 # specify -D__BSD_VISIBLE for FreeBSD
 260 if is_freebsd
 261         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 262 endif
 263
 264 if is_windows
 265         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 266         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 267
 268         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 269         if cc.get_id() == 'gcc'
 270                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 271         endif
 272
 273         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 274         # in Windows SDK, while MinGW exports it by advapi32.a.
 275         if is_ms_linker
 276                 add_project_link_arguments('-lmincore', language: 'c')
 277         endif
 278
 279         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 280         add_project_link_arguments('-ldbghelp', language: 'c')
 281 endif
 282
 283 if get_option('b_lto')
 284         if cc.has_argument('-ffat-lto-objects')
 285                 add_project_arguments('-ffat-lto-objects', language: 'c')
 286         else
 287                 error('compiler does not support fat LTO objects - please turn LTO off')
 288         endif
 289         # workaround for gcc bug 81440
 290         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 291                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 292                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 293         endif
 294 endif