lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  18         'cmdline',
  19         'metrics', # bitrate/latency stats depends on this
  20         'hash',    # efd depends on this
  21         'timer',   # eventdev depends on this
  22         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  23         'compressdev', 'cryptodev',
  24         'distributor', 'efd', 'eventdev',
  25         'gro', 'gso', 'ip_frag', 'jobstats',
  26         'kni', 'latencystats', 'lpm', 'member',
  27         'power', 'pdump', 'rawdev', 'regexdev',
  28         'rib', 'reorder', 'sched', 'security', 'stack', 'vhost',
  29         # ipsec lib depends on net, crypto and security
  30         'ipsec',
  31         #fib lib depends on rib
  32         'fib',
  33         # add pkt framework libs which use other libs from above
  34         'port', 'table', 'pipeline',
  35         # flow_classify lib depends on pkt framework table lib
  36         'flow_classify', 'bpf', 'graph', 'node']
  37
  38 if is_windows
  39         libraries = [
  40                 'kvargs',
  41                 'telemetry',
  42                 'eal',
  43                 'ring',
  44                 'rcu',
  45                 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci',
  46                 'cmdline',
  47                 'hash',
  48                 'cfgfile',
  49         ] # only supported libraries for windows
  50 endif
  51
  52 default_cflags = machine_args
  53 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  54 default_cflags += ['-DALLOW_INTERNAL_API']
  55
  56 if cc.has_argument('-Wno-format-truncation')
  57         default_cflags += '-Wno-format-truncation'
  58 endif
  59
  60 enabled_libs = [] # used to print summary at the end
  61
  62 foreach l:libraries
  63         build = true
  64         reason = '<unknown reason>' # set if build == false to explain why
  65         name = l
  66         use_function_versioning = false
  67         sources = []
  68         headers = []
  69         includes = []
  70         cflags = default_cflags
  71         objs = [] # other object files to link against, used e.g. for
  72                   # instruction-set optimized versions of code
  73
  74         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  75         # external package/library requirements
  76         ext_deps = []
  77         deps = []
  78         # eal is standard dependency once built
  79         if dpdk_conf.has('RTE_LIB_EAL')
  80                 deps += ['eal']
  81         endif
  82
  83         dir_name = 'librte_' + l
  84         subdir(dir_name)
  85
  86         if build
  87                 shared_deps = ext_deps
  88                 static_deps = ext_deps
  89                 foreach d:deps
  90                         if not is_variable('shared_rte_' + d)
  91                                 error('Missing internal dependency "@0@" for @1@ [@2@]'
  92                                                 .format(d, name, 'lib/' + dir_name))
  93                         endif
  94                         shared_deps += [get_variable('shared_rte_' + d)]
  95                         static_deps += [get_variable('static_rte_' + d)]
  96                 endforeach
  97         endif
  98
  99         if not build
 100                 dpdk_libs_disabled += name
 101                 set_variable(name.underscorify() + '_disable_reason', reason)
 102         else
 103                 enabled_libs += name
 104                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1) #old macro
 105                 dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1) # new macro
 106                 install_headers(headers)
 107
 108                 libname = 'rte_' + name
 109                 includes += include_directories(dir_name)
 110
 111                 if sources.length() == 0
 112                         # if no C files, just set a dependency on header path
 113                         shared_dep = declare_dependency(include_directories: includes)
 114                         static_dep = shared_dep
 115                 else
 116                         if is_windows and use_function_versioning
 117                                 message('@0@: Function versioning is not supported by Windows.'
 118                                 .format(name))
 119                         endif
 120
 121                         if use_function_versioning
 122                                 cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 123                         endif
 124
 125                         # first build static lib
 126                         static_lib = static_library(libname,
 127                                         sources,
 128                                         objects: objs,
 129                                         c_args: cflags,
 130                                         dependencies: static_deps,
 131                                         include_directories: includes,
 132                                         install: true)
 133                         static_dep = declare_dependency(
 134                                         include_directories: includes,
 135                                         dependencies: static_deps)
 136
 137                         if not use_function_versioning or is_windows
 138                                 # use pre-build objects to build shared lib
 139                                 sources = []
 140                                 objs += static_lib.extract_all_objects(recursive: false)
 141                         else
 142                                 # for compat we need to rebuild with
 143                                 # RTE_BUILD_SHARED_LIB defined
 144                                 cflags += '-DRTE_BUILD_SHARED_LIB'
 145                         endif
 146                         version_map = '@0@/@1@/version.map'.format(
 147                                         meson.current_source_dir(), dir_name)
 148                         implib = dir_name + '.dll.a'
 149
 150                         def_file = custom_target(libname + '_def',
 151                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 152                                 input: version_map,
 153                                 output: '@0@_exports.def'.format(libname))
 154
 155                         mingw_map = custom_target(libname + '_mingw',
 156                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 157                                 input: version_map,
 158                                 output: '@0@_mingw.map'.format(libname))
 159
 160                         if is_ms_linker
 161                                 lk_args = ['-Wl,/def:' + def_file.full_path()]
 162                                 if meson.version().version_compare('<0.54.0')
 163                                         lk_args += ['-Wl,/implib:lib\\' + implib]
 164                                 endif
 165                         else
 166                                 if is_windows
 167                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 168                                 else
 169                                         lk_args = ['-Wl,--version-script=' + version_map]
 170                                 endif
 171                         endif
 172
 173                         lk_deps = [version_map, def_file, mingw_map]
 174                         if not is_windows
 175                                 # on unix systems check the output of the
 176                                 # check-symbols.sh script, using it as a
 177                                 # dependency of the .so build
 178                                 lk_deps += custom_target(name + '.sym_chk',
 179                                         command: [check_symbols,
 180                                                 version_map, '@INPUT@'],
 181                                         capture: true,
 182                                         input: static_lib,
 183                                         output: name + '.sym_chk')
 184                         endif
 185
 186                         shared_lib = shared_library(libname,
 187                                         sources,
 188                                         objects: objs,
 189                                         c_args: cflags,
 190                                         dependencies: shared_deps,
 191                                         include_directories: includes,
 192                                         link_args: lk_args,
 193                                         link_depends: lk_deps,
 194                                         version: abi_version,
 195                                         soversion: so_version,
 196                                         install: true)
 197                         shared_dep = declare_dependency(link_with: shared_lib,
 198                                         include_directories: includes,
 199                                         dependencies: shared_deps)
 200
 201                         dpdk_libraries = [shared_lib] + dpdk_libraries
 202                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 203                 endif # sources.length() > 0
 204
 205                 set_variable('shared_rte_' + name, shared_dep)
 206                 set_variable('static_rte_' + name, static_dep)
 207                 message('lib/@0@: Defining dependency "@1@"'.format(
 208                                 dir_name, name))
 209         endif # if build
 210 endforeach