config/ppc/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Luca Boccassi <bluca@debian.org>
   3 # Copyright(c) 2021 IBM Corporation
   4
   5 if not dpdk_conf.get('RTE_ARCH_64')
   6     error('Only 64-bit compiles are supported for this platform type')
   7 endif
   8 dpdk_conf.set('RTE_ARCH', 'ppc_64')
   9 dpdk_conf.set('RTE_ARCH_PPC_64', 1)
  10
  11 # RHEL 7.x uses gcc 4.8.X which doesn't generate code for Power 9 CPUs,
  12 # though it will detect a Power 9 CPU when the "-mcpu=native" argument
  13 # is used, resulting in a build failure.
  14 power9_supported = cc.has_argument('-mcpu=power9')
  15 if not power9_supported
  16     cpu_instruction_set = 'power8'
  17     machine_args = ['-mcpu=power8', '-mtune=power8']
  18     dpdk_conf.set('RTE_MACHINE','power8')
  19 endif
  20
  21 # Suppress the gcc warning "note: the layout of aggregates containing
  22 # vectors with 4-byte alignment has changed in GCC 5".
  23 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0') and
  24         cc.version().version_compare('<12.0') and cc.has_argument('-Wno-psabi')
  25     add_project_arguments('-Wno-psabi', language: 'c')
  26 endif
  27
  28 # Certain POWER9 systems can scale as high as 1536 LCORES, but setting such a
  29 # high value can waste memory, cause timeouts in time limited autotests, and is
  30 # unlikely to be used in many production situations.  Similarly, keeping the
  31 # default 64 LCORES seems too small as most POWER9 dual socket systems will have
  32 # at least 128 LCORES available.  Set RTE_MAX_LCORE to 128 for POWER systems as
  33 # a compromise.
  34 dpdk_conf.set('RTE_MAX_LCORE', 128)
  35
  36 # POWER systems do not allocate NUMA nodes sequentially.  A dual socket system
  37 # will have CPUs associated with NUMA nodes 0 & 8, so ensure that the second
  38 # NUMA node will be supported by setting RTE_MAX_NUMA_NODES to 16. High end
  39 # systems can scale even higher with as many as 32 NUMA nodes.
  40 dpdk_conf.set('RTE_MAX_NUMA_NODES', 16)
  41
  42 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)