lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  18         'cmdline',
  19         'metrics', # bitrate/latency stats depends on this
  20         'hash',    # efd depends on this
  21         'timer',   # eventdev depends on this
  22         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  23         'compressdev', 'cryptodev',
  24         'distributor', 'efd', 'eventdev',
  25         'gro', 'gso', 'ip_frag', 'jobstats',
  26         'kni', 'latencystats', 'lpm', 'member',
  27         'power', 'pdump', 'rawdev', 'regexdev',
  28         'rib', 'reorder', 'sched', 'security', 'stack', 'vhost',
  29         # ipsec lib depends on net, crypto and security
  30         'ipsec',
  31         #fib lib depends on rib
  32         'fib',
  33         # add pkt framework libs which use other libs from above
  34         'port', 'table', 'pipeline',
  35         # flow_classify lib depends on pkt framework table lib
  36         'flow_classify', 'bpf', 'graph', 'node']
  37
  38 if is_windows
  39         libraries = [
  40                 'kvargs',
  41                 'telemetry',
  42                 'eal',
  43                 'ring',
  44                 'rcu',
  45                 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci',
  46                 'cmdline',
  47                 'hash',
  48         ] # only supported libraries for windows
  49 endif
  50
  51 default_cflags = machine_args
  52 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  53 default_cflags += ['-DALLOW_INTERNAL_API']
  54
  55 if cc.has_argument('-Wno-format-truncation')
  56         default_cflags += '-Wno-format-truncation'
  57 endif
  58
  59 enabled_libs = [] # used to print summary at the end
  60
  61 foreach l:libraries
  62         build = true
  63         reason = '<unknown reason>' # set if build == false to explain why
  64         name = l
  65         use_function_versioning = false
  66         sources = []
  67         headers = []
  68         includes = []
  69         cflags = default_cflags
  70         objs = [] # other object files to link against, used e.g. for
  71                   # instruction-set optimized versions of code
  72
  73         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  74         # external package/library requirements
  75         ext_deps = []
  76         deps = []
  77         # eal is standard dependency once built
  78         if dpdk_conf.has('RTE_LIB_EAL')
  79                 deps += ['eal']
  80         endif
  81
  82         dir_name = 'librte_' + l
  83         subdir(dir_name)
  84
  85         if build
  86                 shared_deps = ext_deps
  87                 static_deps = ext_deps
  88                 foreach d:deps
  89                         if not is_variable('shared_rte_' + d)
  90                                 error('Missing internal dependency "@0@" for @1@ [@2@]'
  91                                                 .format(d, name, 'lib/' + dir_name))
  92                         endif
  93                         shared_deps += [get_variable('shared_rte_' + d)]
  94                         static_deps += [get_variable('static_rte_' + d)]
  95                 endforeach
  96         endif
  97
  98         if not build
  99                 dpdk_libs_disabled += name
 100                 set_variable(name.underscorify() + '_disable_reason', reason)
 101         else
 102                 enabled_libs += name
 103                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1) #old macro
 104                 dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1) # new macro
 105                 install_headers(headers)
 106
 107                 libname = 'rte_' + name
 108                 includes += include_directories(dir_name)
 109
 110                 if sources.length() == 0
 111                         # if no C files, just set a dependency on header path
 112                         shared_dep = declare_dependency(include_directories: includes)
 113                         static_dep = shared_dep
 114                 else
 115                         if is_windows and use_function_versioning
 116                                 message('@0@: Function versioning is not supported by Windows.'
 117                                 .format(name))
 118                         endif
 119
 120                         if use_function_versioning
 121                                 cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 122                         endif
 123
 124                         # first build static lib
 125                         static_lib = static_library(libname,
 126                                         sources,
 127                                         objects: objs,
 128                                         c_args: cflags,
 129                                         dependencies: static_deps,
 130                                         include_directories: includes,
 131                                         install: true)
 132                         static_dep = declare_dependency(
 133                                         include_directories: includes,
 134                                         dependencies: static_deps)
 135
 136                         if not use_function_versioning or is_windows
 137                                 # use pre-build objects to build shared lib
 138                                 sources = []
 139                                 objs += static_lib.extract_all_objects(recursive: false)
 140                         else
 141                                 # for compat we need to rebuild with
 142                                 # RTE_BUILD_SHARED_LIB defined
 143                                 cflags += '-DRTE_BUILD_SHARED_LIB'
 144                         endif
 145                         version_map = '@0@/@1@/version.map'.format(
 146                                         meson.current_source_dir(), dir_name)
 147                         implib = dir_name + '.dll.a'
 148
 149                         def_file = custom_target(libname + '_def',
 150                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 151                                 input: version_map,
 152                                 output: '@0@_exports.def'.format(libname))
 153
 154                         mingw_map = custom_target(libname + '_mingw',
 155                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 156                                 input: version_map,
 157                                 output: '@0@_mingw.map'.format(libname))
 158
 159                         if is_ms_linker
 160                                 lk_args = ['-Wl,/def:' + def_file.full_path()]
 161                                 if meson.version().version_compare('<0.54.0')
 162                                         lk_args += ['-Wl,/implib:lib\\' + implib]
 163                                 endif
 164                         else
 165                                 if is_windows
 166                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 167                                 else
 168                                         lk_args = ['-Wl,--version-script=' + version_map]
 169                                 endif
 170                         endif
 171
 172                         lk_deps = [version_map, def_file, mingw_map]
 173                         if not is_windows
 174                                 # on unix systems check the output of the
 175                                 # check-symbols.sh script, using it as a
 176                                 # dependency of the .so build
 177                                 lk_deps += custom_target(name + '.sym_chk',
 178                                         command: [check_symbols,
 179                                                 version_map, '@INPUT@'],
 180                                         capture: true,
 181                                         input: static_lib,
 182                                         output: name + '.sym_chk')
 183                         endif
 184
 185                         shared_lib = shared_library(libname,
 186                                         sources,
 187                                         objects: objs,
 188                                         c_args: cflags,
 189                                         dependencies: shared_deps,
 190                                         include_directories: includes,
 191                                         link_args: lk_args,
 192                                         link_depends: lk_deps,
 193                                         version: abi_version,
 194                                         soversion: so_version,
 195                                         install: true)
 196                         shared_dep = declare_dependency(link_with: shared_lib,
 197                                         include_directories: includes,
 198                                         dependencies: shared_deps)
 199
 200                         dpdk_libraries = [shared_lib] + dpdk_libraries
 201                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 202                 endif # sources.length() > 0
 203
 204                 set_variable('shared_rte_' + name, shared_dep)
 205                 set_variable('static_rte_' + name, static_dep)
 206                 message('lib/@0@: Defining dependency "@1@"'.format(
 207                                 dir_name, name))
 208         endif # if build
 209 endforeach