lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  18         'cmdline',
  19         'metrics', # bitrate/latency stats depends on this
  20         'hash',    # efd depends on this
  21         'timer',   # eventdev depends on this
  22         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  23         'compressdev', 'cryptodev',
  24         'distributor', 'efd', 'eventdev',
  25         'gro', 'gso', 'ip_frag', 'jobstats',
  26         'kni', 'latencystats', 'lpm', 'member',
  27         'power', 'pdump', 'rawdev', 'regexdev',
  28         'rib', 'reorder', 'sched', 'security', 'stack', 'vhost',
  29         # ipsec lib depends on net, crypto and security
  30         'ipsec',
  31         #fib lib depends on rib
  32         'fib',
  33         # add pkt framework libs which use other libs from above
  34         'port', 'table', 'pipeline',
  35         # flow_classify lib depends on pkt framework table lib
  36         'flow_classify', 'bpf', 'graph', 'node']
  37
  38 if is_windows
  39         libraries = [
  40                 'kvargs',
  41                 'telemetry',
  42                 'eal',
  43                 'ring',
  44                 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci',
  45         ] # only supported libraries for windows
  46 endif
  47
  48 default_cflags = machine_args
  49 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  50 default_cflags += ['-DALLOW_INTERNAL_API']
  51
  52 if cc.has_argument('-Wno-format-truncation')
  53         default_cflags += '-Wno-format-truncation'
  54 endif
  55
  56 enabled_libs = [] # used to print summary at the end
  57
  58 foreach l:libraries
  59         build = true
  60         reason = '<unknown reason>' # set if build == false to explain why
  61         name = l
  62         use_function_versioning = false
  63         sources = []
  64         headers = []
  65         includes = []
  66         cflags = default_cflags
  67         objs = [] # other object files to link against, used e.g. for
  68                   # instruction-set optimized versions of code
  69
  70         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  71         # external package/library requirements
  72         ext_deps = []
  73         deps = []
  74         # eal is standard dependency once built
  75         if dpdk_conf.has('RTE_LIBRTE_EAL')
  76                 deps += ['eal']
  77         endif
  78
  79         dir_name = 'librte_' + l
  80         subdir(dir_name)
  81
  82         if build
  83                 shared_deps = ext_deps
  84                 static_deps = ext_deps
  85                 foreach d:deps
  86                         if not is_variable('shared_rte_' + d)
  87                                 error('Missing internal dependency "@0@" for @1@ [@2@]'
  88                                                 .format(d, name, 'lib/' + dir_name))
  89                         endif
  90                         shared_deps += [get_variable('shared_rte_' + d)]
  91                         static_deps += [get_variable('static_rte_' + d)]
  92                 endforeach
  93         endif
  94
  95         if not build
  96                 dpdk_libs_disabled += name
  97                 set_variable(name.underscorify() + '_disable_reason', reason)
  98         else
  99                 enabled_libs += name
 100                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1)
 101                 install_headers(headers)
 102
 103                 libname = 'rte_' + name
 104                 includes += include_directories(dir_name)
 105
 106                 if sources.length() == 0
 107                         # if no C files, just set a dependency on header path
 108                         shared_dep = declare_dependency(include_directories: includes)
 109                         static_dep = shared_dep
 110                 else
 111                         if is_windows and use_function_versioning
 112                                 message('@0@: Function versioning is not supported by Windows.'
 113                                 .format(name))
 114                         endif
 115
 116                         if use_function_versioning
 117                                 cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 118                         endif
 119
 120                         # first build static lib
 121                         static_lib = static_library(libname,
 122                                         sources,
 123                                         objects: objs,
 124                                         c_args: cflags,
 125                                         dependencies: static_deps,
 126                                         include_directories: includes,
 127                                         install: true)
 128                         static_dep = declare_dependency(
 129                                         include_directories: includes,
 130                                         dependencies: static_deps)
 131
 132                         if not use_function_versioning or is_windows
 133                                 # use pre-build objects to build shared lib
 134                                 sources = []
 135                                 objs += static_lib.extract_all_objects(recursive: false)
 136                         else
 137                                 # for compat we need to rebuild with
 138                                 # RTE_BUILD_SHARED_LIB defined
 139                                 cflags += '-DRTE_BUILD_SHARED_LIB'
 140                         endif
 141                         version_map = '@0@/@1@/rte_@2@_version.map'.format(
 142                                         meson.current_source_dir(), dir_name, name)
 143                         implib = dir_name + '.dll.a'
 144
 145                         def_file = custom_target(libname + '_def',
 146                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 147                                 input: version_map,
 148                                 output: '@0@_exports.def'.format(libname))
 149
 150                         mingw_map = custom_target(libname + '_mingw',
 151                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 152                                 input: version_map,
 153                                 output: '@0@_mingw.map'.format(libname))
 154
 155                         if is_ms_linker
 156                                 lk_args = ['-Wl,/def:' + def_file.full_path(),
 157                                         '-Wl,/implib:lib\\' + implib]
 158                         else
 159                                 if is_windows
 160                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 161                                 else
 162                                         lk_args = ['-Wl,--version-script=' + version_map]
 163                                 endif
 164                         endif
 165
 166                         lk_deps = [version_map, def_file, mingw_map]
 167                         if not is_windows
 168                                 # on unix systems check the output of the
 169                                 # check-symbols.sh script, using it as a
 170                                 # dependency of the .so build
 171                                 lk_deps += custom_target(name + '.sym_chk',
 172                                         command: [check_symbols,
 173                                                 version_map, '@INPUT@'],
 174                                         capture: true,
 175                                         input: static_lib,
 176                                         output: name + '.sym_chk')
 177                         endif
 178
 179                         shared_lib = shared_library(libname,
 180                                         sources,
 181                                         objects: objs,
 182                                         c_args: cflags,
 183                                         dependencies: shared_deps,
 184                                         include_directories: includes,
 185                                         link_args: lk_args,
 186                                         link_depends: lk_deps,
 187                                         version: abi_version,
 188                                         soversion: so_version,
 189                                         install: true)
 190                         shared_dep = declare_dependency(link_with: shared_lib,
 191                                         include_directories: includes,
 192                                         dependencies: shared_deps)
 193
 194                         dpdk_libraries = [shared_lib] + dpdk_libraries
 195                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 196                 endif # sources.length() > 0
 197
 198                 set_variable('shared_rte_' + name, shared_dep)
 199                 set_variable('static_rte_' + name, static_dep)
 200                 message('lib/@0@: Defining dependency "@1@"'.format(
 201                                 dir_name, name))
 202         endif # if build
 203 endforeach