drivers/net/mlx5/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
   6 LIB_GLUE_BASE = 'librte_pmd_mlx5_glue.so'
   7 LIB_GLUE_VERSION = '19.05.0'
   8 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
   9 if pmd_dlopen
  10         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  11         cflags += [
  12                 '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  13                 '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  14         ]
  15 endif
  16 libnames = [ 'mlx5', 'ibverbs' ]
  17 libs = []
  18 build = true
  19 foreach libname:libnames
  20         lib = dependency('lib' + libname, required:false)
  21         if not lib.found()
  22                 lib = cc.find_library(libname, required:false)
  23         endif
  24         if lib.found()
  25                 libs += [ lib ]
  26         else
  27                 build = false
  28                 reason = 'missing dependency, "' + libname + '"'
  29         endif
  30 endforeach
  31 if build
  32         allow_experimental_apis = true
  33         ext_deps += libs
  34         sources = files(
  35                 'mlx5.c',
  36                 'mlx5_ethdev.c',
  37                 'mlx5_flow.c',
  38                 'mlx5_flow_dv.c',
  39                 'mlx5_flow_verbs.c',
  40                 'mlx5_mac.c',
  41                 'mlx5_mr.c',
  42                 'mlx5_nl.c',
  43                 'mlx5_rss.c',
  44                 'mlx5_rxmode.c',
  45                 'mlx5_rxq.c',
  46                 'mlx5_rxtx.c',
  47                 'mlx5_mp.c',
  48                 'mlx5_stats.c',
  49                 'mlx5_trigger.c',
  50                 'mlx5_txq.c',
  51                 'mlx5_vlan.c',
  52                 'mlx5_devx_cmds.c',
  53         )
  54         if dpdk_conf.has('RTE_ARCH_X86_64') or dpdk_conf.has('RTE_ARCH_ARM64')
  55                 sources += files('mlx5_rxtx_vec.c')
  56         endif
  57         if not pmd_dlopen
  58                 sources += files('mlx5_glue.c')
  59         endif
  60         cflags_options = [
  61                 '-Wextra',
  62                 '-std=c11',
  63                 '-Wno-strict-prototypes',
  64                 '-D_BSD_SOURCE',
  65                 '-D_DEFAULT_SOURCE',
  66                 '-D_XOPEN_SOURCE=600'
  67         ]
  68         foreach option:cflags_options
  69                 if cc.has_argument(option)
  70                         cflags += option
  71                 endif
  72         endforeach
  73         if get_option('buildtype').contains('debug')
  74                 cflags += [ '-pedantic', '-UNDEBUG', '-DPEDANTIC' ]
  75         else
  76                 cflags += [ '-DNDEBUG', '-UPEDANTIC' ]
  77         endif
  78         # To maintain the compatibility with the make build system
  79         # mlx5_autoconf.h file is still generated.
  80         # input array for meson member search:
  81         # [ "MACRO to define if found", "header for the search",
  82         #   "symbol to search", "struct member to search" ]
  83         has_member_args = [
  84                 [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  85                 'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  86                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  87                 'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  88                 [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  89                 'struct ibv_counters_init_attr', 'comp_mask' ],
  90         ]
  91         # input array for meson symbol search:
  92         # [ "MACRO to define if found", "header for the search",
  93         #   "symbol to search" ]
  94         has_sym_args = [
  95                 [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  96                 'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  97                 [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  98                 'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  99                 [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
 100                 'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
 101                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
 102                 'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
 103                 [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
 104                 'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
 105                 [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
 106                 'mlx5dv_create_flow_action_packet_reformat' ],
 107                 [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
 108                 'IBV_FLOW_SPEC_MPLS' ],
 109                 [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
 110                 'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
 111                 [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
 112                 'IBV_WQ_FLAG_RX_END_PADDING' ],
 113                 [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 114                 'mlx5dv_devx_obj_create' ],
 115                 [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 116                 'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 117                 [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 118                 'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 119                 [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 120                 'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 121                 [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 122                 'SUPPORTED_40000baseKR4_Full' ],
 123                 [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 124                 'SUPPORTED_40000baseCR4_Full' ],
 125                 [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 126                 'SUPPORTED_40000baseSR4_Full' ],
 127                 [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 128                 'SUPPORTED_40000baseLR4_Full' ],
 129                 [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 130                 'SUPPORTED_56000baseKR4_Full' ],
 131                 [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 132                 'SUPPORTED_56000baseCR4_Full' ],
 133                 [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 134                 'SUPPORTED_56000baseSR4_Full' ],
 135                 [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 136                 'SUPPORTED_56000baseLR4_Full' ],
 137                 [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 138                 'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 139                 [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 140                 'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 141                 [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 142                 'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 143                 [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 144                 'IFLA_NUM_VF' ],
 145                 [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 146                 'IFLA_EXT_MASK' ],
 147                 [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 148                 'IFLA_PHYS_SWITCH_ID' ],
 149                 [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 150                 'IFLA_PHYS_PORT_NAME' ],
 151                 [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 152                 'RDMA_NL_NLDEV' ],
 153                 [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 154                 'RDMA_NLDEV_CMD_GET' ],
 155                 [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 156                 'RDMA_NLDEV_CMD_PORT_GET' ],
 157                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 158                 'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 159                 [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 160                 'RDMA_NLDEV_ATTR_DEV_NAME' ],
 161                 [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 162                 'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 163                 [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 164                 'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 165         ]
 166         config = configuration_data()
 167         foreach arg:has_sym_args
 168                 config.set(arg[0], cc.has_header_symbol(arg[1], arg[2]))
 169         endforeach
 170         foreach arg:has_member_args
 171                 file_prefix = '#include<' + arg[1] + '>'
 172                 config.set(arg[0], cc.has_member(arg[2], arg[3],
 173                         prefix : file_prefix))
 174         endforeach
 175         configure_file(output : 'mlx5_autoconf.h', configuration : config)
 176 endif
 177 # Build Glue Library
 178 if pmd_dlopen and build
 179         dlopen_name = 'mlx5_glue'
 180         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 181         dlopen_so_version = LIB_GLUE_VERSION
 182         dlopen_sources = files('mlx5_glue.c')
 183         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 184         shared_lib = shared_library(
 185                 dlopen_lib_name,
 186                 dlopen_sources,
 187                 include_directories: global_inc,
 188                 c_args: cflags,
 189                 dependencies: libs,
 190                 link_args: [
 191                 '-Wl,-export-dynamic',
 192                 '-Wl,-h,@0@'.format(LIB_GLUE),
 193                 ],
 194                 soversion: dlopen_so_version,
 195                 install: true,
 196                 install_dir: dlopen_install_dir,
 197         )
 198 endif