test/security: add inline inbound IPsec cases
[dpdk.git] / app / test / meson.build
1 # SPDX-License-Identifier: BSD-3-Clause
2 # Copyright(c) 2017 Intel Corporation
3
4 if not get_option('tests')
5     subdir_done()
6 endif
7
8 test_sources = files(
9         'commands.c',
10         'packet_burst_generator.c',
11         'test.c',
12         'test_acl.c',
13         'test_alarm.c',
14         'test_atomic.c',
15         'test_barrier.c',
16         'test_bitops.c',
17         'test_bitmap.c',
18         'test_bpf.c',
19         'test_byteorder.c',
20         'test_cksum.c',
21         'test_cmdline.c',
22         'test_cmdline_cirbuf.c',
23         'test_cmdline_etheraddr.c',
24         'test_cmdline_ipaddr.c',
25         'test_cmdline_lib.c',
26         'test_cmdline_num.c',
27         'test_cmdline_portlist.c',
28         'test_cmdline_string.c',
29         'test_common.c',
30         'test_cpuflags.c',
31         'test_crc.c',
32         'test_cryptodev.c',
33         'test_cryptodev_asym.c',
34         'test_cryptodev_blockcipher.c',
35         'test_cryptodev_security_ipsec.c',
36         'test_cryptodev_security_pdcp.c',
37         'test_cycles.c',
38         'test_debug.c',
39         'test_devargs.c',
40         'test_distributor.c',
41         'test_distributor_perf.c',
42         'test_dmadev.c',
43         'test_dmadev_api.c',
44         'test_eal_flags.c',
45         'test_eal_fs.c',
46         'test_efd.c',
47         'test_efd_perf.c',
48         'test_errno.c',
49         'test_ethdev_link.c',
50         'test_event_crypto_adapter.c',
51         'test_event_eth_rx_adapter.c',
52         'test_event_ring.c',
53         'test_event_timer_adapter.c',
54         'test_eventdev.c',
55         'test_external_mem.c',
56         'test_fbarray.c',
57         'test_fib.c',
58         'test_fib_perf.c',
59         'test_fib6.c',
60         'test_fib6_perf.c',
61         'test_func_reentrancy.c',
62         'test_graph.c',
63         'test_graph_perf.c',
64         'test_hash.c',
65         'test_hash_functions.c',
66         'test_hash_multiwriter.c',
67         'test_hash_readwrite.c',
68         'test_hash_perf.c',
69         'test_hash_readwrite_lf_perf.c',
70         'test_interrupts.c',
71         'test_ipfrag.c',
72         'test_ipsec.c',
73         'test_ipsec_sad.c',
74         'test_ipsec_perf.c',
75         'test_kni.c',
76         'test_kvargs.c',
77         'test_lcores.c',
78         'test_logs.c',
79         'test_lpm.c',
80         'test_lpm6.c',
81         'test_lpm6_perf.c',
82         'test_lpm_perf.c',
83         'test_malloc.c',
84         'test_malloc_perf.c',
85         'test_mbuf.c',
86         'test_member.c',
87         'test_member_perf.c',
88         'test_memcpy.c',
89         'test_memcpy_perf.c',
90         'test_memory.c',
91         'test_mempool.c',
92         'test_mempool_perf.c',
93         'test_memzone.c',
94         'test_meter.c',
95         'test_mcslock.c',
96         'test_mp_secondary.c',
97         'test_per_lcore.c',
98         'test_pflock.c',
99         'test_pmd_perf.c',
100         'test_power.c',
101         'test_power_cpufreq.c',
102         'test_power_kvm_vm.c',
103         'test_prefetch.c',
104         'test_rand_perf.c',
105         'test_rawdev.c',
106         'test_rcu_qsbr.c',
107         'test_rcu_qsbr_perf.c',
108         'test_reciprocal_division.c',
109         'test_reciprocal_division_perf.c',
110         'test_red.c',
111         'test_pie.c',
112         'test_reorder.c',
113         'test_rib.c',
114         'test_rib6.c',
115         'test_ring.c',
116         'test_ring_mpmc_stress.c',
117         'test_ring_hts_stress.c',
118         'test_ring_mt_peek_stress.c',
119         'test_ring_mt_peek_stress_zc.c',
120         'test_ring_perf.c',
121         'test_ring_rts_stress.c',
122         'test_ring_st_peek_stress.c',
123         'test_ring_st_peek_stress_zc.c',
124         'test_ring_stress.c',
125         'test_rwlock.c',
126         'test_sched.c',
127         'test_security.c',
128         'test_security_inline_proto.c',
129         'test_service_cores.c',
130         'test_spinlock.c',
131         'test_stack.c',
132         'test_stack_perf.c',
133         'test_string_fns.c',
134         'test_tailq.c',
135         'test_thash.c',
136         'test_thash_perf.c',
137         'test_threads.c',
138         'test_timer.c',
139         'test_timer_perf.c',
140         'test_timer_racecond.c',
141         'test_timer_secondary.c',
142         'test_ticketlock.c',
143         'test_trace.c',
144         'test_trace_register.c',
145         'test_trace_perf.c',
146         'test_version.c',
147         'virtual_pmd.c',
148 )
149
150 test_deps = enabled_libs
151 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
152 test_deps += ['bus_pci', 'bus_vdev']
153
154 # Each test is marked with flags:
155 # - the first flag indicates whether the test can run in no-huge mode,
156 # - the second flag indicates whether the test can run with ASan enabled,
157 fast_tests = [
158         ['acl_autotest', true, true],
159         ['atomic_autotest', false, true],
160         ['bitmap_autotest', true, true],
161         ['bpf_autotest', true, true],
162         ['bpf_convert_autotest', true, true],
163         ['bitops_autotest', true, true],
164         ['byteorder_autotest', true, true],
165         ['cksum_autotest', true, true],
166         ['cmdline_autotest', true, true],
167         ['common_autotest', true, true],
168         ['cpuflags_autotest', true, true],
169         ['debug_autotest', true, true],
170         ['devargs_autotest', true, true],
171         ['eal_flags_c_opt_autotest', false, false],
172         ['eal_flags_main_opt_autotest', false, false],
173         ['eal_flags_n_opt_autotest', false, false],
174         ['eal_flags_hpet_autotest', false, false],
175         ['eal_flags_no_huge_autotest', false, false],
176         ['eal_flags_a_opt_autotest', false, false],
177         ['eal_flags_b_opt_autotest', false, false],
178         ['eal_flags_vdev_opt_autotest', false, false],
179         ['eal_flags_r_opt_autotest', false, false],
180         ['eal_flags_mem_autotest', false, false],
181         ['eal_flags_file_prefix_autotest', false, false],
182         ['eal_flags_misc_autotest', false, false],
183         ['eal_fs_autotest', true, true],
184         ['errno_autotest', true, true],
185         ['ethdev_link_status', true, true],
186         ['event_ring_autotest', true, true],
187         ['fib_autotest', true, true],
188         ['fib6_autotest', true, true],
189         ['func_reentrancy_autotest', false, true],
190         ['hash_autotest', true, true],
191         ['interrupt_autotest', true, true],
192         ['ipfrag_autotest', false, true],
193         ['lcores_autotest', true, true],
194         ['logs_autotest', true, true],
195         ['lpm_autotest', true, true],
196         ['lpm6_autotest', true, true],
197         ['malloc_autotest', false, true],
198         ['mbuf_autotest', false, true],
199         ['mcslock_autotest', false, true],
200         ['memcpy_autotest', true, true],
201         ['memory_autotest', false, true],
202         ['mempool_autotest', false, true],
203         ['memzone_autotest', false, true],
204         ['meter_autotest', true, true],
205         ['multiprocess_autotest', false, false],
206         ['per_lcore_autotest', true, true],
207         ['pflock_autotest', true, true],
208         ['prefetch_autotest', true, true],
209         ['rcu_qsbr_autotest', true, true],
210         ['pie_autotest', true, true],
211         ['rib_autotest', true, true],
212         ['rib6_autotest', true, true],
213         ['ring_autotest', true, true],
214         ['rwlock_test1_autotest', true, true],
215         ['rwlock_rda_autotest', true, true],
216         ['rwlock_rds_wrm_autotest', true, true],
217         ['rwlock_rde_wro_autotest', true, true],
218         ['sched_autotest', true, true],
219         ['security_autotest', false, true],
220         ['spinlock_autotest', true, true],
221         ['stack_autotest', false, true],
222         ['stack_lf_autotest', false, true],
223         ['string_autotest', true, true],
224         ['tailq_autotest', true, true],
225         ['ticketlock_autotest', true, true],
226         ['timer_autotest', false, true],
227         ['user_delay_us', true, true],
228         ['version_autotest', true, true],
229         ['crc_autotest', true, true],
230         ['distributor_autotest', false, true],
231         ['eventdev_common_autotest', true, true],
232         ['fbarray_autotest', true, true],
233         ['hash_readwrite_func_autotest', false, true],
234         ['ipsec_autotest', true, true],
235         ['kni_autotest', false, true],
236         ['kvargs_autotest', true, true],
237         ['member_autotest', true, true],
238         ['power_cpufreq_autotest', false, true],
239         ['power_autotest', true, true],
240         ['power_kvm_vm_autotest', false, true],
241         ['reorder_autotest', true, true],
242         ['service_autotest', true, true],
243         ['thash_autotest', true, true],
244         ['threads_autotest', true, true],
245         ['trace_autotest', true, true],
246 ]
247
248 # Tests known to have issues or which don't belong in other tests lists.
249 extra_test_names = [
250         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
251         'cycles_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
252         'delay_us_sleep_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
253         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
254 ]
255
256 perf_test_names = [
257         'ring_perf_autotest',
258         'malloc_perf_autotest',
259         'mempool_perf_autotest',
260         'memcpy_perf_autotest',
261         'hash_perf_autotest',
262         'timer_perf_autotest',
263         'reciprocal_division',
264         'reciprocal_division_perf',
265         'lpm_perf_autotest',
266         'rib_slow_autotest',
267         'fib_slow_autotest',
268         'fib_perf_autotest',
269         'red_all',
270         'pie_all',
271         'barrier_autotest',
272         'hash_multiwriter_autotest',
273         'timer_racecond_autotest',
274         'efd_autotest',
275         'hash_functions_autotest',
276         'member_perf_autotest',
277         'efd_perf_autotest',
278         'lpm6_perf_autotest',
279         'rib6_slow_autotest',
280         'fib6_slow_autotest',
281         'fib6_perf_autotest',
282         'rcu_qsbr_perf_autotest',
283         'red_perf',
284         'pie_perf',
285         'distributor_perf_autotest',
286         'pmd_perf_autotest',
287         'stack_perf_autotest',
288         'stack_lf_perf_autotest',
289         'rand_perf_autotest',
290         'hash_readwrite_perf_autotest',
291         'hash_readwrite_lf_perf_autotest',
292         'trace_perf_autotest',
293         'ipsec_perf_autotest',
294         'thash_perf_autotest',
295 ]
296
297 driver_test_names = []
298
299 dump_test_names = []
300
301 if not is_windows
302     driver_test_names += [
303             'cryptodev_aesni_mb_autotest',
304             'cryptodev_aesni_gcm_autotest',
305             'cryptodev_cn9k_autotest',
306             'cryptodev_cn10k_autotest',
307             'cryptodev_dpaa_sec_autotest',
308             'cryptodev_dpaa2_sec_autotest',
309             'cryptodev_null_autotest',
310             'cryptodev_openssl_autotest',
311             'cryptodev_openssl_asym_autotest',
312             'cryptodev_qat_autotest',
313             'cryptodev_sw_armv8_autotest',
314             'cryptodev_sw_kasumi_autotest',
315             'cryptodev_sw_mvsam_autotest',
316             'cryptodev_sw_snow3g_autotest',
317             'cryptodev_sw_zuc_autotest',
318             'dmadev_autotest',
319             'eventdev_selftest_octeontx',
320             'eventdev_selftest_sw',
321             'rawdev_autotest',
322     ]
323
324     dump_test_names += [
325             'dump_struct_sizes',
326             'dump_mempool',
327             'dump_malloc_stats',
328             'dump_devargs',
329             'dump_log_types',
330             'dump_ring',
331             'dump_physmem',
332             'dump_memzone',
333     ]
334 endif
335
336 # The following linkages are an exception to allow running the
337 # unit tests without requiring that the developer install the
338 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
339 # in applications should not be used.
340 if dpdk_conf.has('RTE_MEMPOOL_RING')
341     test_deps += 'mempool_ring'
342 endif
343 if dpdk_conf.has('RTE_MEMPOOL_STACK')
344     test_deps += 'mempool_stack'
345 endif
346 if dpdk_conf.has('RTE_EVENT_SKELETON')
347     test_deps += 'event_skeleton'
348 endif
349
350 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
351     test_sources += 'test_flow_classify.c'
352     fast_tests += [['flow_classify_autotest', false, true]]
353 endif
354 if dpdk_conf.has('RTE_LIB_METRICS')
355     test_sources += ['test_metrics.c']
356     fast_tests += [['metrics_autotest', true, true]]
357 endif
358 if not is_windows and dpdk_conf.has('RTE_LIB_TELEMETRY')
359     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
360     fast_tests += [['telemetry_json_autotest', true, true]]
361     fast_tests += [['telemetry_data_autotest', true, true]]
362 endif
363 if dpdk_conf.has('RTE_LIB_PIPELINE')
364 # pipeline lib depends on port and table libs, so those must be present
365 # if pipeline library is.
366     test_sources += [
367             'test_table.c',
368             'test_table_acl.c',
369             'test_table_combined.c',
370             'test_table_pipeline.c',
371             'test_table_ports.c',
372             'test_table_tables.c',
373     ]
374     fast_tests += [['table_autotest', true, true]]
375 endif
376
377 # The following linkages of drivers are required because
378 # they are used via a driver-specific API.
379 if dpdk_conf.has('RTE_NET_BOND')
380     test_deps += 'net_bond'
381     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
382     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
383     if dpdk_conf.has('RTE_NET_RING')
384         test_sources += 'test_link_bonding_mode4.c'
385         driver_test_names += 'link_bonding_mode4_autotest'
386     endif
387 endif
388 if dpdk_conf.has('RTE_NET_RING')
389     test_deps += 'net_ring'
390     test_sources += 'test_pmd_ring_perf.c'
391     test_sources += 'test_pmd_ring.c'
392     test_sources += 'test_event_eth_tx_adapter.c'
393     test_sources += 'sample_packet_forward.c'
394     fast_tests += [['ring_pmd_autotest', true, true]]
395     perf_test_names += 'ring_pmd_perf_autotest'
396     fast_tests += [['event_eth_tx_adapter_autotest', false, true]]
397     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
398         test_sources += 'test_bitratestats.c'
399         fast_tests += [['bitratestats_autotest', true, true]]
400     endif
401     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
402         test_sources += 'test_latencystats.c'
403         fast_tests += [['latencystats_autotest', true, true]]
404     endif
405     if dpdk_conf.has('RTE_LIB_PDUMP')
406         test_sources += 'test_pdump.c'
407         fast_tests += [['pdump_autotest', true, false]]
408     endif
409 endif
410 if dpdk_conf.has('RTE_NET_NULL')
411     test_deps += 'net_null'
412     test_sources += 'test_vdev.c'
413     fast_tests += [['vdev_autotest', true, true]]
414 endif
415
416 if dpdk_conf.has('RTE_HAS_LIBPCAP')
417     ext_deps += pcap_dep
418     if dpdk_conf.has('RTE_LIB_PCAPNG')
419         test_sources += 'test_pcapng.c'
420     endif
421 endif
422
423 if cc.has_argument('-Wno-format-truncation')
424     cflags += '-Wno-format-truncation'
425 endif
426
427 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
428 cflags += '-fno-strict-aliasing'
429
430 # Enable using internal APIs in unit tests
431 cflags += ['-DALLOW_INTERNAL_API']
432
433 test_dep_objs = []
434 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
435     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
436     if compress_test_dep.found()
437         test_dep_objs += compress_test_dep
438         test_sources += 'test_compressdev.c'
439         fast_tests += [['compressdev_autotest', false, true]]
440     endif
441 endif
442
443 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
444     driver_test_names += 'cryptodev_scheduler_autotest'
445     test_deps += 'crypto_scheduler'
446 endif
447
448 foreach d:test_deps
449     def_lib = get_option('default_library')
450     test_dep_objs += get_variable(def_lib + '_rte_' + d)
451 endforeach
452
453 link_libs = []
454 if get_option('default_library') == 'static'
455     link_libs = dpdk_static_libraries + dpdk_drivers
456 endif
457
458 dpdk_test = executable('dpdk-test',
459         test_sources,
460         link_whole: link_libs,
461         dependencies: test_dep_objs + ext_deps,
462         c_args: cflags,
463         install_rpath: join_paths(get_option('prefix'),
464              driver_install_path),
465         install: true)
466
467 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
468 message('hugepage availability: @0@'.format(has_hugepage))
469
470 # some perf tests (eg: memcpy perf autotest)take very long
471 # to complete, so timeout to 10 minutes
472 timeout_seconds = 600
473 timeout_seconds_fast = 10
474
475 foreach arg : fast_tests
476     test_args = []
477     run_test = true
478     if not has_hugepage
479         if arg[1]
480             test_args += ['--no-huge', '-m', '2048']
481         else
482             run_test = false
483         endif
484     endif
485
486     if get_option('b_sanitize') == 'address' or get_option('b_sanitize') == 'address,undefined'
487         if not arg[2]
488             run_test = false
489         endif
490     endif
491
492     if (get_option('default_library') == 'shared' and
493         arg[0] == 'event_eth_tx_adapter_autotest')
494         foreach drv:dpdk_drivers
495             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
496         endforeach
497     endif
498     if is_linux
499         test_args += ['--file-prefix=@0@'.format(arg[0])]
500     endif
501
502     if run_test
503         test(arg[0], dpdk_test,
504                 env : ['DPDK_TEST=' + arg[0]],
505                 args : test_args,
506                 timeout : timeout_seconds_fast,
507                 is_parallel : false,
508                 suite : 'fast-tests')
509     endif
510 endforeach
511
512 foreach arg : perf_test_names
513     test(arg, dpdk_test,
514             env : ['DPDK_TEST=' + arg],
515             timeout : timeout_seconds,
516             is_parallel : false,
517             suite : 'perf-tests')
518 endforeach
519
520 foreach arg : driver_test_names
521     test(arg, dpdk_test,
522             env : ['DPDK_TEST=' + arg],
523             timeout : timeout_seconds,
524             is_parallel : false,
525             suite : 'driver-tests')
526 endforeach
527
528 foreach arg : dump_test_names
529     test(arg, dpdk_test,
530             env : ['DPDK_TEST=' + arg],
531             timeout : timeout_seconds,
532             is_parallel : false,
533             suite : 'debug-tests')
534 endforeach
535
536 foreach arg : extra_test_names
537     test(arg, dpdk_test,
538             env : ['DPDK_TEST=' + arg],
539             timeout : timeout_seconds,
540             is_parallel : false,
541             suite : 'extra-tests')
542 endforeach