app/test/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 if not get_option('tests')
   5     subdir_done()
   6 endif
   7
   8 test_sources = files(
   9         'commands.c',
  10         'packet_burst_generator.c',
  11         'test.c',
  12         'test_acl.c',
  13         'test_alarm.c',
  14         'test_atomic.c',
  15         'test_barrier.c',
  16         'test_bitops.c',
  17         'test_bitmap.c',
  18         'test_bpf.c',
  19         'test_byteorder.c',
  20         'test_cksum.c',
  21         'test_cmdline.c',
  22         'test_cmdline_cirbuf.c',
  23         'test_cmdline_etheraddr.c',
  24         'test_cmdline_ipaddr.c',
  25         'test_cmdline_lib.c',
  26         'test_cmdline_num.c',
  27         'test_cmdline_portlist.c',
  28         'test_cmdline_string.c',
  29         'test_common.c',
  30         'test_cpuflags.c',
  31         'test_crc.c',
  32         'test_cryptodev.c',
  33         'test_cryptodev_asym.c',
  34         'test_cryptodev_blockcipher.c',
  35         'test_cryptodev_security_ipsec.c',
  36         'test_cryptodev_security_pdcp.c',
  37         'test_cycles.c',
  38         'test_debug.c',
  39         'test_devargs.c',
  40         'test_distributor.c',
  41         'test_distributor_perf.c',
  42         'test_dmadev.c',
  43         'test_dmadev_api.c',
  44         'test_eal_flags.c',
  45         'test_eal_fs.c',
  46         'test_efd.c',
  47         'test_efd_perf.c',
  48         'test_errno.c',
  49         'test_ethdev_link.c',
  50         'test_event_crypto_adapter.c',
  51         'test_event_eth_rx_adapter.c',
  52         'test_event_ring.c',
  53         'test_event_timer_adapter.c',
  54         'test_eventdev.c',
  55         'test_external_mem.c',
  56         'test_fbarray.c',
  57         'test_fib.c',
  58         'test_fib_perf.c',
  59         'test_fib6.c',
  60         'test_fib6_perf.c',
  61         'test_func_reentrancy.c',
  62         'test_graph.c',
  63         'test_graph_perf.c',
  64         'test_hash.c',
  65         'test_hash_functions.c',
  66         'test_hash_multiwriter.c',
  67         'test_hash_readwrite.c',
  68         'test_hash_perf.c',
  69         'test_hash_readwrite_lf_perf.c',
  70         'test_interrupts.c',
  71         'test_ipfrag.c',
  72         'test_ipsec.c',
  73         'test_ipsec_sad.c',
  74         'test_ipsec_perf.c',
  75         'test_kni.c',
  76         'test_kvargs.c',
  77         'test_lcores.c',
  78         'test_logs.c',
  79         'test_lpm.c',
  80         'test_lpm6.c',
  81         'test_lpm6_perf.c',
  82         'test_lpm_perf.c',
  83         'test_malloc.c',
  84         'test_mbuf.c',
  85         'test_member.c',
  86         'test_member_perf.c',
  87         'test_memcpy.c',
  88         'test_memcpy_perf.c',
  89         'test_memory.c',
  90         'test_mempool.c',
  91         'test_mempool_perf.c',
  92         'test_memzone.c',
  93         'test_meter.c',
  94         'test_mcslock.c',
  95         'test_mp_secondary.c',
  96         'test_per_lcore.c',
  97         'test_pflock.c',
  98         'test_pmd_perf.c',
  99         'test_power.c',
 100         'test_power_cpufreq.c',
 101         'test_power_kvm_vm.c',
 102         'test_prefetch.c',
 103         'test_rand_perf.c',
 104         'test_rawdev.c',
 105         'test_rcu_qsbr.c',
 106         'test_rcu_qsbr_perf.c',
 107         'test_reciprocal_division.c',
 108         'test_reciprocal_division_perf.c',
 109         'test_red.c',
 110         'test_pie.c',
 111         'test_reorder.c',
 112         'test_rib.c',
 113         'test_rib6.c',
 114         'test_ring.c',
 115         'test_ring_mpmc_stress.c',
 116         'test_ring_hts_stress.c',
 117         'test_ring_mt_peek_stress.c',
 118         'test_ring_mt_peek_stress_zc.c',
 119         'test_ring_perf.c',
 120         'test_ring_rts_stress.c',
 121         'test_ring_st_peek_stress.c',
 122         'test_ring_st_peek_stress_zc.c',
 123         'test_ring_stress.c',
 124         'test_rwlock.c',
 125         'test_sched.c',
 126         'test_security.c',
 127         'test_service_cores.c',
 128         'test_spinlock.c',
 129         'test_stack.c',
 130         'test_stack_perf.c',
 131         'test_string_fns.c',
 132         'test_tailq.c',
 133         'test_thash.c',
 134         'test_thash_perf.c',
 135         'test_timer.c',
 136         'test_timer_perf.c',
 137         'test_timer_racecond.c',
 138         'test_timer_secondary.c',
 139         'test_ticketlock.c',
 140         'test_trace.c',
 141         'test_trace_register.c',
 142         'test_trace_perf.c',
 143         'test_version.c',
 144         'virtual_pmd.c',
 145 )
 146
 147 test_deps = enabled_libs
 148 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
 149 test_deps += ['bus_pci', 'bus_vdev']
 150
 151 # Each test is marked with flag true/false
 152 # to indicate whether it can run in no-huge mode.
 153 fast_tests = [
 154         ['acl_autotest', true],
 155         ['atomic_autotest', false],
 156         ['bitmap_autotest', true],
 157         ['bpf_autotest', true],
 158         ['bpf_convert_autotest', true],
 159         ['bitops_autotest', true],
 160         ['byteorder_autotest', true],
 161         ['cksum_autotest', true],
 162         ['cmdline_autotest', true],
 163         ['common_autotest', true],
 164         ['cpuflags_autotest', true],
 165         ['debug_autotest', true],
 166         ['devargs_autotest', true],
 167         ['eal_flags_c_opt_autotest', false],
 168         ['eal_flags_main_opt_autotest', false],
 169         ['eal_flags_n_opt_autotest', false],
 170         ['eal_flags_hpet_autotest', false],
 171         ['eal_flags_no_huge_autotest', false],
 172         ['eal_flags_a_opt_autotest', false],
 173         ['eal_flags_b_opt_autotest', false],
 174         ['eal_flags_vdev_opt_autotest', false],
 175         ['eal_flags_r_opt_autotest', false],
 176         ['eal_flags_mem_autotest', false],
 177         ['eal_flags_file_prefix_autotest', false],
 178         ['eal_flags_misc_autotest', false],
 179         ['eal_fs_autotest', true],
 180         ['errno_autotest', true],
 181         ['ethdev_link_status', true],
 182         ['event_ring_autotest', true],
 183         ['fib_autotest', true],
 184         ['fib6_autotest', true],
 185         ['func_reentrancy_autotest', false],
 186         ['hash_autotest', true],
 187         ['interrupt_autotest', true],
 188         ['ipfrag_autotest', false],
 189         ['lcores_autotest', true],
 190         ['logs_autotest', true],
 191         ['lpm_autotest', true],
 192         ['lpm6_autotest', true],
 193         ['malloc_autotest', false],
 194         ['mbuf_autotest', false],
 195         ['mcslock_autotest', false],
 196         ['memcpy_autotest', true],
 197         ['memory_autotest', false],
 198         ['mempool_autotest', false],
 199         ['memzone_autotest', false],
 200         ['meter_autotest', true],
 201         ['multiprocess_autotest', false],
 202         ['per_lcore_autotest', true],
 203         ['pflock_autotest', true],
 204         ['prefetch_autotest', true],
 205         ['rcu_qsbr_autotest', true],
 206         ['pie_autotest', true],
 207         ['rib_autotest', true],
 208         ['rib6_autotest', true],
 209         ['ring_autotest', true],
 210         ['rwlock_test1_autotest', true],
 211         ['rwlock_rda_autotest', true],
 212         ['rwlock_rds_wrm_autotest', true],
 213         ['rwlock_rde_wro_autotest', true],
 214         ['sched_autotest', true],
 215         ['security_autotest', false],
 216         ['spinlock_autotest', true],
 217         ['stack_autotest', false],
 218         ['stack_lf_autotest', false],
 219         ['string_autotest', true],
 220         ['tailq_autotest', true],
 221         ['ticketlock_autotest', true],
 222         ['timer_autotest', false],
 223         ['user_delay_us', true],
 224         ['version_autotest', true],
 225         ['crc_autotest', true],
 226         ['distributor_autotest', false],
 227         ['eventdev_common_autotest', true],
 228         ['fbarray_autotest', true],
 229         ['hash_readwrite_func_autotest', false],
 230         ['ipsec_autotest', true],
 231         ['kni_autotest', false],
 232         ['kvargs_autotest', true],
 233         ['member_autotest', true],
 234         ['power_cpufreq_autotest', false],
 235         ['power_autotest', true],
 236         ['power_kvm_vm_autotest', false],
 237         ['reorder_autotest', true],
 238         ['service_autotest', true],
 239         ['thash_autotest', true],
 240         ['trace_autotest', true],
 241 ]
 242
 243 # Tests known to have issues or which don't belong in other tests lists.
 244 extra_test_names = [
 245         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 246         'cycles_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 247         'delay_us_sleep_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 248         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
 249 ]
 250
 251 perf_test_names = [
 252         'ring_perf_autotest',
 253         'mempool_perf_autotest',
 254         'memcpy_perf_autotest',
 255         'hash_perf_autotest',
 256         'timer_perf_autotest',
 257         'reciprocal_division',
 258         'reciprocal_division_perf',
 259         'lpm_perf_autotest',
 260         'rib_slow_autotest',
 261         'fib_slow_autotest',
 262         'fib_perf_autotest',
 263         'red_all',
 264         'pie_all',
 265         'barrier_autotest',
 266         'hash_multiwriter_autotest',
 267         'timer_racecond_autotest',
 268         'efd_autotest',
 269         'hash_functions_autotest',
 270         'member_perf_autotest',
 271         'efd_perf_autotest',
 272         'lpm6_perf_autotest',
 273         'rib6_slow_autotest',
 274         'fib6_slow_autotest',
 275         'fib6_perf_autotest',
 276         'rcu_qsbr_perf_autotest',
 277         'red_perf',
 278         'pie_perf',
 279         'distributor_perf_autotest',
 280         'pmd_perf_autotest',
 281         'stack_perf_autotest',
 282         'stack_lf_perf_autotest',
 283         'rand_perf_autotest',
 284         'hash_readwrite_perf_autotest',
 285         'hash_readwrite_lf_perf_autotest',
 286         'trace_perf_autotest',
 287         'ipsec_perf_autotest',
 288         'thash_perf_autotest',
 289 ]
 290
 291 driver_test_names = []
 292
 293 dump_test_names = []
 294
 295 if not is_windows
 296     driver_test_names += [
 297             'cryptodev_aesni_mb_autotest',
 298             'cryptodev_aesni_gcm_autotest',
 299             'cryptodev_cn9k_autotest',
 300             'cryptodev_cn10k_autotest',
 301             'cryptodev_dpaa_sec_autotest',
 302             'cryptodev_dpaa2_sec_autotest',
 303             'cryptodev_null_autotest',
 304             'cryptodev_openssl_autotest',
 305             'cryptodev_openssl_asym_autotest',
 306             'cryptodev_qat_autotest',
 307             'cryptodev_sw_armv8_autotest',
 308             'cryptodev_sw_kasumi_autotest',
 309             'cryptodev_sw_mvsam_autotest',
 310             'cryptodev_sw_snow3g_autotest',
 311             'cryptodev_sw_zuc_autotest',
 312             'dmadev_autotest',
 313             'eventdev_selftest_octeontx',
 314             'eventdev_selftest_sw',
 315             'rawdev_autotest',
 316     ]
 317
 318     dump_test_names += [
 319             'dump_struct_sizes',
 320             'dump_mempool',
 321             'dump_malloc_stats',
 322             'dump_devargs',
 323             'dump_log_types',
 324             'dump_ring',
 325             'dump_physmem',
 326             'dump_memzone',
 327     ]
 328 endif
 329
 330 # The following linkages are an exception to allow running the
 331 # unit tests without requiring that the developer install the
 332 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
 333 # in applications should not be used.
 334 if dpdk_conf.has('RTE_MEMPOOL_RING')
 335     test_deps += 'mempool_ring'
 336 endif
 337 if dpdk_conf.has('RTE_MEMPOOL_STACK')
 338     test_deps += 'mempool_stack'
 339 endif
 340 if dpdk_conf.has('RTE_EVENT_SKELETON')
 341     test_deps += 'event_skeleton'
 342 endif
 343
 344 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
 345     test_sources += 'test_flow_classify.c'
 346     fast_tests += [['flow_classify_autotest', false]]
 347 endif
 348 if dpdk_conf.has('RTE_LIB_METRICS')
 349     test_sources += ['test_metrics.c']
 350     fast_tests += [['metrics_autotest', true]]
 351 endif
 352 if not is_windows and dpdk_conf.has('RTE_LIB_TELEMETRY')
 353     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
 354     fast_tests += [['telemetry_json_autotest', true], ['telemetry_data_autotest', true]]
 355 endif
 356 if dpdk_conf.has('RTE_LIB_PIPELINE')
 357 # pipeline lib depends on port and table libs, so those must be present
 358 # if pipeline library is.
 359     test_sources += [
 360             'test_table.c',
 361             'test_table_acl.c',
 362             'test_table_combined.c',
 363             'test_table_pipeline.c',
 364             'test_table_ports.c',
 365             'test_table_tables.c',
 366     ]
 367     fast_tests += [['table_autotest', true]]
 368 endif
 369
 370 # The following linkages of drivers are required because
 371 # they are used via a driver-specific API.
 372 if dpdk_conf.has('RTE_NET_BOND')
 373     test_deps += 'net_bond'
 374     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
 375     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
 376     if dpdk_conf.has('RTE_NET_RING')
 377         test_sources += 'test_link_bonding_mode4.c'
 378         driver_test_names += 'link_bonding_mode4_autotest'
 379     endif
 380 endif
 381 if dpdk_conf.has('RTE_NET_RING')
 382     test_deps += 'net_ring'
 383     test_sources += 'test_pmd_ring_perf.c'
 384     test_sources += 'test_pmd_ring.c'
 385     test_sources += 'test_event_eth_tx_adapter.c'
 386     test_sources += 'sample_packet_forward.c'
 387     fast_tests += [['ring_pmd_autotest', true]]
 388     perf_test_names += 'ring_pmd_perf_autotest'
 389     fast_tests += [['event_eth_tx_adapter_autotest', false]]
 390     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
 391         test_sources += 'test_bitratestats.c'
 392         fast_tests += [['bitratestats_autotest', true]]
 393     endif
 394     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
 395         test_sources += 'test_latencystats.c'
 396         fast_tests += [['latencystats_autotest', true]]
 397     endif
 398     if dpdk_conf.has('RTE_LIB_PDUMP')
 399         test_sources += 'test_pdump.c'
 400         fast_tests += [['pdump_autotest', true]]
 401     endif
 402 endif
 403 if dpdk_conf.has('RTE_NET_NULL')
 404     test_deps += 'net_null'
 405     test_sources += 'test_vdev.c'
 406     fast_tests += [['vdev_autotest', true]]
 407 endif
 408
 409 if dpdk_conf.has('RTE_HAS_LIBPCAP')
 410     ext_deps += pcap_dep
 411     if dpdk_conf.has('RTE_LIB_PCAPNG')
 412         test_sources += 'test_pcapng.c'
 413     endif
 414 endif
 415
 416 if cc.has_argument('-Wno-format-truncation')
 417     cflags += '-Wno-format-truncation'
 418 endif
 419
 420 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
 421 cflags += '-fno-strict-aliasing'
 422
 423 # Enable using internal APIs in unit tests
 424 cflags += ['-DALLOW_INTERNAL_API']
 425
 426 test_dep_objs = []
 427 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
 428     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
 429     if compress_test_dep.found()
 430         test_dep_objs += compress_test_dep
 431         test_sources += 'test_compressdev.c'
 432         fast_tests += [['compressdev_autotest', false]]
 433     endif
 434 endif
 435
 436 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
 437     driver_test_names += 'cryptodev_scheduler_autotest'
 438     test_deps += 'crypto_scheduler'
 439 endif
 440
 441 foreach d:test_deps
 442     def_lib = get_option('default_library')
 443     test_dep_objs += get_variable(def_lib + '_rte_' + d)
 444 endforeach
 445
 446 link_libs = []
 447 if get_option('default_library') == 'static'
 448     link_libs = dpdk_static_libraries + dpdk_drivers
 449 endif
 450
 451 dpdk_test = executable('dpdk-test',
 452         test_sources,
 453         link_whole: link_libs,
 454         dependencies: test_dep_objs + ext_deps,
 455         c_args: cflags,
 456         install_rpath: join_paths(get_option('prefix'),
 457              driver_install_path),
 458         install: true)
 459
 460 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
 461 message('hugepage availability: @0@'.format(has_hugepage))
 462
 463 # some perf tests (eg: memcpy perf autotest)take very long
 464 # to complete, so timeout to 10 minutes
 465 timeout_seconds = 600
 466 timeout_seconds_fast = 10
 467
 468 foreach arg : fast_tests
 469     test_args = []
 470     run_test = true
 471     if not has_hugepage
 472         if arg[1]
 473             test_args += ['--no-huge', '-m', '2048']
 474         else
 475             run_test = false
 476         endif
 477     endif
 478
 479     if (get_option('default_library') == 'shared' and
 480         arg[0] == 'event_eth_tx_adapter_autotest')
 481         foreach drv:dpdk_drivers
 482             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
 483         endforeach
 484     endif
 485     if is_linux
 486         test_args += ['--file-prefix=@0@'.format(arg[0])]
 487     endif
 488
 489     if run_test
 490         test(arg[0], dpdk_test,
 491                 env : ['DPDK_TEST=' + arg[0]],
 492                 args : test_args,
 493                 timeout : timeout_seconds_fast,
 494                 is_parallel : false,
 495                 suite : 'fast-tests')
 496     endif
 497 endforeach
 498
 499 foreach arg : perf_test_names
 500     test(arg, dpdk_test,
 501             env : ['DPDK_TEST=' + arg],
 502             timeout : timeout_seconds,
 503             is_parallel : false,
 504             suite : 'perf-tests')
 505 endforeach
 506
 507 foreach arg : driver_test_names
 508     test(arg, dpdk_test,
 509             env : ['DPDK_TEST=' + arg],
 510             timeout : timeout_seconds,
 511             is_parallel : false,
 512             suite : 'driver-tests')
 513 endforeach
 514
 515 foreach arg : dump_test_names
 516     test(arg, dpdk_test,
 517             env : ['DPDK_TEST=' + arg],
 518             timeout : timeout_seconds,
 519             is_parallel : false,
 520             suite : 'debug-tests')
 521 endforeach
 522
 523 foreach arg : extra_test_names
 524     test(arg, dpdk_test,
 525             env : ['DPDK_TEST=' + arg],
 526             timeout : timeout_seconds,
 527             is_parallel : false,
 528             suite : 'extra-tests')
 529 endforeach