app/test/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 if not get_option('tests')
   5     subdir_done()
   6 endif
   7
   8 test_sources = files(
   9         'commands.c',
  10         'packet_burst_generator.c',
  11         'test.c',
  12         'test_acl.c',
  13         'test_alarm.c',
  14         'test_atomic.c',
  15         'test_barrier.c',
  16         'test_bitops.c',
  17         'test_bitmap.c',
  18         'test_bpf.c',
  19         'test_byteorder.c',
  20         'test_cksum.c',
  21         'test_cmdline.c',
  22         'test_cmdline_cirbuf.c',
  23         'test_cmdline_etheraddr.c',
  24         'test_cmdline_ipaddr.c',
  25         'test_cmdline_lib.c',
  26         'test_cmdline_num.c',
  27         'test_cmdline_portlist.c',
  28         'test_cmdline_string.c',
  29         'test_common.c',
  30         'test_cpuflags.c',
  31         'test_crc.c',
  32         'test_cryptodev.c',
  33         'test_cryptodev_asym.c',
  34         'test_cryptodev_blockcipher.c',
  35         'test_cryptodev_security_ipsec.c',
  36         'test_cryptodev_security_pdcp.c',
  37         'test_cycles.c',
  38         'test_debug.c',
  39         'test_devargs.c',
  40         'test_distributor.c',
  41         'test_distributor_perf.c',
  42         'test_dmadev.c',
  43         'test_dmadev_api.c',
  44         'test_eal_flags.c',
  45         'test_eal_fs.c',
  46         'test_efd.c',
  47         'test_efd_perf.c',
  48         'test_errno.c',
  49         'test_ethdev_link.c',
  50         'test_event_crypto_adapter.c',
  51         'test_event_eth_rx_adapter.c',
  52         'test_event_ring.c',
  53         'test_event_timer_adapter.c',
  54         'test_eventdev.c',
  55         'test_external_mem.c',
  56         'test_fbarray.c',
  57         'test_fib.c',
  58         'test_fib_perf.c',
  59         'test_fib6.c',
  60         'test_fib6_perf.c',
  61         'test_func_reentrancy.c',
  62         'test_graph.c',
  63         'test_graph_perf.c',
  64         'test_hash.c',
  65         'test_hash_functions.c',
  66         'test_hash_multiwriter.c',
  67         'test_hash_readwrite.c',
  68         'test_hash_perf.c',
  69         'test_hash_readwrite_lf_perf.c',
  70         'test_interrupts.c',
  71         'test_ipfrag.c',
  72         'test_ipsec.c',
  73         'test_ipsec_sad.c',
  74         'test_ipsec_perf.c',
  75         'test_kni.c',
  76         'test_kvargs.c',
  77         'test_lcores.c',
  78         'test_logs.c',
  79         'test_lpm.c',
  80         'test_lpm6.c',
  81         'test_lpm6_perf.c',
  82         'test_lpm_perf.c',
  83         'test_malloc.c',
  84         'test_malloc_perf.c',
  85         'test_mbuf.c',
  86         'test_member.c',
  87         'test_member_perf.c',
  88         'test_memcpy.c',
  89         'test_memcpy_perf.c',
  90         'test_memory.c',
  91         'test_mempool.c',
  92         'test_mempool_perf.c',
  93         'test_memzone.c',
  94         'test_meter.c',
  95         'test_mcslock.c',
  96         'test_mp_secondary.c',
  97         'test_per_lcore.c',
  98         'test_pflock.c',
  99         'test_pmd_perf.c',
 100         'test_power.c',
 101         'test_power_cpufreq.c',
 102         'test_power_kvm_vm.c',
 103         'test_prefetch.c',
 104         'test_rand_perf.c',
 105         'test_rawdev.c',
 106         'test_rcu_qsbr.c',
 107         'test_rcu_qsbr_perf.c',
 108         'test_reciprocal_division.c',
 109         'test_reciprocal_division_perf.c',
 110         'test_red.c',
 111         'test_pie.c',
 112         'test_reorder.c',
 113         'test_rib.c',
 114         'test_rib6.c',
 115         'test_ring.c',
 116         'test_ring_mpmc_stress.c',
 117         'test_ring_hts_stress.c',
 118         'test_ring_mt_peek_stress.c',
 119         'test_ring_mt_peek_stress_zc.c',
 120         'test_ring_perf.c',
 121         'test_ring_rts_stress.c',
 122         'test_ring_st_peek_stress.c',
 123         'test_ring_st_peek_stress_zc.c',
 124         'test_ring_stress.c',
 125         'test_rwlock.c',
 126         'test_sched.c',
 127         'test_security.c',
 128         'test_security_inline_proto.c',
 129         'test_seqlock.c',
 130         'test_service_cores.c',
 131         'test_spinlock.c',
 132         'test_stack.c',
 133         'test_stack_perf.c',
 134         'test_string_fns.c',
 135         'test_tailq.c',
 136         'test_thash.c',
 137         'test_thash_perf.c',
 138         'test_threads.c',
 139         'test_timer.c',
 140         'test_timer_perf.c',
 141         'test_timer_racecond.c',
 142         'test_timer_secondary.c',
 143         'test_ticketlock.c',
 144         'test_trace.c',
 145         'test_trace_register.c',
 146         'test_trace_perf.c',
 147         'test_version.c',
 148         'virtual_pmd.c',
 149 )
 150
 151 test_deps = enabled_libs
 152 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
 153 test_deps += ['bus_pci', 'bus_vdev']
 154
 155 # Each test is marked with flags:
 156 # - the first flag indicates whether the test can run in no-huge mode,
 157 # - the second flag indicates whether the test can run with ASan enabled,
 158 fast_tests = [
 159         ['acl_autotest', true, true],
 160         ['atomic_autotest', false, true],
 161         ['bitmap_autotest', true, true],
 162         ['bpf_autotest', true, true],
 163         ['bpf_convert_autotest', true, true],
 164         ['bitops_autotest', true, true],
 165         ['byteorder_autotest', true, true],
 166         ['cksum_autotest', true, true],
 167         ['cmdline_autotest', true, true],
 168         ['common_autotest', true, true],
 169         ['cpuflags_autotest', true, true],
 170         ['debug_autotest', true, true],
 171         ['devargs_autotest', true, true],
 172         ['eal_flags_c_opt_autotest', false, false],
 173         ['eal_flags_main_opt_autotest', false, false],
 174         ['eal_flags_n_opt_autotest', false, false],
 175         ['eal_flags_hpet_autotest', false, false],
 176         ['eal_flags_no_huge_autotest', false, false],
 177         ['eal_flags_a_opt_autotest', false, false],
 178         ['eal_flags_b_opt_autotest', false, false],
 179         ['eal_flags_vdev_opt_autotest', false, false],
 180         ['eal_flags_r_opt_autotest', false, false],
 181         ['eal_flags_mem_autotest', false, false],
 182         ['eal_flags_file_prefix_autotest', false, false],
 183         ['eal_flags_misc_autotest', false, false],
 184         ['eal_fs_autotest', true, true],
 185         ['errno_autotest', true, true],
 186         ['ethdev_link_status', true, true],
 187         ['event_ring_autotest', true, true],
 188         ['fib_autotest', true, true],
 189         ['fib6_autotest', true, true],
 190         ['func_reentrancy_autotest', false, true],
 191         ['hash_autotest', true, true],
 192         ['interrupt_autotest', true, true],
 193         ['ipfrag_autotest', false, true],
 194         ['lcores_autotest', true, true],
 195         ['logs_autotest', true, true],
 196         ['lpm_autotest', true, true],
 197         ['lpm6_autotest', true, true],
 198         ['malloc_autotest', false, true],
 199         ['mbuf_autotest', false, true],
 200         ['mcslock_autotest', false, true],
 201         ['memcpy_autotest', true, true],
 202         ['memory_autotest', false, true],
 203         ['mempool_autotest', false, true],
 204         ['memzone_autotest', false, true],
 205         ['meter_autotest', true, true],
 206         ['multiprocess_autotest', false, false],
 207         ['per_lcore_autotest', true, true],
 208         ['pflock_autotest', true, true],
 209         ['prefetch_autotest', true, true],
 210         ['rcu_qsbr_autotest', true, true],
 211         ['pie_autotest', true, true],
 212         ['rib_autotest', true, true],
 213         ['rib6_autotest', true, true],
 214         ['ring_autotest', true, true],
 215         ['rwlock_test1_autotest', true, true],
 216         ['rwlock_rda_autotest', true, true],
 217         ['rwlock_rds_wrm_autotest', true, true],
 218         ['rwlock_rde_wro_autotest', true, true],
 219         ['sched_autotest', true, true],
 220         ['security_autotest', false, true],
 221         ['seqlock_autotest', true, true],
 222         ['spinlock_autotest', true, true],
 223         ['stack_autotest', false, true],
 224         ['stack_lf_autotest', false, true],
 225         ['string_autotest', true, true],
 226         ['tailq_autotest', true, true],
 227         ['ticketlock_autotest', true, true],
 228         ['timer_autotest', false, true],
 229         ['user_delay_us', true, true],
 230         ['version_autotest', true, true],
 231         ['crc_autotest', true, true],
 232         ['distributor_autotest', false, true],
 233         ['eventdev_common_autotest', true, true],
 234         ['fbarray_autotest', true, true],
 235         ['hash_readwrite_func_autotest', false, true],
 236         ['ipsec_autotest', true, true],
 237         ['kni_autotest', false, true],
 238         ['kvargs_autotest', true, true],
 239         ['member_autotest', true, true],
 240         ['power_cpufreq_autotest', false, true],
 241         ['power_autotest', true, true],
 242         ['power_kvm_vm_autotest', false, true],
 243         ['reorder_autotest', true, true],
 244         ['service_autotest', true, true],
 245         ['thash_autotest', true, true],
 246         ['threads_autotest', true, true],
 247         ['trace_autotest', true, true],
 248 ]
 249
 250 # Tests known to have issues or which don't belong in other tests lists.
 251 extra_test_names = [
 252         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 253         'cycles_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 254         'delay_us_sleep_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 255         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
 256 ]
 257
 258 perf_test_names = [
 259         'ring_perf_autotest',
 260         'malloc_perf_autotest',
 261         'mempool_perf_autotest',
 262         'memcpy_perf_autotest',
 263         'hash_perf_autotest',
 264         'timer_perf_autotest',
 265         'reciprocal_division',
 266         'reciprocal_division_perf',
 267         'lpm_perf_autotest',
 268         'rib_slow_autotest',
 269         'fib_slow_autotest',
 270         'fib_perf_autotest',
 271         'red_all',
 272         'pie_all',
 273         'barrier_autotest',
 274         'hash_multiwriter_autotest',
 275         'timer_racecond_autotest',
 276         'efd_autotest',
 277         'hash_functions_autotest',
 278         'member_perf_autotest',
 279         'efd_perf_autotest',
 280         'lpm6_perf_autotest',
 281         'rib6_slow_autotest',
 282         'fib6_slow_autotest',
 283         'fib6_perf_autotest',
 284         'rcu_qsbr_perf_autotest',
 285         'red_perf',
 286         'pie_perf',
 287         'distributor_perf_autotest',
 288         'pmd_perf_autotest',
 289         'stack_perf_autotest',
 290         'stack_lf_perf_autotest',
 291         'rand_perf_autotest',
 292         'hash_readwrite_perf_autotest',
 293         'hash_readwrite_lf_perf_autotest',
 294         'trace_perf_autotest',
 295         'ipsec_perf_autotest',
 296         'thash_perf_autotest',
 297 ]
 298
 299 driver_test_names = []
 300
 301 dump_test_names = []
 302
 303 if not is_windows
 304     driver_test_names += [
 305             'cryptodev_aesni_mb_autotest',
 306             'cryptodev_aesni_gcm_autotest',
 307             'cryptodev_cn9k_autotest',
 308             'cryptodev_cn10k_autotest',
 309             'cryptodev_dpaa_sec_autotest',
 310             'cryptodev_dpaa2_sec_autotest',
 311             'cryptodev_null_autotest',
 312             'cryptodev_openssl_autotest',
 313             'cryptodev_openssl_asym_autotest',
 314             'cryptodev_qat_autotest',
 315             'cryptodev_sw_armv8_autotest',
 316             'cryptodev_sw_kasumi_autotest',
 317             'cryptodev_sw_mvsam_autotest',
 318             'cryptodev_sw_snow3g_autotest',
 319             'cryptodev_sw_zuc_autotest',
 320             'dmadev_autotest',
 321             'eventdev_selftest_octeontx',
 322             'eventdev_selftest_sw',
 323             'rawdev_autotest',
 324     ]
 325
 326     dump_test_names += [
 327             'dump_struct_sizes',
 328             'dump_mempool',
 329             'dump_malloc_stats',
 330             'dump_devargs',
 331             'dump_log_types',
 332             'dump_ring',
 333             'dump_physmem',
 334             'dump_memzone',
 335     ]
 336 endif
 337
 338 # The following linkages are an exception to allow running the
 339 # unit tests without requiring that the developer install the
 340 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
 341 # in applications should not be used.
 342 if dpdk_conf.has('RTE_MEMPOOL_RING')
 343     test_deps += 'mempool_ring'
 344 endif
 345 if dpdk_conf.has('RTE_MEMPOOL_STACK')
 346     test_deps += 'mempool_stack'
 347 endif
 348 if dpdk_conf.has('RTE_EVENT_SKELETON')
 349     test_deps += 'event_skeleton'
 350 endif
 351
 352 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
 353     test_sources += 'test_flow_classify.c'
 354     fast_tests += [['flow_classify_autotest', false, true]]
 355 endif
 356 if dpdk_conf.has('RTE_LIB_METRICS')
 357     test_sources += ['test_metrics.c']
 358     fast_tests += [['metrics_autotest', true, true]]
 359 endif
 360 if not is_windows and dpdk_conf.has('RTE_LIB_TELEMETRY')
 361     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
 362     fast_tests += [['telemetry_json_autotest', true, true]]
 363     fast_tests += [['telemetry_data_autotest', true, true]]
 364 endif
 365 if dpdk_conf.has('RTE_LIB_PIPELINE')
 366 # pipeline lib depends on port and table libs, so those must be present
 367 # if pipeline library is.
 368     test_sources += [
 369             'test_table.c',
 370             'test_table_acl.c',
 371             'test_table_combined.c',
 372             'test_table_pipeline.c',
 373             'test_table_ports.c',
 374             'test_table_tables.c',
 375     ]
 376     fast_tests += [['table_autotest', true, true]]
 377 endif
 378
 379 # The following linkages of drivers are required because
 380 # they are used via a driver-specific API.
 381 if dpdk_conf.has('RTE_NET_BOND')
 382     test_deps += 'net_bond'
 383     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
 384     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
 385     if dpdk_conf.has('RTE_NET_RING')
 386         test_sources += 'test_link_bonding_mode4.c'
 387         driver_test_names += 'link_bonding_mode4_autotest'
 388     endif
 389 endif
 390 if dpdk_conf.has('RTE_NET_RING')
 391     test_deps += 'net_ring'
 392     test_sources += 'test_pmd_ring_perf.c'
 393     test_sources += 'test_pmd_ring.c'
 394     test_sources += 'test_event_eth_tx_adapter.c'
 395     test_sources += 'sample_packet_forward.c'
 396     fast_tests += [['ring_pmd_autotest', true, true]]
 397     perf_test_names += 'ring_pmd_perf_autotest'
 398     fast_tests += [['event_eth_tx_adapter_autotest', false, true]]
 399     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
 400         test_sources += 'test_bitratestats.c'
 401         fast_tests += [['bitratestats_autotest', true, true]]
 402     endif
 403     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
 404         test_sources += 'test_latencystats.c'
 405         fast_tests += [['latencystats_autotest', true, true]]
 406     endif
 407     if dpdk_conf.has('RTE_LIB_PDUMP')
 408         test_sources += 'test_pdump.c'
 409         fast_tests += [['pdump_autotest', true, false]]
 410     endif
 411 endif
 412 if dpdk_conf.has('RTE_NET_NULL')
 413     test_deps += 'net_null'
 414     test_sources += 'test_vdev.c'
 415     fast_tests += [['vdev_autotest', true, true]]
 416 endif
 417
 418 if dpdk_conf.has('RTE_HAS_LIBPCAP')
 419     ext_deps += pcap_dep
 420     if dpdk_conf.has('RTE_LIB_PCAPNG')
 421         test_sources += 'test_pcapng.c'
 422     endif
 423 endif
 424
 425 if cc.has_argument('-Wno-format-truncation')
 426     cflags += '-Wno-format-truncation'
 427 endif
 428
 429 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
 430 cflags += '-fno-strict-aliasing'
 431
 432 # Enable using internal APIs in unit tests
 433 cflags += ['-DALLOW_INTERNAL_API']
 434
 435 test_dep_objs = []
 436 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
 437     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
 438     if compress_test_dep.found()
 439         test_dep_objs += compress_test_dep
 440         test_sources += 'test_compressdev.c'
 441         fast_tests += [['compressdev_autotest', false, true]]
 442     endif
 443 endif
 444
 445 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
 446     driver_test_names += 'cryptodev_scheduler_autotest'
 447     test_deps += 'crypto_scheduler'
 448 endif
 449
 450 foreach d:test_deps
 451     def_lib = get_option('default_library')
 452     test_dep_objs += get_variable(def_lib + '_rte_' + d)
 453 endforeach
 454
 455 link_libs = []
 456 if get_option('default_library') == 'static'
 457     link_libs = dpdk_static_libraries + dpdk_drivers
 458 endif
 459
 460 dpdk_test = executable('dpdk-test',
 461         test_sources,
 462         link_whole: link_libs,
 463         dependencies: test_dep_objs + ext_deps,
 464         c_args: cflags,
 465         install_rpath: join_paths(get_option('prefix'),
 466              driver_install_path),
 467         install: true)
 468
 469 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
 470 message('hugepage availability: @0@'.format(has_hugepage))
 471
 472 # some perf tests (eg: memcpy perf autotest)take very long
 473 # to complete, so timeout to 10 minutes
 474 timeout_seconds = 600
 475 timeout_seconds_fast = 10
 476
 477 foreach arg : fast_tests
 478     test_args = []
 479     run_test = true
 480     if not has_hugepage
 481         if arg[1]
 482             test_args += ['--no-huge', '-m', '2048']
 483         else
 484             run_test = false
 485         endif
 486     endif
 487
 488     if get_option('b_sanitize') == 'address' or get_option('b_sanitize') == 'address,undefined'
 489         if not arg[2]
 490             run_test = false
 491         endif
 492     endif
 493
 494     if (get_option('default_library') == 'shared' and
 495         arg[0] == 'event_eth_tx_adapter_autotest')
 496         foreach drv:dpdk_drivers
 497             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
 498         endforeach
 499     endif
 500     if is_linux
 501         test_args += ['--file-prefix=@0@'.format(arg[0])]
 502     endif
 503
 504     if run_test
 505         test(arg[0], dpdk_test,
 506                 env : ['DPDK_TEST=' + arg[0]],
 507                 args : test_args,
 508                 timeout : timeout_seconds_fast,
 509                 is_parallel : false,
 510                 suite : 'fast-tests')
 511     endif
 512 endforeach
 513
 514 foreach arg : perf_test_names
 515     test(arg, dpdk_test,
 516             env : ['DPDK_TEST=' + arg],
 517             timeout : timeout_seconds,
 518             is_parallel : false,
 519             suite : 'perf-tests')
 520 endforeach
 521
 522 foreach arg : driver_test_names
 523     test(arg, dpdk_test,
 524             env : ['DPDK_TEST=' + arg],
 525             timeout : timeout_seconds,
 526             is_parallel : false,
 527             suite : 'driver-tests')
 528 endforeach
 529
 530 foreach arg : dump_test_names
 531     test(arg, dpdk_test,
 532             env : ['DPDK_TEST=' + arg],
 533             timeout : timeout_seconds,
 534             is_parallel : false,
 535             suite : 'debug-tests')
 536 endforeach
 537
 538 foreach arg : extra_test_names
 539     test(arg, dpdk_test,
 540             env : ['DPDK_TEST=' + arg],
 541             timeout : timeout_seconds,
 542             is_parallel : false,
 543             suite : 'extra-tests')
 544 endforeach