meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 project('DPDK', 'C',
   5         version: '19.05.0-rc0',
   6         license: 'BSD',
   7         default_options: ['buildtype=release', 'default_library=static'],
   8         meson_version: '>= 0.41'
   9 )
  10
  11 # set up some global vars for compiler, platform, configuration, etc.
  12 cc = meson.get_compiler('c')
  13 dpdk_conf = configuration_data()
  14 dpdk_libraries = []
  15 dpdk_static_libraries = []
  16 dpdk_drivers = []
  17 dpdk_extra_ldflags = []
  18 dpdk_app_link_libraries = []
  19
  20 # set the major version, which might be used by drivers and libraries
  21 # depending on the configuration options
  22 pver = meson.project_version().split('.')
  23 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  24
  25 pmd_subdir_opt = get_option('drivers_install_subdir')
  26 if pmd_subdir_opt.contains('<VERSION>')
  27         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  28 endif
  29 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  30 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  31
  32 # configure the build, and make sure configs here and in config folder are
  33 # able to be included in any file. We also store a global array of include dirs
  34 # for passing to pmdinfogen scripts
  35 global_inc = include_directories('.', 'config')
  36 subdir('config')
  37
  38 # build libs and drivers
  39 subdir('lib')
  40 subdir('buildtools')
  41 subdir('drivers')
  42
  43 # build binaries and installable tools
  44 subdir('usertools')
  45 subdir('app')
  46 subdir('test')
  47
  48 # build docs
  49 subdir('doc')
  50
  51 # build any examples explicitly requested - useful for developers
  52 if get_option('examples') != ''
  53         subdir('examples')
  54 endif
  55
  56 # build kernel modules if enabled
  57 if get_option('enable_kmods')
  58         subdir('kernel')
  59 endif
  60
  61 # write the build config
  62 build_cfg = 'rte_build_config.h'
  63 configure_file(output: build_cfg,
  64                 configuration: dpdk_conf,
  65                 install_dir: join_paths(get_option('includedir'),
  66                                 get_option('include_subdir_arch')))
  67
  68 # for static builds, include the drivers as libs and we need to "whole-archive"
  69 # them.
  70 dpdk_drivers = ['-Wl,--whole-archive'] + dpdk_drivers + ['-Wl,--no-whole-archive']
  71
  72 # driver .so files often depend upon the bus drivers for their connect bus,
  73 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  74 # to be in the library path, so symlink the drivers from the main lib directory.
  75 meson.add_install_script('buildtools/symlink-drivers-solibs.sh',
  76                 driver_install_path,
  77                 get_option('libdir'))
  78
  79 pkg = import('pkgconfig')
  80 pkg.generate(name: meson.project_name(),
  81         filebase: 'lib' + meson.project_name().to_lower(),
  82         version: meson.project_version(),
  83         libraries: dpdk_libraries,
  84         libraries_private: dpdk_drivers + dpdk_static_libraries +
  85                         ['-Wl,-Bdynamic'] + dpdk_extra_ldflags,
  86         description: '''The Data Plane Development Kit (DPDK).
  87 Note that CFLAGS might contain an -march flag higher than typical baseline.
  88 This is required for a number of static inline functions in the public headers.''',
  89         subdirs: [get_option('include_subdir_arch'), '.'],
  90         extra_cflags: ['-include', 'rte_config.h'] + machine_args
  91 )
  92
  93 # final output, list all the libs and drivers to be built
  94 # this does not affect any part of the build, for information only.
  95 output_message = '\n=================\nLibraries Enabled\n=================\n'
  96 output_message += '\nlibs:\n\t'
  97 output_count = 0
  98 foreach lib:enabled_libs
  99         output_message += lib + ', '
 100         output_count += 1
 101         if output_count == 8
 102                 output_message += '\n\t'
 103                 output_count = 0
 104         endif
 105 endforeach
 106 message(output_message + '\n')
 107
 108
 109 # prior to 0.47 set_variable didn't work with arrays, so we can't
 110 # track driver lists easily
 111 if meson.version().version_compare('>=0.47')
 112         output_message = '\n===============\nDrivers Enabled\n===============\n'
 113         foreach class:driver_classes
 114                 class_drivers = get_variable(class + '_drivers')
 115                 output_message += '\n' + class + ':\n\t'
 116                 output_count = 0
 117                 foreach drv:class_drivers
 118                         output_message += drv + ', '
 119                         output_count += 1
 120                         if output_count == 8
 121                                 output_message += '\n\t'
 122                                 output_count = 0
 123                         endif
 124                 endforeach
 125         endforeach
 126         message(output_message + '\n')
 127 endif