lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool',
  18         'mbuf',
  19         'net',
  20         'meter',
  21         'ethdev',
  22         'pci', # core
  23         'cmdline',
  24         'metrics', # bitrate/latency stats depends on this
  25         'hash',    # efd depends on this
  26         'timer',   # eventdev depends on this
  27         'acl',
  28         'bbdev',
  29         'bitratestats',
  30         'cfgfile',
  31         'compressdev',
  32         'cryptodev',
  33         'distributor',
  34         'efd',
  35         'eventdev',
  36         'gro',
  37         'gso',
  38         'ip_frag',
  39         'jobstats',
  40         'kni',
  41         'latencystats',
  42         'lpm',
  43         'member',
  44         'power',
  45         'pdump',
  46         'rawdev',
  47         'regexdev',
  48         'rib',
  49         'reorder',
  50         'sched',
  51         'security',
  52         'stack',
  53         'vhost',
  54         'ipsec', # ipsec lib depends on net, crypto and security
  55         'fib', #fib lib depends on rib
  56         'port', # pkt framework libs which use other libs from above
  57         'table',
  58         'pipeline',
  59         'flow_classify', # flow_classify lib depends on pkt framework table lib
  60         'bpf',
  61         'graph',
  62         'node',
  63 ]
  64
  65 if is_windows
  66     libraries = [
  67             'kvargs',
  68             'telemetry',
  69             'eal',
  70             'ring',
  71             'rcu',
  72             'mempool',
  73             'mbuf',
  74             'net',
  75             'meter',
  76             'ethdev',
  77             'pci',
  78             'cmdline',
  79             'hash',
  80             'cfgfile',
  81     ] # only supported libraries for windows
  82 endif
  83
  84 default_cflags = machine_args
  85 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  86 default_cflags += ['-DALLOW_INTERNAL_API']
  87
  88 if cc.has_argument('-Wno-format-truncation')
  89     default_cflags += '-Wno-format-truncation'
  90 endif
  91
  92 enabled_libs = [] # used to print summary at the end
  93
  94 foreach l:libraries
  95     build = true
  96     reason = '<unknown reason>' # set if build == false to explain why
  97     name = l
  98     use_function_versioning = false
  99     sources = []
 100     headers = []
 101     indirect_headers = [] # public headers not directly included by apps
 102     driver_sdk_headers = [] # public headers included by drivers
 103     includes = []
 104     cflags = default_cflags
 105     objs = [] # other object files to link against, used e.g. for
 106               # instruction-set optimized versions of code
 107
 108     # use "deps" for internal DPDK dependencies, and "ext_deps" for
 109     # external package/library requirements
 110     ext_deps = []
 111     deps = []
 112     # eal is standard dependency once built
 113     if dpdk_conf.has('RTE_LIB_EAL')
 114         deps += ['eal']
 115     endif
 116
 117     dir_name = 'librte_' + l
 118     subdir(dir_name)
 119
 120     if not build
 121         dpdk_libs_disabled += name
 122         set_variable(name.underscorify() + '_disable_reason', reason)
 123         continue
 124     endif
 125
 126     shared_deps = ext_deps
 127     static_deps = ext_deps
 128     foreach d:deps
 129         if not is_variable('shared_rte_' + d)
 130             error('Missing internal dependency "@0@" for @1@ [@2@]'
 131                     .format(d, name, 'lib/' + dir_name))
 132         endif
 133         shared_deps += [get_variable('shared_rte_' + d)]
 134         static_deps += [get_variable('static_rte_' + d)]
 135     endforeach
 136
 137     enabled_libs += name
 138     dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1)
 139     install_headers(headers)
 140     install_headers(indirect_headers)
 141     if get_option('enable_driver_sdk')
 142         install_headers(driver_sdk_headers)
 143     endif
 144     dpdk_chkinc_headers += headers
 145
 146     libname = 'rte_' + name
 147     includes += include_directories(dir_name)
 148
 149     if is_windows and use_function_versioning
 150         message('@0@: Function versioning is not supported by Windows.'.format(name))
 151     endif
 152
 153     if use_function_versioning
 154         cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 155     endif
 156
 157     # first build static lib
 158     static_lib = static_library(libname,
 159             sources,
 160             objects: objs,
 161             c_args: cflags,
 162             dependencies: static_deps,
 163             include_directories: includes,
 164             install: true)
 165     static_dep = declare_dependency(
 166             include_directories: includes,
 167             dependencies: static_deps)
 168
 169     if not use_function_versioning or is_windows
 170         # use pre-build objects to build shared lib
 171         sources = []
 172         objs += static_lib.extract_all_objects(recursive: false)
 173     else
 174         # for compat we need to rebuild with
 175         # RTE_BUILD_SHARED_LIB defined
 176         cflags += '-DRTE_BUILD_SHARED_LIB'
 177     endif
 178     version_map = '@0@/@1@/version.map'.format(
 179             meson.current_source_dir(), dir_name)
 180     implib = dir_name + '.dll.a'
 181
 182     def_file = custom_target(libname + '_def',
 183             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 184             input: version_map,
 185             output: '@0@_exports.def'.format(libname))
 186
 187     mingw_map = custom_target(libname + '_mingw',
 188             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 189             input: version_map,
 190             output: '@0@_mingw.map'.format(libname))
 191
 192     if is_ms_linker
 193         lk_args = ['-Wl,/def:' + def_file.full_path()]
 194         if meson.version().version_compare('<0.54.0')
 195             lk_args += ['-Wl,/implib:lib\\' + implib]
 196         endif
 197     else
 198         if is_windows
 199             lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 200         else
 201             lk_args = ['-Wl,--version-script=' + version_map]
 202         endif
 203     endif
 204
 205     lk_deps = [version_map, def_file, mingw_map]
 206     if not is_windows
 207         # on unix systems check the output of the
 208         # check-symbols.sh script, using it as a
 209         # dependency of the .so build
 210         lk_deps += custom_target(name + '.sym_chk',
 211                 command: [check_symbols,
 212                     version_map, '@INPUT@'],
 213                 capture: true,
 214                 input: static_lib,
 215                 output: name + '.sym_chk')
 216     endif
 217
 218     shared_lib = shared_library(libname,
 219             sources,
 220             objects: objs,
 221             c_args: cflags,
 222             dependencies: shared_deps,
 223             include_directories: includes,
 224             link_args: lk_args,
 225             link_depends: lk_deps,
 226             version: abi_version,
 227             soversion: so_version,
 228             install: true)
 229     shared_dep = declare_dependency(link_with: shared_lib,
 230             include_directories: includes,
 231             dependencies: shared_deps)
 232
 233     dpdk_libraries = [shared_lib] + dpdk_libraries
 234     dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 235
 236     set_variable('shared_rte_' + name, shared_dep)
 237     set_variable('static_rte_' + name, static_dep)
 238     if developer_mode
 239         message('lib/@0@: Defining dependency "@1@"'.format(dir_name, name))
 240     endif
 241 endforeach