config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 so_version = abi_version.split('.')[0]
  33
  34 # extract all version information into the build configuration
  35 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  36 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  37 if pver.get(2).contains('-rc')
  38         rc_ver = pver.get(2).split('-rc')
  39         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  40         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  41         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  42 else
  43         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  44         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  45 # for actual, non-rc releases, set the release value to 99 to ensure releases
  46 # have higher version numbers than their respective release candidates
  47         dpdk_conf.set('RTE_VER_RELEASE', 99)
  48 endif
  49
  50 pmd_subdir_opt = get_option('drivers_install_subdir')
  51 if pmd_subdir_opt.contains('<VERSION>')
  52         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  53 endif
  54 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  55 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  56
  57 # driver .so files often depend upon the bus drivers for their connect bus,
  58 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  59 # to be in the library path, so symlink the drivers from the main lib directory.
  60 if not is_windows
  61         meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  62                         get_option('libdir'),
  63                         pmd_subdir_opt)
  64 endif
  65
  66 # set the machine type and cflags for it
  67 if meson.is_cross_build()
  68         machine = host_machine.cpu()
  69 else
  70         machine = get_option('machine')
  71 endif
  72
  73 # machine type 'default' is special, it defaults to the per arch agreed common
  74 # minimal baseline needed for DPDK.
  75 # That might not be the most optimized, but the most portable version while
  76 # still being able to support the CPU features required for DPDK.
  77 # This can be bumped up by the DPDK project, but it can never be an
  78 # invariant like 'native'
  79 if machine == 'default'
  80         if host_machine.cpu_family().startswith('x86')
  81                 # matches the old pre-meson build systems default
  82                 machine = 'corei7'
  83         elif host_machine.cpu_family().startswith('arm')
  84                 machine = 'armv7-a'
  85         elif host_machine.cpu_family().startswith('aarch')
  86                 # arm64 manages defaults in config/arm/meson.build
  87                 machine = 'default'
  88         elif host_machine.cpu_family().startswith('ppc')
  89                 machine = 'power8'
  90         endif
  91 endif
  92
  93 dpdk_conf.set('RTE_MACHINE', machine)
  94 machine_args = []
  95
  96 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  97 if host_machine.cpu_family().startswith('ppc')
  98         machine_args += '-mcpu=' + machine
  99         machine_args += '-mtune=' + machine
 100 else
 101         machine_args += '-march=' + machine
 102 endif
 103
 104 toolchain = cc.get_id()
 105 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 106 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 107
 108 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 109 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 110
 111 if not is_windows
 112         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 113 endif
 114
 115 # use pthreads if available for the platform
 116 if not is_windows
 117         add_project_link_arguments('-pthread', language: 'c')
 118         dpdk_extra_ldflags += '-pthread'
 119 endif
 120
 121 # on some OS, maths functions are in a separate library
 122 if cc.find_library('m', required : false).found()
 123         # some libs depend on maths lib
 124         add_project_link_arguments('-lm', language: 'c')
 125         dpdk_extra_ldflags += '-lm'
 126 endif
 127
 128 # for linux link against dl, for bsd execinfo
 129 if is_linux
 130         link_lib = 'dl'
 131 elif is_freebsd
 132         link_lib = 'execinfo'
 133 else
 134         link_lib = ''
 135 endif
 136
 137 # if link_lib is empty, do not add it to project properties
 138 if link_lib != ''
 139         add_project_link_arguments('-l' + link_lib, language: 'c')
 140         dpdk_extra_ldflags += '-l' + link_lib
 141 endif
 142
 143 # check for libraries used in multiple places in DPDK
 144 has_libnuma = 0
 145 find_libnuma = true
 146 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 147         # don't look for libnuma if explicitly disabled in cross build
 148         find_libnuma = false
 149 endif
 150 if find_libnuma
 151         numa_dep = cc.find_library('numa', required: false)
 152         if numa_dep.found() and cc.has_header('numaif.h')
 153                 dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 154                 has_libnuma = 1
 155                 add_project_link_arguments('-lnuma', language: 'c')
 156                 dpdk_extra_ldflags += '-lnuma'
 157         endif
 158 endif
 159
 160 has_libfdt = 0
 161 fdt_dep = cc.find_library('libfdt', required: false)
 162 if fdt_dep.found() and cc.has_header('fdt.h')
 163         dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 164         has_libfdt = 1
 165         add_project_link_arguments('-lfdt', language: 'c')
 166         dpdk_extra_ldflags += '-lfdt'
 167 endif
 168
 169 # check for libbsd
 170 libbsd = dependency('libbsd', required: false)
 171 if libbsd.found()
 172         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 173 endif
 174
 175 # check for pcap
 176 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 177 if not pcap_dep.found()
 178         # pcap got a pkg-config file only in 1.9.0
 179         pcap_dep = cc.find_library('pcap', required: false)
 180 endif
 181 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 182         dpdk_conf.set('RTE_PORT_PCAP', 1)
 183         dpdk_extra_ldflags += '-lpcap'
 184 endif
 185
 186 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 187 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 188         atomic_dep = cc.find_library('atomic', required: true)
 189         add_project_link_arguments('-latomic', language: 'c')
 190         dpdk_extra_ldflags += '-latomic'
 191 endif
 192
 193 # add -include rte_config to cflags
 194 add_project_arguments('-include', 'rte_config.h', language: 'c')
 195
 196 # enable extra warnings and disable any unwanted warnings
 197 warning_flags = [
 198         # -Wall is added by meson by default, so add -Wextra only
 199         '-Wextra',
 200
 201         # additional warnings in alphabetical order
 202         '-Wcast-qual',
 203         '-Wdeprecated',
 204         '-Wformat',
 205         '-Wformat-nonliteral',
 206         '-Wformat-security',
 207         '-Wmissing-declarations',
 208         '-Wmissing-prototypes',
 209         '-Wnested-externs',
 210         '-Wold-style-definition',
 211         '-Wpointer-arith',
 212         '-Wsign-compare',
 213         '-Wstrict-prototypes',
 214         '-Wundef',
 215         '-Wwrite-strings',
 216
 217         # globally disabled warnings
 218         '-Wno-address-of-packed-member',
 219         '-Wno-packed-not-aligned',
 220         '-Wno-missing-field-initializers'
 221 ]
 222 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 223 # FIXME: Bugzilla 396
 224         warning_flags += '-Wno-zero-length-bounds'
 225 endif
 226 if not dpdk_conf.get('RTE_ARCH_64')
 227 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 228         warning_flags += '-Wno-pointer-to-int-cast'
 229 endif
 230 if cc.get_id() == 'intel'
 231         warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 232         foreach i:warning_ids
 233                 warning_flags += '-diag-disable=@0@'.format(i)
 234         endforeach
 235 endif
 236 foreach arg: warning_flags
 237         if cc.has_argument(arg)
 238                 add_project_arguments(arg, language: 'c')
 239         endif
 240 endforeach
 241
 242 # set other values pulled from the build options
 243 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 244 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 245 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 246 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 247 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 248 # values which have defaults which may be overridden
 249 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 250 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 251 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 252 if dpdk_conf.get('RTE_ARCH_64')
 253         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 254 else # for 32-bit we need smaller reserved memory areas
 255         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 256 endif
 257
 258
 259 compile_time_cpuflags = []
 260 subdir(arch_subdir)
 261 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 262
 263 # apply cross-specific options
 264 if meson.is_cross_build()
 265         # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 266         cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 267         if cross_max_lcores != 0
 268                 message('Setting RTE_MAX_LCORE from cross file')
 269                 dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 270         endif
 271         cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 272         if cross_max_numa_nodes != 0
 273                 message('Setting RTE_MAX_NUMA_NODES from cross file')
 274                 dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 275         endif
 276 endif
 277
 278 # set the install path for the drivers
 279 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 280
 281 install_headers(['rte_config.h', 'rte_compatibility_defines.h'],
 282                 subdir: get_option('include_subdir_arch'))
 283
 284 # enable VFIO only if it is linux OS
 285 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 286
 287 # specify -D_GNU_SOURCE unconditionally
 288 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 289
 290 # specify -D__BSD_VISIBLE for FreeBSD
 291 if is_freebsd
 292         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 293 endif
 294
 295 if is_windows
 296         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 297         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 298
 299         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 300         if cc.get_id() == 'gcc'
 301                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 302         endif
 303
 304         # Disable secure CRT deprecated warnings for clang
 305         if cc.get_id() == 'clang'
 306                 add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 307         endif
 308
 309         add_project_link_arguments('-lws2_32', language: 'c')
 310
 311         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 312         # in Windows SDK, while MinGW exports it by advapi32.a.
 313         if is_ms_linker
 314                 add_project_link_arguments('-lmincore', language: 'c')
 315         endif
 316
 317         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 318         add_project_link_arguments('-ldbghelp', language: 'c')
 319 endif
 320
 321 if get_option('b_lto')
 322         if cc.has_argument('-ffat-lto-objects')
 323                 add_project_arguments('-ffat-lto-objects', language: 'c')
 324         else
 325                 error('compiler does not support fat LTO objects - please turn LTO off')
 326         endif
 327         # workaround for gcc bug 81440
 328         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 329                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 330                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 331         endif
 332 endif