lib/librte_net/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2020 Intel Corporation
   3
   4 headers = files('rte_ip.h',
   5         'rte_tcp.h',
   6         'rte_udp.h',
   7         'rte_esp.h',
   8         'rte_sctp.h',
   9         'rte_icmp.h',
  10         'rte_arp.h',
  11         'rte_ether.h',
  12         'rte_vxlan.h',
  13         'rte_gre.h',
  14         'rte_gtp.h',
  15         'rte_net.h',
  16         'rte_net_crc.h',
  17         'rte_mpls.h',
  18         'rte_higig.h',
  19         'rte_ecpri.h')
  20
  21 sources = files('rte_arp.c', 'rte_ether.c', 'rte_net.c', 'rte_net_crc.c')
  22 deps += ['mbuf']
  23
  24 if dpdk_conf.has('RTE_ARCH_X86_64')
  25         net_crc_sse42_cpu_support = (
  26                 cc.get_define('__PCLMUL__', args: machine_args) != '')
  27         net_crc_avx512_cpu_support = (
  28                 cc.get_define('__AVX512F__', args: machine_args) != '' and
  29                 cc.get_define('__AVX512BW__', args: machine_args) != '' and
  30                 cc.get_define('__AVX512DQ__', args: machine_args) != '' and
  31                 cc.get_define('__AVX512VL__', args: machine_args) != '' and
  32                 cc.get_define('__VPCLMULQDQ__', args: machine_args) != '')
  33
  34         net_crc_sse42_cc_support = (
  35                 cc.has_argument('-mpclmul') and cc.has_argument('-maes'))
  36         net_crc_avx512_cc_support = (
  37                 not machine_args.contains('-mno-avx512f') and
  38                 cc.has_argument('-mavx512f') and
  39                 cc.has_argument('-mavx512bw') and
  40                 cc.has_argument('-mavx512dq') and
  41                 cc.has_argument('-mavx512vl') and
  42                 cc.has_argument('-mvpclmulqdq') and
  43                 cc.has_argument('-mavx2') and
  44                 cc.has_argument('-mavx'))
  45
  46         build_static_net_crc_sse42_lib = 0
  47         build_static_net_crc_avx512_lib = 0
  48
  49         if net_crc_sse42_cpu_support == true
  50                 sources += files('net_crc_sse.c')
  51                 cflags += ['-DCC_X86_64_SSE42_PCLMULQDQ_SUPPORT']
  52                 if net_crc_avx512_cpu_support == true
  53                         sources += files('net_crc_avx512.c')
  54                         cflags += ['-DCC_X86_64_AVX512_VPCLMULQDQ_SUPPORT']
  55                 elif net_crc_avx512_cc_support == true
  56                         build_static_net_crc_avx512_lib = 1
  57                         net_crc_avx512_lib_cflags = ['-mavx512f',
  58                                                         '-mavx512bw',
  59                                                         '-mavx512dq',
  60                                                         '-mavx512vl',
  61                                                         '-mvpclmulqdq',
  62                                                         '-mavx2',
  63                                                         '-mavx']
  64                         cflags += ['-DCC_X86_64_AVX512_VPCLMULQDQ_SUPPORT']
  65                 endif
  66         elif net_crc_sse42_cc_support == true
  67                 build_static_net_crc_sse42_lib = 1
  68                 net_crc_sse42_lib_cflags = ['-mpclmul', '-maes']
  69                 cflags += ['-DCC_X86_64_SSE42_PCLMULQDQ_SUPPORT']
  70                 if net_crc_avx512_cc_support == true
  71                         build_static_net_crc_avx512_lib = 1
  72                         net_crc_avx512_lib_cflags = ['-mpclmul',
  73                                                         '-maes',
  74                                                         '-mavx512f',
  75                                                         '-mavx512bw',
  76                                                         '-mavx512dq',
  77                                                         '-mavx512vl',
  78                                                         '-mvpclmulqdq',
  79                                                         '-mavx2',
  80                                                         '-mavx']
  81                         cflags += ['-DCC_X86_64_AVX512_VPCLMULQDQ_SUPPORT']
  82                 endif
  83         endif
  84
  85         if build_static_net_crc_sse42_lib == 1
  86                 net_crc_sse42_lib = static_library(
  87                                         'net_crc_sse42_lib',
  88                                         'net_crc_sse.c',
  89                                         dependencies: static_rte_eal,
  90                                         c_args: [cflags,
  91                                                 net_crc_sse42_lib_cflags])
  92                 objs += net_crc_sse42_lib.extract_objects('net_crc_sse.c')
  93         endif
  94
  95         if build_static_net_crc_avx512_lib == 1
  96                 net_crc_avx512_lib = static_library(
  97                                         'net_crc_avx512_lib',
  98                                         'net_crc_avx512.c',
  99                                         dependencies: static_rte_eal,
 100                                         c_args: [cflags,
 101                                                 net_crc_avx512_lib_cflags])
 102                 objs += net_crc_avx512_lib.extract_objects('net_crc_avx512.c')
 103         endif
 104
 105 elif (dpdk_conf.has('RTE_ARCH_ARM64') and
 106                 cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != '')
 107         sources += files('net_crc_neon.c')
 108         cflags += ['-DCC_ARM64_NEON_PMULL_SUPPORT']
 109 endif