meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 project('DPDK', 'C',
   5         # Get version number from file.
   6         # Fallback to "more" for Windows compatibility.
   7         version: run_command(find_program('cat', 'more'),
   8                 files('VERSION')).stdout().strip(),
   9         license: 'BSD',
  10         default_options: ['buildtype=release', 'default_library=static'],
  11         meson_version: '>= 0.47.1'
  12 )
  13
  14 # set up some global vars for compiler, platform, configuration, etc.
  15 cc = meson.get_compiler('c')
  16 dpdk_conf = configuration_data()
  17 dpdk_libraries = []
  18 dpdk_static_libraries = []
  19 dpdk_driver_classes = []
  20 dpdk_drivers = []
  21 dpdk_extra_ldflags = []
  22 dpdk_libs_disabled = []
  23 dpdk_drvs_disabled = []
  24 abi_version_file = files('ABI_VERSION')
  25
  26 if host_machine.cpu_family().startswith('x86')
  27         arch_subdir = 'x86'
  28 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
  29         arch_subdir = 'arm'
  30 elif host_machine.cpu_family().startswith('ppc')
  31         arch_subdir = 'ppc'
  32 endif
  33
  34 # configure the build, and make sure configs here and in config folder are
  35 # able to be included in any file. We also store a global array of include dirs
  36 # for passing to pmdinfogen scripts
  37 global_inc = include_directories('.', 'config',
  38         'lib/librte_eal/include',
  39         'lib/librte_eal/@0@/include'.format(host_machine.system()),
  40         'lib/librte_eal/@0@/include'.format(arch_subdir),
  41 )
  42
  43 # do configuration and get tool paths
  44 subdir('buildtools')
  45 subdir('config')
  46
  47 # build libs and drivers
  48 subdir('buildtools/pmdinfogen')
  49 subdir('lib')
  50 subdir('drivers')
  51
  52 # build binaries and installable tools
  53 subdir('usertools')
  54 subdir('app')
  55
  56 # build docs
  57 subdir('doc')
  58
  59 # build any examples explicitly requested - useful for developers - and
  60 # install any example code into the appropriate install path
  61 subdir('examples')
  62 install_subdir('examples',
  63         install_dir: get_option('datadir') + '/dpdk',
  64         exclude_files: 'meson.build')
  65
  66 # build kernel modules if enabled
  67 if get_option('enable_kmods')
  68         subdir('kernel')
  69 endif
  70
  71 # write the build config
  72 build_cfg = 'rte_build_config.h'
  73 configure_file(output: build_cfg,
  74                 configuration: dpdk_conf,
  75                 install_dir: join_paths(get_option('includedir'),
  76                                 get_option('include_subdir_arch')))
  77
  78 # build pkg-config files for dpdk
  79 subdir('buildtools/pkg-config')
  80
  81 # final output, list all the libs and drivers to be built
  82 # this does not affect any part of the build, for information only.
  83 output_message = '\n=================\nLibraries Enabled\n=================\n'
  84 output_message += '\nlibs:\n\t'
  85 output_count = 0
  86 foreach lib:enabled_libs
  87         output_message += lib + ', '
  88         output_count += 1
  89         if output_count == 8
  90                 output_message += '\n\t'
  91                 output_count = 0
  92         endif
  93 endforeach
  94 message(output_message + '\n')
  95
  96 output_message = '\n===============\nDrivers Enabled\n===============\n'
  97 foreach class:dpdk_driver_classes
  98         class_drivers = get_variable(class + '_drivers')
  99         output_message += '\n' + class + ':\n\t'
 100         output_count = 0
 101         foreach drv:class_drivers
 102                 output_message += drv + ', '
 103                 output_count += 1
 104                 if output_count == 8
 105                         output_message += '\n\t'
 106                         output_count = 0
 107                 endif
 108         endforeach
 109 endforeach
 110 message(output_message + '\n')
 111
 112 output_message = '\n=================\nContent Skipped\n=================\n'
 113 output_message += '\nlibs:\n\t'
 114 foreach lib:dpdk_libs_disabled
 115         reason = get_variable(lib.underscorify() + '_disable_reason')
 116         output_message += lib + ':\t' + reason + '\n\t'
 117 endforeach
 118 output_message += '\ndrivers:\n\t'
 119 foreach drv:dpdk_drvs_disabled
 120         reason = get_variable(drv.underscorify() + '_disable_reason')
 121         output_message += drv + ':\t' + reason + '\n\t'
 122 endforeach
 123 message(output_message + '\n')