app/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 if is_windows
   5         subdir_done()
   6 endif
   7
   8 apps = [
   9         'pdump',
  10         'proc-info',
  11         'test-acl',
  12         'test-bbdev',
  13         'test-cmdline',
  14         'test-compress-perf',
  15         'test-crypto-perf',
  16         'test-eventdev',
  17         'test-fib',
  18         'test-flow-perf',
  19         'test-pipeline',
  20         'test-pmd',
  21         'test-regex',
  22         'test-sad']
  23
  24 default_cflags = machine_args + ['-DALLOW_EXPERIMENTAL_API']
  25 default_ldflags = []
  26 if get_option('default_library') == 'static' and not is_windows
  27         default_ldflags += ['-Wl,--export-dynamic']
  28 endif
  29
  30 foreach app:apps
  31         build = true
  32         name = app
  33         sources = []
  34         includes = []
  35         cflags = default_cflags
  36         ldflags = default_ldflags
  37         objs = [] # other object files to link against, used e.g. for
  38                   # instruction-set optimized versions of code
  39
  40         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  41         # external package/library requirements
  42         ext_deps = []
  43         deps = []
  44
  45         subdir(name)
  46
  47         if build
  48                 dep_objs = []
  49                 foreach d:deps
  50                         dep_objs += get_variable(get_option('default_library')
  51                                  + '_rte_' + d)
  52                 endforeach
  53
  54                 link_libs = []
  55                 if get_option('default_library') == 'static'
  56                         link_libs = dpdk_static_libraries + dpdk_drivers
  57                 endif
  58
  59                 executable('dpdk-' + name,
  60                                 sources,
  61                                 c_args: cflags,
  62                                 link_args: ldflags,
  63                                 link_whole: link_libs,
  64                                 dependencies: dep_objs,
  65                                 include_directories: includes,
  66                                 install_rpath: join_paths(get_option('prefix'),
  67                                                  driver_install_path),
  68                                 install: true)
  69         endif
  70 endforeach
  71
  72 # special case the autotests
  73 subdir('test')