config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 # for checking defines we need to use the correct compiler flags
   5 march_opt = '-march=@0@'.format(machine)
   6
   7 # we require SSE4.2 for DPDK
   8 sse_errormsg = '''SSE4.2 instruction set is required for DPDK.
   9 Please set the machine type to "nehalem" or "corei7" or higher value'''
  10
  11 if cc.get_define('__SSE4_2__', args: march_opt) == ''
  12         error(sse_errormsg)
  13 endif
  14
  15 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  16 foreach f:base_flags
  17         dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  18         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  19 endforeach
  20
  21 dpdk_conf.set('RTE_ARCH_X86', 1)
  22 if (host_machine.cpu_family() == 'x86_64')
  23         dpdk_conf.set('RTE_ARCH_X86_64', 1)
  24         dpdk_conf.set('RTE_ARCH', 'x86_64')
  25         dpdk_conf.set('RTE_ARCH_64', 1)
  26 else
  27         dpdk_conf.set('RTE_ARCH_I686', 1)
  28         dpdk_conf.set('RTE_ARCH', 'i686')
  29 endif
  30
  31 if cc.get_define('__AES__', args: march_opt) != ''
  32         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
  33         compile_time_cpuflags += ['RTE_CPUFLAG_AES']
  34 endif
  35 if cc.get_define('__PCLMUL__', args: march_opt) != ''
  36         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PCLMULQDQ', 1)
  37         compile_time_cpuflags += ['RTE_CPUFLAG_PCLMULQDQ']
  38 endif
  39 if cc.get_define('__AVX__', args: march_opt) != ''
  40         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX', 1)
  41         compile_time_cpuflags += ['RTE_CPUFLAG_AVX']
  42 endif
  43 if cc.get_define('__AVX2__', args: march_opt) != ''
  44         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX2', 1)
  45         compile_time_cpuflags += ['RTE_CPUFLAG_AVX2']
  46 endif
  47 if cc.get_define('__AVX512F__', args: march_opt) != ''
  48         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX512F', 1)
  49         compile_time_cpuflags += ['RTE_CPUFLAG_AVX512F']
  50 endif
  51
  52 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)