drivers/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # Defines the order of dependencies evaluation
   5 subdirs = [
   6         'common',
   7         'bus',
   8         'common/mlx5', # depends on bus.
   9         'common/qat', # depends on bus.
  10         'mempool', # depends on common and bus.
  11         'net',     # depends on common, bus, mempool
  12         'raw',     # depends on common, bus and net.
  13         'crypto',  # depends on common, bus and mempool (net in future).
  14         'compress', # depends on common, bus, mempool.
  15         'regex', # depends on common, bus, regexdev.
  16         'vdpa',    # depends on common, bus and mempool.
  17         'event',   # depends on common, bus, mempool and net.
  18         'baseband', # depends on common and bus.
  19 ]
  20
  21 disabled_drivers = run_command(list_dir_globs, get_option('disable_drivers'),
  22                 ).stdout().split()
  23
  24 default_cflags = machine_args
  25 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  26 default_cflags += ['-DALLOW_INTERNAL_API']
  27
  28 if cc.has_argument('-Wno-format-truncation')
  29         default_cflags += '-Wno-format-truncation'
  30 endif
  31
  32 foreach subpath:subdirs
  33         drivers = []
  34         std_deps = []
  35         config_flag_fmt = '' # format string used to set the value in dpdk_conf
  36
  37         # subpath can be either "class" or "class/driver"
  38         if subpath.contains('/')
  39                 driver_path = subpath.split('/')
  40                 class = driver_path[0]
  41                 drivers += driver_path[1]
  42         else
  43                 class = subpath
  44                 subdir(class)
  45         endif
  46
  47         # save class name on first occurrence
  48         if not dpdk_driver_classes.contains(class)
  49                 dpdk_driver_classes += class
  50         endif
  51         # get already enabled drivers of the same class
  52         enabled_drivers = get_variable(class + '_drivers', [])
  53
  54         foreach drv:drivers
  55                 drv_path = join_paths(class, drv)
  56
  57                 # set up empty variables used for build
  58                 build = true # set to false to disable, e.g. missing deps
  59                 reason = '<unknown reason>' # set if build == false to explain
  60                 name = drv
  61                 fmt_name = ''
  62                 sources = []
  63                 objs = []
  64                 cflags = default_cflags
  65                 includes = [include_directories(drv_path)]
  66                 # set up internal deps. Drivers can append/override as necessary
  67                 deps = std_deps
  68                 # ext_deps: Stores external library dependency got
  69                 # using dependency() (preferred) or find_library().
  70                 # For the find_library() case (but not with dependency()) we also
  71                 # need to specify the "-l" flags in pkgconfig_extra_libs variable
  72                 # too, so that it can be reflected in the pkgconfig output for
  73                 # static builds.
  74                 ext_deps = []
  75                 pkgconfig_extra_libs = []
  76
  77                 if disabled_drivers.contains(drv_path)
  78                         build = false
  79                         reason = 'Explicitly disabled via build config'
  80                 else
  81                         # pull in driver directory which should update all the local variables
  82                         subdir(drv_path)
  83                 endif
  84
  85                 if build
  86                         # get dependency objs from strings
  87                         shared_deps = ext_deps
  88                         static_deps = ext_deps
  89                         foreach d:deps
  90                                 if not is_variable('shared_rte_' + d)
  91                                         build = false
  92                                         reason = 'Missing internal dependency, "@0@"'.format(d)
  93                                         message('Disabling @1@ [@2@]: missing internal dependency "@0@"'
  94                                                         .format(d, name, 'drivers/' + drv_path))
  95                                 else
  96                                         shared_deps += [get_variable('shared_rte_' + d)]
  97                                         static_deps += [get_variable('static_rte_' + d)]
  98                                 endif
  99                         endforeach
 100                 endif
 101
 102                 if not build
 103                         # some driver directories are placeholders which
 104                         # are never built, so we allow suppression of the
 105                         # component disable printout in those cases
 106                         if reason != ''
 107                                 dpdk_drvs_disabled += drv_path
 108                                 set_variable(drv_path.underscorify() +
 109                                                 '_disable_reason', reason)
 110                         endif
 111                 else
 112                         enabled_drivers += name
 113                         lib_name = '_'.join(['rte', class, name])
 114                         dpdk_conf.set(lib_name.to_upper(), 1)
 115
 116                         if fmt_name == ''
 117                                 fmt_name = name
 118                         endif
 119
 120                         dpdk_conf.set(config_flag_fmt.format(fmt_name.to_upper()),1) #old-style macro
 121                         # for driver compatibility, since we changed the
 122                         # default to match that of make. Remove in future release
 123                         # after following deprecation process
 124                         if config_flag_fmt.contains('_PMD_@0@') and (class == 'crypto'
 125                                         or class == 'compress'
 126                                         or class == 'event')
 127                                 alt_flag_fmt = '_@0@_PMD'.join(
 128                                                 config_flag_fmt.split('_PMD_@0@'))
 129                                 if config_flag_fmt.contains('EVENTDEV')
 130                                         alt_flag_fmt = '_@0@_EVENTDEV_PMD'.join(
 131                                                 config_flag_fmt.split('_PMD_@0@_EVENTDEV'))
 132                                 endif
 133                                 dpdk_conf.set(alt_flag_fmt.format(
 134                                                 fmt_name.to_upper()), 1)
 135                         endif
 136
 137                         dpdk_extra_ldflags += pkgconfig_extra_libs
 138
 139                         # generate pmdinfo sources by building a temporary
 140                         # lib and then running pmdinfogen on the contents of
 141                         # that lib. The final lib reuses the object files and
 142                         # adds in the new source file.
 143                         if not is_windows
 144                                 out_filename = lib_name + '.pmd.c'
 145                                 tmp_lib = static_library('tmp_' + lib_name,
 146                                                 sources,
 147                                                 include_directories: includes,
 148                                                 dependencies: static_deps,
 149                                                 c_args: cflags)
 150                                 objs += tmp_lib.extract_all_objects()
 151                                 sources = custom_target(out_filename,
 152                                                 command: [pmdinfo, tmp_lib.full_path(),
 153                                                         '@OUTPUT@', pmdinfogen],
 154                                                 output: out_filename,
 155                                                 depends: [pmdinfogen, tmp_lib])
 156                         endif
 157
 158                         # now build the static driver
 159                         static_lib = static_library(lib_name,
 160                                 sources,
 161                                 objects: objs,
 162                                 include_directories: includes,
 163                                 dependencies: static_deps,
 164                                 c_args: cflags,
 165                                 install: true)
 166
 167                         # now build the shared driver
 168                         version_map = '@0@/@1@/version.map'.format(
 169                                         meson.current_source_dir(),
 170                                         drv_path)
 171                         implib = 'lib' + lib_name + '.dll.a'
 172
 173                         def_file = custom_target(lib_name + '_def',
 174                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 175                                 input: version_map,
 176                                 output: '@0@_exports.def'.format(lib_name))
 177
 178                         mingw_map = custom_target(lib_name + '_mingw',
 179                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 180                                 input: version_map,
 181                                 output: '@0@_mingw.map'.format(lib_name))
 182
 183                         lk_deps = [version_map, def_file, mingw_map]
 184                         if is_windows
 185                                 if is_ms_linker
 186                                         lk_args = ['-Wl,/def:' + def_file.full_path(),
 187                                                 '-Wl,/implib:drivers\\' + implib]
 188                                 else
 189                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 190                                 endif
 191                         else
 192                                 lk_args = ['-Wl,--version-script=' + version_map]
 193                                 # on unix systems check the output of the
 194                                 # check-symbols.sh script, using it as a
 195                                 # dependency of the .so build
 196                                 lk_deps += custom_target(lib_name + '.sym_chk',
 197                                         command: [check_symbols,
 198                                                 version_map, '@INPUT@'],
 199                                         capture: true,
 200                                         input: static_lib,
 201                                         output: lib_name + '.sym_chk')
 202                         endif
 203
 204                         shared_lib = shared_library(lib_name,
 205                                 sources,
 206                                 objects: objs,
 207                                 include_directories: includes,
 208                                 dependencies: shared_deps,
 209                                 c_args: cflags,
 210                                 link_args: lk_args,
 211                                 link_depends: lk_deps,
 212                                 version: abi_version,
 213                                 soversion: so_version,
 214                                 install: true,
 215                                 install_dir: driver_install_path)
 216
 217                         # create a dependency object and add it to the global dictionary so
 218                         # testpmd or other built-in apps can find it if necessary
 219                         shared_dep = declare_dependency(link_with: shared_lib,
 220                                         include_directories: includes,
 221                                         dependencies: shared_deps)
 222                         static_dep = declare_dependency(
 223                                         include_directories: includes,
 224                                         dependencies: static_deps)
 225
 226                         dpdk_drivers += static_lib
 227
 228                         set_variable('shared_@0@'.format(lib_name), shared_dep)
 229                         set_variable('static_@0@'.format(lib_name), static_dep)
 230                         dependency_name = ''.join(lib_name.split('rte_'))
 231                         message('drivers/@0@: Defining dependency "@1@"'.format(
 232                                         drv_path, dependency_name))
 233                 endif # build
 234         endforeach
 235
 236         set_variable(class + '_drivers', enabled_drivers)
 237 endforeach