app/test/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 if not get_option('tests')
   5     subdir_done()
   6 endif
   7
   8 test_sources = files(
   9         'commands.c',
  10         'packet_burst_generator.c',
  11         'test.c',
  12         'test_acl.c',
  13         'test_alarm.c',
  14         'test_atomic.c',
  15         'test_barrier.c',
  16         'test_bitops.c',
  17         'test_bitmap.c',
  18         'test_bpf.c',
  19         'test_byteorder.c',
  20         'test_cksum.c',
  21         'test_cmdline.c',
  22         'test_cmdline_cirbuf.c',
  23         'test_cmdline_etheraddr.c',
  24         'test_cmdline_ipaddr.c',
  25         'test_cmdline_lib.c',
  26         'test_cmdline_num.c',
  27         'test_cmdline_portlist.c',
  28         'test_cmdline_string.c',
  29         'test_common.c',
  30         'test_cpuflags.c',
  31         'test_crc.c',
  32         'test_cryptodev.c',
  33         'test_cryptodev_asym.c',
  34         'test_cryptodev_blockcipher.c',
  35         'test_cryptodev_security_ipsec.c',
  36         'test_cryptodev_security_pdcp.c',
  37         'test_cycles.c',
  38         'test_debug.c',
  39         'test_devargs.c',
  40         'test_distributor.c',
  41         'test_distributor_perf.c',
  42         'test_dmadev.c',
  43         'test_dmadev_api.c',
  44         'test_eal_flags.c',
  45         'test_eal_fs.c',
  46         'test_efd.c',
  47         'test_efd_perf.c',
  48         'test_errno.c',
  49         'test_ethdev_link.c',
  50         'test_event_crypto_adapter.c',
  51         'test_event_eth_rx_adapter.c',
  52         'test_event_ring.c',
  53         'test_event_timer_adapter.c',
  54         'test_eventdev.c',
  55         'test_external_mem.c',
  56         'test_fbarray.c',
  57         'test_fib.c',
  58         'test_fib_perf.c',
  59         'test_fib6.c',
  60         'test_fib6_perf.c',
  61         'test_func_reentrancy.c',
  62         'test_graph.c',
  63         'test_graph_perf.c',
  64         'test_hash.c',
  65         'test_hash_functions.c',
  66         'test_hash_multiwriter.c',
  67         'test_hash_readwrite.c',
  68         'test_hash_perf.c',
  69         'test_hash_readwrite_lf_perf.c',
  70         'test_interrupts.c',
  71         'test_ipfrag.c',
  72         'test_ipsec.c',
  73         'test_ipsec_sad.c',
  74         'test_ipsec_perf.c',
  75         'test_kni.c',
  76         'test_kvargs.c',
  77         'test_lcores.c',
  78         'test_logs.c',
  79         'test_lpm.c',
  80         'test_lpm6.c',
  81         'test_lpm6_perf.c',
  82         'test_lpm_perf.c',
  83         'test_malloc.c',
  84         'test_malloc_perf.c',
  85         'test_mbuf.c',
  86         'test_member.c',
  87         'test_member_perf.c',
  88         'test_memcpy.c',
  89         'test_memcpy_perf.c',
  90         'test_memory.c',
  91         'test_mempool.c',
  92         'test_mempool_perf.c',
  93         'test_memzone.c',
  94         'test_meter.c',
  95         'test_mcslock.c',
  96         'test_mp_secondary.c',
  97         'test_per_lcore.c',
  98         'test_pflock.c',
  99         'test_pmd_perf.c',
 100         'test_power.c',
 101         'test_power_cpufreq.c',
 102         'test_power_kvm_vm.c',
 103         'test_prefetch.c',
 104         'test_rand_perf.c',
 105         'test_rawdev.c',
 106         'test_rcu_qsbr.c',
 107         'test_rcu_qsbr_perf.c',
 108         'test_reciprocal_division.c',
 109         'test_reciprocal_division_perf.c',
 110         'test_red.c',
 111         'test_pie.c',
 112         'test_reorder.c',
 113         'test_rib.c',
 114         'test_rib6.c',
 115         'test_ring.c',
 116         'test_ring_mpmc_stress.c',
 117         'test_ring_hts_stress.c',
 118         'test_ring_mt_peek_stress.c',
 119         'test_ring_mt_peek_stress_zc.c',
 120         'test_ring_perf.c',
 121         'test_ring_rts_stress.c',
 122         'test_ring_st_peek_stress.c',
 123         'test_ring_st_peek_stress_zc.c',
 124         'test_ring_stress.c',
 125         'test_rwlock.c',
 126         'test_sched.c',
 127         'test_security.c',
 128         'test_service_cores.c',
 129         'test_spinlock.c',
 130         'test_stack.c',
 131         'test_stack_perf.c',
 132         'test_string_fns.c',
 133         'test_tailq.c',
 134         'test_thash.c',
 135         'test_thash_perf.c',
 136         'test_timer.c',
 137         'test_timer_perf.c',
 138         'test_timer_racecond.c',
 139         'test_timer_secondary.c',
 140         'test_ticketlock.c',
 141         'test_trace.c',
 142         'test_trace_register.c',
 143         'test_trace_perf.c',
 144         'test_version.c',
 145         'virtual_pmd.c',
 146 )
 147
 148 test_deps = enabled_libs
 149 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
 150 test_deps += ['bus_pci', 'bus_vdev']
 151
 152 # Each test is marked with flag true/false
 153 # to indicate whether it can run in no-huge mode.
 154 fast_tests = [
 155         ['acl_autotest', true],
 156         ['atomic_autotest', false],
 157         ['bitmap_autotest', true],
 158         ['bpf_autotest', true],
 159         ['bpf_convert_autotest', true],
 160         ['bitops_autotest', true],
 161         ['byteorder_autotest', true],
 162         ['cksum_autotest', true],
 163         ['cmdline_autotest', true],
 164         ['common_autotest', true],
 165         ['cpuflags_autotest', true],
 166         ['debug_autotest', true],
 167         ['devargs_autotest', true],
 168         ['eal_flags_c_opt_autotest', false],
 169         ['eal_flags_main_opt_autotest', false],
 170         ['eal_flags_n_opt_autotest', false],
 171         ['eal_flags_hpet_autotest', false],
 172         ['eal_flags_no_huge_autotest', false],
 173         ['eal_flags_a_opt_autotest', false],
 174         ['eal_flags_b_opt_autotest', false],
 175         ['eal_flags_vdev_opt_autotest', false],
 176         ['eal_flags_r_opt_autotest', false],
 177         ['eal_flags_mem_autotest', false],
 178         ['eal_flags_file_prefix_autotest', false],
 179         ['eal_flags_misc_autotest', false],
 180         ['eal_fs_autotest', true],
 181         ['errno_autotest', true],
 182         ['ethdev_link_status', true],
 183         ['event_ring_autotest', true],
 184         ['fib_autotest', true],
 185         ['fib6_autotest', true],
 186         ['func_reentrancy_autotest', false],
 187         ['hash_autotest', true],
 188         ['interrupt_autotest', true],
 189         ['ipfrag_autotest', false],
 190         ['lcores_autotest', true],
 191         ['logs_autotest', true],
 192         ['lpm_autotest', true],
 193         ['lpm6_autotest', true],
 194         ['malloc_autotest', false],
 195         ['mbuf_autotest', false],
 196         ['mcslock_autotest', false],
 197         ['memcpy_autotest', true],
 198         ['memory_autotest', false],
 199         ['mempool_autotest', false],
 200         ['memzone_autotest', false],
 201         ['meter_autotest', true],
 202         ['multiprocess_autotest', false],
 203         ['per_lcore_autotest', true],
 204         ['pflock_autotest', true],
 205         ['prefetch_autotest', true],
 206         ['rcu_qsbr_autotest', true],
 207         ['pie_autotest', true],
 208         ['rib_autotest', true],
 209         ['rib6_autotest', true],
 210         ['ring_autotest', true],
 211         ['rwlock_test1_autotest', true],
 212         ['rwlock_rda_autotest', true],
 213         ['rwlock_rds_wrm_autotest', true],
 214         ['rwlock_rde_wro_autotest', true],
 215         ['sched_autotest', true],
 216         ['security_autotest', false],
 217         ['spinlock_autotest', true],
 218         ['stack_autotest', false],
 219         ['stack_lf_autotest', false],
 220         ['string_autotest', true],
 221         ['tailq_autotest', true],
 222         ['ticketlock_autotest', true],
 223         ['timer_autotest', false],
 224         ['user_delay_us', true],
 225         ['version_autotest', true],
 226         ['crc_autotest', true],
 227         ['distributor_autotest', false],
 228         ['eventdev_common_autotest', true],
 229         ['fbarray_autotest', true],
 230         ['hash_readwrite_func_autotest', false],
 231         ['ipsec_autotest', true],
 232         ['kni_autotest', false],
 233         ['kvargs_autotest', true],
 234         ['member_autotest', true],
 235         ['power_cpufreq_autotest', false],
 236         ['power_autotest', true],
 237         ['power_kvm_vm_autotest', false],
 238         ['reorder_autotest', true],
 239         ['service_autotest', true],
 240         ['thash_autotest', true],
 241         ['trace_autotest', true],
 242 ]
 243
 244 # Tests known to have issues or which don't belong in other tests lists.
 245 extra_test_names = [
 246         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 247         'cycles_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 248         'delay_us_sleep_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 249         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
 250 ]
 251
 252 perf_test_names = [
 253         'ring_perf_autotest',
 254         'malloc_perf_autotest',
 255         'mempool_perf_autotest',
 256         'memcpy_perf_autotest',
 257         'hash_perf_autotest',
 258         'timer_perf_autotest',
 259         'reciprocal_division',
 260         'reciprocal_division_perf',
 261         'lpm_perf_autotest',
 262         'rib_slow_autotest',
 263         'fib_slow_autotest',
 264         'fib_perf_autotest',
 265         'red_all',
 266         'pie_all',
 267         'barrier_autotest',
 268         'hash_multiwriter_autotest',
 269         'timer_racecond_autotest',
 270         'efd_autotest',
 271         'hash_functions_autotest',
 272         'member_perf_autotest',
 273         'efd_perf_autotest',
 274         'lpm6_perf_autotest',
 275         'rib6_slow_autotest',
 276         'fib6_slow_autotest',
 277         'fib6_perf_autotest',
 278         'rcu_qsbr_perf_autotest',
 279         'red_perf',
 280         'pie_perf',
 281         'distributor_perf_autotest',
 282         'pmd_perf_autotest',
 283         'stack_perf_autotest',
 284         'stack_lf_perf_autotest',
 285         'rand_perf_autotest',
 286         'hash_readwrite_perf_autotest',
 287         'hash_readwrite_lf_perf_autotest',
 288         'trace_perf_autotest',
 289         'ipsec_perf_autotest',
 290         'thash_perf_autotest',
 291 ]
 292
 293 driver_test_names = []
 294
 295 dump_test_names = []
 296
 297 if not is_windows
 298     driver_test_names += [
 299             'cryptodev_aesni_mb_autotest',
 300             'cryptodev_aesni_gcm_autotest',
 301             'cryptodev_cn9k_autotest',
 302             'cryptodev_cn10k_autotest',
 303             'cryptodev_dpaa_sec_autotest',
 304             'cryptodev_dpaa2_sec_autotest',
 305             'cryptodev_null_autotest',
 306             'cryptodev_openssl_autotest',
 307             'cryptodev_openssl_asym_autotest',
 308             'cryptodev_qat_autotest',
 309             'cryptodev_sw_armv8_autotest',
 310             'cryptodev_sw_kasumi_autotest',
 311             'cryptodev_sw_mvsam_autotest',
 312             'cryptodev_sw_snow3g_autotest',
 313             'cryptodev_sw_zuc_autotest',
 314             'dmadev_autotest',
 315             'eventdev_selftest_octeontx',
 316             'eventdev_selftest_sw',
 317             'rawdev_autotest',
 318     ]
 319
 320     dump_test_names += [
 321             'dump_struct_sizes',
 322             'dump_mempool',
 323             'dump_malloc_stats',
 324             'dump_devargs',
 325             'dump_log_types',
 326             'dump_ring',
 327             'dump_physmem',
 328             'dump_memzone',
 329     ]
 330 endif
 331
 332 # The following linkages are an exception to allow running the
 333 # unit tests without requiring that the developer install the
 334 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
 335 # in applications should not be used.
 336 if dpdk_conf.has('RTE_MEMPOOL_RING')
 337     test_deps += 'mempool_ring'
 338 endif
 339 if dpdk_conf.has('RTE_MEMPOOL_STACK')
 340     test_deps += 'mempool_stack'
 341 endif
 342 if dpdk_conf.has('RTE_EVENT_SKELETON')
 343     test_deps += 'event_skeleton'
 344 endif
 345
 346 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
 347     test_sources += 'test_flow_classify.c'
 348     fast_tests += [['flow_classify_autotest', false]]
 349 endif
 350 if dpdk_conf.has('RTE_LIB_METRICS')
 351     test_sources += ['test_metrics.c']
 352     fast_tests += [['metrics_autotest', true]]
 353 endif
 354 if not is_windows and dpdk_conf.has('RTE_LIB_TELEMETRY')
 355     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
 356     fast_tests += [['telemetry_json_autotest', true], ['telemetry_data_autotest', true]]
 357 endif
 358 if dpdk_conf.has('RTE_LIB_PIPELINE')
 359 # pipeline lib depends on port and table libs, so those must be present
 360 # if pipeline library is.
 361     test_sources += [
 362             'test_table.c',
 363             'test_table_acl.c',
 364             'test_table_combined.c',
 365             'test_table_pipeline.c',
 366             'test_table_ports.c',
 367             'test_table_tables.c',
 368     ]
 369     fast_tests += [['table_autotest', true]]
 370 endif
 371
 372 # The following linkages of drivers are required because
 373 # they are used via a driver-specific API.
 374 if dpdk_conf.has('RTE_NET_BOND')
 375     test_deps += 'net_bond'
 376     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
 377     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
 378     if dpdk_conf.has('RTE_NET_RING')
 379         test_sources += 'test_link_bonding_mode4.c'
 380         driver_test_names += 'link_bonding_mode4_autotest'
 381     endif
 382 endif
 383 if dpdk_conf.has('RTE_NET_RING')
 384     test_deps += 'net_ring'
 385     test_sources += 'test_pmd_ring_perf.c'
 386     test_sources += 'test_pmd_ring.c'
 387     test_sources += 'test_event_eth_tx_adapter.c'
 388     test_sources += 'sample_packet_forward.c'
 389     fast_tests += [['ring_pmd_autotest', true]]
 390     perf_test_names += 'ring_pmd_perf_autotest'
 391     fast_tests += [['event_eth_tx_adapter_autotest', false]]
 392     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
 393         test_sources += 'test_bitratestats.c'
 394         fast_tests += [['bitratestats_autotest', true]]
 395     endif
 396     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
 397         test_sources += 'test_latencystats.c'
 398         fast_tests += [['latencystats_autotest', true]]
 399     endif
 400     if dpdk_conf.has('RTE_LIB_PDUMP')
 401         test_sources += 'test_pdump.c'
 402         fast_tests += [['pdump_autotest', true]]
 403     endif
 404 endif
 405 if dpdk_conf.has('RTE_NET_NULL')
 406     test_deps += 'net_null'
 407     test_sources += 'test_vdev.c'
 408     fast_tests += [['vdev_autotest', true]]
 409 endif
 410
 411 if dpdk_conf.has('RTE_HAS_LIBPCAP')
 412     ext_deps += pcap_dep
 413     if dpdk_conf.has('RTE_LIB_PCAPNG')
 414         test_sources += 'test_pcapng.c'
 415     endif
 416 endif
 417
 418 if cc.has_argument('-Wno-format-truncation')
 419     cflags += '-Wno-format-truncation'
 420 endif
 421
 422 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
 423 cflags += '-fno-strict-aliasing'
 424
 425 # Enable using internal APIs in unit tests
 426 cflags += ['-DALLOW_INTERNAL_API']
 427
 428 test_dep_objs = []
 429 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
 430     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
 431     if compress_test_dep.found()
 432         test_dep_objs += compress_test_dep
 433         test_sources += 'test_compressdev.c'
 434         fast_tests += [['compressdev_autotest', false]]
 435     endif
 436 endif
 437
 438 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
 439     driver_test_names += 'cryptodev_scheduler_autotest'
 440     test_deps += 'crypto_scheduler'
 441 endif
 442
 443 foreach d:test_deps
 444     def_lib = get_option('default_library')
 445     test_dep_objs += get_variable(def_lib + '_rte_' + d)
 446 endforeach
 447
 448 link_libs = []
 449 if get_option('default_library') == 'static'
 450     link_libs = dpdk_static_libraries + dpdk_drivers
 451 endif
 452
 453 dpdk_test = executable('dpdk-test',
 454         test_sources,
 455         link_whole: link_libs,
 456         dependencies: test_dep_objs + ext_deps,
 457         c_args: cflags,
 458         install_rpath: join_paths(get_option('prefix'),
 459              driver_install_path),
 460         install: true)
 461
 462 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
 463 message('hugepage availability: @0@'.format(has_hugepage))
 464
 465 # some perf tests (eg: memcpy perf autotest)take very long
 466 # to complete, so timeout to 10 minutes
 467 timeout_seconds = 600
 468 timeout_seconds_fast = 10
 469
 470 foreach arg : fast_tests
 471     test_args = []
 472     run_test = true
 473     if not has_hugepage
 474         if arg[1]
 475             test_args += ['--no-huge', '-m', '2048']
 476         else
 477             run_test = false
 478         endif
 479     endif
 480
 481     if (get_option('default_library') == 'shared' and
 482         arg[0] == 'event_eth_tx_adapter_autotest')
 483         foreach drv:dpdk_drivers
 484             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
 485         endforeach
 486     endif
 487     if is_linux
 488         test_args += ['--file-prefix=@0@'.format(arg[0])]
 489     endif
 490
 491     if run_test
 492         test(arg[0], dpdk_test,
 493                 env : ['DPDK_TEST=' + arg[0]],
 494                 args : test_args,
 495                 timeout : timeout_seconds_fast,
 496                 is_parallel : false,
 497                 suite : 'fast-tests')
 498     endif
 499 endforeach
 500
 501 foreach arg : perf_test_names
 502     test(arg, dpdk_test,
 503             env : ['DPDK_TEST=' + arg],
 504             timeout : timeout_seconds,
 505             is_parallel : false,
 506             suite : 'perf-tests')
 507 endforeach
 508
 509 foreach arg : driver_test_names
 510     test(arg, dpdk_test,
 511             env : ['DPDK_TEST=' + arg],
 512             timeout : timeout_seconds,
 513             is_parallel : false,
 514             suite : 'driver-tests')
 515 endforeach
 516
 517 foreach arg : dump_test_names
 518     test(arg, dpdk_test,
 519             env : ['DPDK_TEST=' + arg],
 520             timeout : timeout_seconds,
 521             is_parallel : false,
 522             suite : 'debug-tests')
 523 endforeach
 524
 525 foreach arg : extra_test_names
 526     test(arg, dpdk_test,
 527             env : ['DPDK_TEST=' + arg],
 528             timeout : timeout_seconds,
 529             is_parallel : false,
 530             suite : 'extra-tests')
 531 endforeach