drivers/net/i40e/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 version = 2
   5
   6 cflags += ['-DPF_DRIVER',
   7         '-DVF_DRIVER',
   8         '-DINTEGRATED_VF',
   9         '-DX722_A0_SUPPORT',
  10         '-DALLOW_EXPERIMENTAL_API']
  11
  12 subdir('base')
  13 objs = [base_objs]
  14
  15 sources = files(
  16         'i40e_ethdev.c',
  17         'i40e_rxtx.c',
  18         'i40e_ethdev_vf.c',
  19         'i40e_pf.c',
  20         'i40e_fdir.c',
  21         'i40e_flow.c',
  22         'i40e_tm.c',
  23         'i40e_vf_representor.c',
  24         'rte_pmd_i40e.c'
  25         )
  26
  27 deps += ['hash']
  28
  29 if arch_subdir == 'x86'
  30         dpdk_conf.set('RTE_LIBRTE_I40E_INC_VECTOR', 1)
  31         sources += files('i40e_rxtx_vec_sse.c')
  32
  33         # compile AVX2 version if either:
  34         # a. we have AVX supported in minimum instruction set baseline
  35         # b. it's not minimum instruction set, but supported by compiler
  36         if dpdk_conf.has('RTE_MACHINE_CPUFLAG_AVX2')
  37                 sources += files('i40e_rxtx_vec_avx2.c')
  38         elif cc.has_argument('-mavx2')
  39                 i40e_avx2_lib = static_library('i40e_avx2_lib',
  40                                 'i40e_rxtx_vec_avx2.c',
  41                                 dependencies: [static_rte_ethdev,
  42                                         static_rte_kvargs, static_rte_hash],
  43                                 c_args: '-mavx2')
  44                 objs += i40e_avx2_lib.extract_objects('i40e_rxtx_vec_avx2.c')
  45         endif
  46 endif
  47
  48 includes += include_directories('base')
  49
  50 install_headers('rte_pmd_i40e.h')