lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool',
  18         'mbuf',
  19         'net',
  20         'meter',
  21         'ethdev',
  22         'pci', # core
  23         'cmdline',
  24         'metrics', # bitrate/latency stats depends on this
  25         'hash',    # efd depends on this
  26         'timer',   # eventdev depends on this
  27         'acl',
  28         'bbdev',
  29         'bitratestats',
  30         'cfgfile',
  31         'compressdev',
  32         'cryptodev',
  33         'distributor',
  34         'efd',
  35         'eventdev',
  36         'gro',
  37         'gso',
  38         'ip_frag',
  39         'jobstats',
  40         'kni',
  41         'latencystats',
  42         'lpm',
  43         'member',
  44         'power',
  45         'pdump',
  46         'rawdev',
  47         'regexdev',
  48         'rib',
  49         'reorder',
  50         'sched',
  51         'security',
  52         'stack',
  53         'vhost',
  54         'ipsec', # ipsec lib depends on net, crypto and security
  55         'fib', #fib lib depends on rib
  56         'port', # pkt framework libs which use other libs from above
  57         'table',
  58         'pipeline',
  59         'flow_classify', # flow_classify lib depends on pkt framework table lib
  60         'bpf',
  61         'graph',
  62         'node',
  63 ]
  64
  65 if is_windows
  66     libraries = [
  67             'kvargs',
  68             'telemetry',
  69             'eal',
  70             'ring',
  71             'rcu',
  72             'mempool',
  73             'mbuf',
  74             'net',
  75             'meter',
  76             'ethdev',
  77             'pci',
  78             'cmdline',
  79             'metrics',
  80             'hash',
  81             'timer',
  82             'bitratestats',
  83             'cfgfile',
  84             'gro',
  85             'gso',
  86             'latencystats',
  87             'pdump',
  88     ] # only supported libraries for windows
  89 endif
  90
  91 optional_libs = [
  92         'kni',
  93         'power',
  94         'vhost',
  95 ]
  96
  97 disabled_libs = []
  98 opt_disabled_libs = run_command(list_dir_globs, get_option('disable_libs'),
  99         check: true).stdout().split()
 100 foreach l:opt_disabled_libs
 101     if not optional_libs.contains(l)
 102         warning('Cannot disable mandatory library "@0@"'.format(l))
 103         continue
 104     endif
 105     disabled_libs += l
 106 endforeach
 107
 108
 109 default_cflags = machine_args
 110 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
 111 default_cflags += ['-DALLOW_INTERNAL_API']
 112
 113 if cc.has_argument('-Wno-format-truncation')
 114     default_cflags += '-Wno-format-truncation'
 115 endif
 116
 117 enabled_libs = [] # used to print summary at the end
 118
 119 foreach l:libraries
 120     build = true
 121     reason = '<unknown reason>' # set if build == false to explain why
 122     name = l
 123     use_function_versioning = false
 124     sources = []
 125     headers = []
 126     indirect_headers = [] # public headers not directly included by apps
 127     driver_sdk_headers = [] # public headers included by drivers
 128     includes = []
 129     cflags = default_cflags
 130     objs = [] # other object files to link against, used e.g. for
 131               # instruction-set optimized versions of code
 132
 133     # use "deps" for internal DPDK dependencies, and "ext_deps" for
 134     # external package/library requirements
 135     ext_deps = []
 136     deps = []
 137     # eal is standard dependency once built
 138     if dpdk_conf.has('RTE_LIB_EAL')
 139         deps += ['eal']
 140     endif
 141
 142     if disabled_libs.contains(l)
 143         build = false
 144         reason = 'explicitly disabled via build config'
 145     else
 146         subdir(l)
 147     endif
 148     if name != l
 149         warning('Library name, "@0@", and directory name, "@1@", do not match'.format(name, l))
 150     endif
 151
 152     if not build
 153         dpdk_libs_disabled += name
 154         set_variable(name.underscorify() + '_disable_reason', reason)
 155         continue
 156     endif
 157
 158     shared_deps = ext_deps
 159     static_deps = ext_deps
 160     foreach d:deps
 161         if not is_variable('shared_rte_' + d)
 162             error('Missing internal dependency "@0@" for @1@ [@2@]'
 163                     .format(d, name, 'lib/' + l))
 164         endif
 165         shared_deps += [get_variable('shared_rte_' + d)]
 166         static_deps += [get_variable('static_rte_' + d)]
 167     endforeach
 168
 169     enabled_libs += name
 170     dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1)
 171     install_headers(headers)
 172     install_headers(indirect_headers)
 173     if get_option('enable_driver_sdk')
 174         install_headers(driver_sdk_headers)
 175     endif
 176     dpdk_chkinc_headers += headers
 177
 178     libname = 'rte_' + name
 179     includes += include_directories(l)
 180
 181     if developer_mode and is_windows and use_function_versioning
 182         message('@0@: Function versioning is not supported by Windows.'.format(name))
 183     endif
 184
 185     if use_function_versioning
 186         cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 187     endif
 188     cflags += '-DRTE_LOG_DEFAULT_LOGTYPE=lib.' + l
 189
 190     # first build static lib
 191     static_lib = static_library(libname,
 192             sources,
 193             objects: objs,
 194             c_args: cflags,
 195             dependencies: static_deps,
 196             include_directories: includes,
 197             install: true)
 198     static_dep = declare_dependency(
 199             include_directories: includes,
 200             dependencies: static_deps)
 201
 202     if not use_function_versioning or is_windows
 203         # use pre-build objects to build shared lib
 204         sources = []
 205         objs += static_lib.extract_all_objects(recursive: false)
 206     else
 207         # for compat we need to rebuild with
 208         # RTE_BUILD_SHARED_LIB defined
 209         cflags += '-DRTE_BUILD_SHARED_LIB'
 210     endif
 211     version_map = '@0@/@1@/version.map'.format(
 212             meson.current_source_dir(), l)
 213     implib = 'librte_' + l + '.dll.a'
 214
 215     def_file = custom_target(libname + '_def',
 216             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 217             input: version_map,
 218             output: '@0@_exports.def'.format(libname))
 219
 220     mingw_map = custom_target(libname + '_mingw',
 221             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 222             input: version_map,
 223             output: '@0@_mingw.map'.format(libname))
 224
 225     if is_ms_linker
 226         lk_args = ['-Wl,/def:' + def_file.full_path()]
 227         if meson.version().version_compare('<0.54.0')
 228             lk_args += ['-Wl,/implib:lib\\' + implib]
 229         endif
 230     else
 231         if is_windows
 232             lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 233         else
 234             lk_args = ['-Wl,--version-script=' + version_map]
 235         endif
 236     endif
 237
 238     lk_deps = [version_map, def_file, mingw_map]
 239     if developer_mode and not is_windows
 240         # on unix systems check the output of the
 241         # check-symbols.sh script, using it as a
 242         # dependency of the .so build
 243         lk_deps += custom_target(name + '.sym_chk',
 244                 command: [check_symbols,
 245                     version_map, '@INPUT@'],
 246                 capture: true,
 247                 input: static_lib,
 248                 output: name + '.sym_chk')
 249     endif
 250
 251     shared_lib = shared_library(libname,
 252             sources,
 253             objects: objs,
 254             c_args: cflags,
 255             dependencies: shared_deps,
 256             include_directories: includes,
 257             link_args: lk_args,
 258             link_depends: lk_deps,
 259             version: abi_version,
 260             soversion: so_version,
 261             install: true)
 262     shared_dep = declare_dependency(link_with: shared_lib,
 263             include_directories: includes,
 264             dependencies: shared_deps)
 265
 266     dpdk_libraries = [shared_lib] + dpdk_libraries
 267     dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 268
 269     set_variable('shared_rte_' + name, shared_dep)
 270     set_variable('static_rte_' + name, static_dep)
 271     if developer_mode
 272         message('lib/@0@: Defining dependency "@1@"'.format(l, name))
 273     endif
 274 endforeach