drivers/net/enic/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Cisco Systems, Inc.
   3
   4 # Experimental APIs used: rte_intr_ack
   5 cflags += ['-DALLOW_EXPERIMENTAL_API']
   6 sources = files(
   7         'base/vnic_cq.c',
   8         'base/vnic_dev.c',
   9         'base/vnic_intr.c',
  10         'base/vnic_rq.c',
  11         'base/vnic_wq.c',
  12         'enic_clsf.c',
  13         'enic_ethdev.c',
  14         'enic_flow.c',
  15         'enic_fm_flow.c',
  16         'enic_main.c',
  17         'enic_res.c',
  18         'enic_rxtx.c',
  19         )
  20 deps += ['hash']
  21 includes += include_directories('base')
  22
  23 # The current implementation assumes 64-bit pointers
  24 if dpdk_conf.has('RTE_MACHINE_CPUFLAG_AVX2') and dpdk_conf.get('RTE_ARCH_64')
  25         sources += files('enic_rxtx_vec_avx2.c')
  26 # Build the avx2 handler if the compiler supports it, even though 'machine'
  27 # does not. This is to support users who build for the min supported machine
  28 # and need to run the binary on newer CPUs too.
  29 # This part is from i40e meson.build
  30 elif cc.has_argument('-mavx2') and dpdk_conf.get('RTE_ARCH_64')
  31         enic_avx2_lib = static_library('enic_avx2_lib',
  32                         'enic_rxtx_vec_avx2.c',
  33                         dependencies: [static_rte_ethdev, static_rte_bus_pci],
  34                         include_directories: includes,
  35                         c_args: [cflags, '-mavx2'])
  36         objs += enic_avx2_lib.extract_objects('enic_rxtx_vec_avx2.c')
  37 endif