config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # for checking defines we need to use the correct compiler flags
   5 march_opt = ['-march=@0@'.format(machine)]
   6
   7 # get binutils version for the workaround of Bug 97
   8 if host_machine.system() != 'windows'
   9         ldver = run_command('ld', '-v').stdout().strip()
  10         if ldver.contains('2.30')
  11                 if cc.has_argument('-mno-avx512f')
  12                         march_opt += '-mno-avx512f'
  13                         message('Binutils 2.30 detected, disabling AVX512 support as workaround for bug #97')
  14                 endif
  15         endif
  16 endif
  17
  18 # we require SSE4.2 for DPDK
  19 sse_errormsg = '''SSE4.2 instruction set is required for DPDK.
  20 Please set the machine type to "nehalem" or "corei7" or higher value'''
  21
  22 if cc.get_define('__SSE4_2__', args: march_opt) == ''
  23         error(sse_errormsg)
  24 endif
  25
  26 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  27 foreach f:base_flags
  28         dpdk_conf.set('RTE_MACHINE_CPUFLAG_' + f, 1)
  29         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  30 endforeach
  31
  32 dpdk_conf.set('RTE_ARCH_X86', 1)
  33 if dpdk_conf.get('RTE_ARCH_64')
  34         dpdk_conf.set('RTE_ARCH_X86_64', 1)
  35         dpdk_conf.set('RTE_ARCH', 'x86_64')
  36 else
  37         dpdk_conf.set('RTE_ARCH_I686', 1)
  38         dpdk_conf.set('RTE_ARCH', 'i686')
  39 endif
  40
  41 if cc.get_define('__AES__', args: march_opt) != ''
  42         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
  43         compile_time_cpuflags += ['RTE_CPUFLAG_AES']
  44 endif
  45 if cc.get_define('__PCLMUL__', args: march_opt) != ''
  46         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PCLMULQDQ', 1)
  47         compile_time_cpuflags += ['RTE_CPUFLAG_PCLMULQDQ']
  48 endif
  49 if cc.get_define('__AVX__', args: march_opt) != ''
  50         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX', 1)
  51         compile_time_cpuflags += ['RTE_CPUFLAG_AVX']
  52 endif
  53 if cc.get_define('__AVX2__', args: march_opt) != ''
  54         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX2', 1)
  55         compile_time_cpuflags += ['RTE_CPUFLAG_AVX2']
  56 endif
  57 if cc.get_define('__AVX512F__', args: march_opt) != ''
  58         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AVX512F', 1)
  59         compile_time_cpuflags += ['RTE_CPUFLAG_AVX512F']
  60 endif
  61
  62 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)