examples/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 link_whole_libs = []
   5 if get_option('default_library') == 'static'
   6         link_whole_libs = dpdk_static_libraries + dpdk_drivers
   7 endif
   8
   9 execinfo = cc.find_library('execinfo', required: false)
  10
  11 # list of all example apps. Keep 1-3 per line, in alphabetical order.
  12 all_examples = [
  13         'bbdev_app', 'bond',
  14         'cmdline',
  15         'distributor', 'ethtool',
  16         'eventdev_pipeline',
  17         'fips_validation', 'flow_classify',
  18         'flow_filtering', 'helloworld',
  19         'ioat',
  20         'ip_fragmentation', 'ip_pipeline',
  21         'ip_reassembly', 'ipsec-secgw',
  22         'ipv4_multicast', 'kni',
  23         'l2fwd', 'l2fwd-cat', 'l2fwd-event',
  24         'l2fwd-crypto', 'l2fwd-jobstats',
  25         'l2fwd-keepalive', 'l3fwd',
  26         'l3fwd-acl', 'l3fwd-power', 'l3fwd-graph',
  27         'link_status_interrupt',
  28         'multi_process/client_server_mp/mp_client',
  29         'multi_process/client_server_mp/mp_server',
  30         'multi_process/hotplug_mp',
  31         'multi_process/simple_mp',
  32         'multi_process/symmetric_mp',
  33         'ntb', 'packet_ordering',
  34         'performance-thread/l3fwd-thread',
  35         'performance-thread/pthread_shim',
  36         'pipeline',
  37         'ptpclient',
  38         'qos_meter', 'qos_sched',
  39         'rxtx_callbacks',
  40         'server_node_efd/node',
  41         'server_node_efd/server',
  42         'service_cores',
  43         'skeleton',
  44         'timer', 'vdpa',
  45         'vhost', 'vhost_crypto',
  46         'vhost_blk', 'vm_power_manager',
  47         'vm_power_manager/guest_cli',
  48         'vmdq', 'vmdq_dcb',
  49 ]
  50 # install all example code on install - irrespective of whether the example in
  51 # question is to be built as part of this build or not.
  52 foreach ex:all_examples
  53         install_subdir(ex,
  54                         install_dir: get_option('datadir') + '/dpdk/examples',
  55                         exclude_files: 'meson.build')
  56 endforeach
  57
  58 if get_option('examples') == ''
  59         subdir_done()
  60 endif
  61
  62 if get_option('examples').to_lower() == 'all'
  63         examples = all_examples
  64         allow_skips = true # don't flag an error if we can't build an app
  65 else
  66         examples = get_option('examples').split(',')
  67         allow_skips = false # error out if we can't build a requested app
  68 endif
  69 default_cflags = machine_args
  70 if cc.has_argument('-Wno-format-truncation')
  71         default_cflags += '-Wno-format-truncation'
  72 endif
  73
  74 foreach example: examples
  75         name = example.split('/')[-1]
  76         build = true
  77         sources = []
  78         allow_experimental_apis = false
  79         cflags = default_cflags
  80
  81         ext_deps = [execinfo]
  82         includes = [include_directories(example)]
  83         deps = ['eal', 'mempool', 'net', 'mbuf', 'ethdev', 'cmdline']
  84         subdir(example)
  85
  86         if build
  87                 dep_objs = ext_deps
  88                 foreach d:deps
  89                         var_name = get_option('default_library') + '_rte_' + d
  90                         if not is_variable(var_name)
  91                                 error('Missing dependency "@0@" for example "@1@"'.format(d, name))
  92                         endif
  93                         dep_objs += [get_variable(var_name)]
  94                 endforeach
  95                 if allow_experimental_apis
  96                         cflags += '-DALLOW_EXPERIMENTAL_API'
  97                 endif
  98                 executable('dpdk-' + name, sources,
  99                         include_directories: includes,
 100                         link_whole: link_whole_libs,
 101                         link_args: dpdk_extra_ldflags,
 102                         c_args: cflags,
 103                         dependencies: dep_objs)
 104         elif not allow_skips
 105                 error('Cannot build requested example "' + name + '"')
 106         else
 107                 message('Skipping example "' + name + '"')
 108         endif
 109 endforeach