app/test/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 if is_windows
   5     build = false
   6     reason = 'not supported on Windows'
   7     subdir_done()
   8 endif
   9
  10 if not get_option('tests')
  11     subdir_done()
  12 endif
  13
  14 test_sources = files(
  15         'commands.c',
  16         'packet_burst_generator.c',
  17         'test.c',
  18         'test_acl.c',
  19         'test_alarm.c',
  20         'test_atomic.c',
  21         'test_barrier.c',
  22         'test_bitops.c',
  23         'test_bitmap.c',
  24         'test_bpf.c',
  25         'test_byteorder.c',
  26         'test_cksum.c',
  27         'test_cmdline.c',
  28         'test_cmdline_cirbuf.c',
  29         'test_cmdline_etheraddr.c',
  30         'test_cmdline_ipaddr.c',
  31         'test_cmdline_lib.c',
  32         'test_cmdline_num.c',
  33         'test_cmdline_portlist.c',
  34         'test_cmdline_string.c',
  35         'test_common.c',
  36         'test_cpuflags.c',
  37         'test_crc.c',
  38         'test_cryptodev.c',
  39         'test_cryptodev_asym.c',
  40         'test_cryptodev_blockcipher.c',
  41         'test_cryptodev_security_ipsec.c',
  42         'test_cryptodev_security_pdcp.c',
  43         'test_cycles.c',
  44         'test_debug.c',
  45         'test_devargs.c',
  46         'test_distributor.c',
  47         'test_distributor_perf.c',
  48         'test_dmadev.c',
  49         'test_dmadev_api.c',
  50         'test_eal_flags.c',
  51         'test_eal_fs.c',
  52         'test_efd.c',
  53         'test_efd_perf.c',
  54         'test_errno.c',
  55         'test_ethdev_link.c',
  56         'test_event_crypto_adapter.c',
  57         'test_event_eth_rx_adapter.c',
  58         'test_event_ring.c',
  59         'test_event_timer_adapter.c',
  60         'test_eventdev.c',
  61         'test_external_mem.c',
  62         'test_fbarray.c',
  63         'test_fib.c',
  64         'test_fib_perf.c',
  65         'test_fib6.c',
  66         'test_fib6_perf.c',
  67         'test_func_reentrancy.c',
  68         'test_graph.c',
  69         'test_graph_perf.c',
  70         'test_hash.c',
  71         'test_hash_functions.c',
  72         'test_hash_multiwriter.c',
  73         'test_hash_readwrite.c',
  74         'test_hash_perf.c',
  75         'test_hash_readwrite_lf_perf.c',
  76         'test_interrupts.c',
  77         'test_ipfrag.c',
  78         'test_ipsec.c',
  79         'test_ipsec_sad.c',
  80         'test_ipsec_perf.c',
  81         'test_kni.c',
  82         'test_kvargs.c',
  83         'test_lcores.c',
  84         'test_logs.c',
  85         'test_lpm.c',
  86         'test_lpm6.c',
  87         'test_lpm6_perf.c',
  88         'test_lpm_perf.c',
  89         'test_malloc.c',
  90         'test_mbuf.c',
  91         'test_member.c',
  92         'test_member_perf.c',
  93         'test_memcpy.c',
  94         'test_memcpy_perf.c',
  95         'test_memory.c',
  96         'test_mempool.c',
  97         'test_mempool_perf.c',
  98         'test_memzone.c',
  99         'test_meter.c',
 100         'test_mcslock.c',
 101         'test_mp_secondary.c',
 102         'test_per_lcore.c',
 103         'test_pflock.c',
 104         'test_pmd_perf.c',
 105         'test_power.c',
 106         'test_power_cpufreq.c',
 107         'test_power_kvm_vm.c',
 108         'test_prefetch.c',
 109         'test_rand_perf.c',
 110         'test_rawdev.c',
 111         'test_rcu_qsbr.c',
 112         'test_rcu_qsbr_perf.c',
 113         'test_reciprocal_division.c',
 114         'test_reciprocal_division_perf.c',
 115         'test_red.c',
 116         'test_pie.c',
 117         'test_reorder.c',
 118         'test_rib.c',
 119         'test_rib6.c',
 120         'test_ring.c',
 121         'test_ring_mpmc_stress.c',
 122         'test_ring_hts_stress.c',
 123         'test_ring_mt_peek_stress.c',
 124         'test_ring_mt_peek_stress_zc.c',
 125         'test_ring_perf.c',
 126         'test_ring_rts_stress.c',
 127         'test_ring_st_peek_stress.c',
 128         'test_ring_st_peek_stress_zc.c',
 129         'test_ring_stress.c',
 130         'test_rwlock.c',
 131         'test_sched.c',
 132         'test_security.c',
 133         'test_service_cores.c',
 134         'test_spinlock.c',
 135         'test_stack.c',
 136         'test_stack_perf.c',
 137         'test_string_fns.c',
 138         'test_tailq.c',
 139         'test_thash.c',
 140         'test_thash_perf.c',
 141         'test_timer.c',
 142         'test_timer_perf.c',
 143         'test_timer_racecond.c',
 144         'test_timer_secondary.c',
 145         'test_ticketlock.c',
 146         'test_trace.c',
 147         'test_trace_register.c',
 148         'test_trace_perf.c',
 149         'test_version.c',
 150         'virtual_pmd.c',
 151 )
 152
 153 test_deps = enabled_libs
 154 # as well as libs, the pci and vdev bus drivers are needed for a lot of tests
 155 test_deps += ['bus_pci', 'bus_vdev']
 156
 157 # Each test is marked with flag true/false
 158 # to indicate whether it can run in no-huge mode.
 159 fast_tests = [
 160         ['acl_autotest', true],
 161         ['atomic_autotest', false],
 162         ['bitmap_autotest', true],
 163         ['bpf_autotest', true],
 164         ['bpf_convert_autotest', true],
 165         ['bitops_autotest', true],
 166         ['byteorder_autotest', true],
 167         ['cksum_autotest', true],
 168         ['cmdline_autotest', true],
 169         ['common_autotest', true],
 170         ['cpuflags_autotest', true],
 171         ['debug_autotest', true],
 172         ['devargs_autotest', true],
 173         ['eal_flags_c_opt_autotest', false],
 174         ['eal_flags_main_opt_autotest', false],
 175         ['eal_flags_n_opt_autotest', false],
 176         ['eal_flags_hpet_autotest', false],
 177         ['eal_flags_no_huge_autotest', false],
 178         ['eal_flags_a_opt_autotest', false],
 179         ['eal_flags_b_opt_autotest', false],
 180         ['eal_flags_vdev_opt_autotest', false],
 181         ['eal_flags_r_opt_autotest', false],
 182         ['eal_flags_mem_autotest', false],
 183         ['eal_flags_file_prefix_autotest', false],
 184         ['eal_flags_misc_autotest', false],
 185         ['eal_fs_autotest', true],
 186         ['errno_autotest', true],
 187         ['ethdev_link_status', true],
 188         ['event_ring_autotest', true],
 189         ['fib_autotest', true],
 190         ['fib6_autotest', true],
 191         ['func_reentrancy_autotest', false],
 192         ['hash_autotest', true],
 193         ['interrupt_autotest', true],
 194         ['ipfrag_autotest', false],
 195         ['lcores_autotest', true],
 196         ['logs_autotest', true],
 197         ['lpm_autotest', true],
 198         ['lpm6_autotest', true],
 199         ['malloc_autotest', false],
 200         ['mbuf_autotest', false],
 201         ['mcslock_autotest', false],
 202         ['memcpy_autotest', true],
 203         ['memory_autotest', false],
 204         ['mempool_autotest', false],
 205         ['memzone_autotest', false],
 206         ['meter_autotest', true],
 207         ['multiprocess_autotest', false],
 208         ['per_lcore_autotest', true],
 209         ['pflock_autotest', true],
 210         ['prefetch_autotest', true],
 211         ['rcu_qsbr_autotest', true],
 212         ['pie_autotest', true],
 213         ['rib_autotest', true],
 214         ['rib6_autotest', true],
 215         ['ring_autotest', true],
 216         ['rwlock_test1_autotest', true],
 217         ['rwlock_rda_autotest', true],
 218         ['rwlock_rds_wrm_autotest', true],
 219         ['rwlock_rde_wro_autotest', true],
 220         ['sched_autotest', true],
 221         ['security_autotest', false],
 222         ['spinlock_autotest', true],
 223         ['stack_autotest', false],
 224         ['stack_lf_autotest', false],
 225         ['string_autotest', true],
 226         ['tailq_autotest', true],
 227         ['ticketlock_autotest', true],
 228         ['timer_autotest', false],
 229         ['user_delay_us', true],
 230         ['version_autotest', true],
 231         ['crc_autotest', true],
 232         ['distributor_autotest', false],
 233         ['eventdev_common_autotest', true],
 234         ['fbarray_autotest', true],
 235         ['hash_readwrite_func_autotest', false],
 236         ['ipsec_autotest', true],
 237         ['kni_autotest', false],
 238         ['kvargs_autotest', true],
 239         ['member_autotest', true],
 240         ['power_cpufreq_autotest', false],
 241         ['power_autotest', true],
 242         ['power_kvm_vm_autotest', false],
 243         ['reorder_autotest', true],
 244         ['service_autotest', true],
 245         ['thash_autotest', true],
 246         ['trace_autotest', true],
 247 ]
 248
 249 # Tests known to have issues or which don't belong in other tests lists.
 250 extra_test_names = [
 251         'alarm_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 252         'cycles_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 253         'delay_us_sleep_autotest', # ee00af60170b ("test: remove strict timing requirements some tests")
 254         'red_autotest', # https://bugs.dpdk.org/show_bug.cgi?id=826
 255 ]
 256
 257 perf_test_names = [
 258         'ring_perf_autotest',
 259         'mempool_perf_autotest',
 260         'memcpy_perf_autotest',
 261         'hash_perf_autotest',
 262         'timer_perf_autotest',
 263         'reciprocal_division',
 264         'reciprocal_division_perf',
 265         'lpm_perf_autotest',
 266         'rib_slow_autotest',
 267         'fib_slow_autotest',
 268         'fib_perf_autotest',
 269         'red_all',
 270         'pie_all',
 271         'barrier_autotest',
 272         'hash_multiwriter_autotest',
 273         'timer_racecond_autotest',
 274         'efd_autotest',
 275         'hash_functions_autotest',
 276         'member_perf_autotest',
 277         'efd_perf_autotest',
 278         'lpm6_perf_autotest',
 279         'rib6_slow_autotest',
 280         'fib6_slow_autotest',
 281         'fib6_perf_autotest',
 282         'rcu_qsbr_perf_autotest',
 283         'red_perf',
 284         'pie_perf',
 285         'distributor_perf_autotest',
 286         'pmd_perf_autotest',
 287         'stack_perf_autotest',
 288         'stack_lf_perf_autotest',
 289         'rand_perf_autotest',
 290         'hash_readwrite_perf_autotest',
 291         'hash_readwrite_lf_perf_autotest',
 292         'trace_perf_autotest',
 293         'ipsec_perf_autotest',
 294         'thash_perf_autotest',
 295 ]
 296
 297 driver_test_names = [
 298         'cryptodev_aesni_mb_autotest',
 299         'cryptodev_aesni_gcm_autotest',
 300         'cryptodev_cn9k_autotest',
 301         'cryptodev_cn10k_autotest',
 302         'cryptodev_dpaa_sec_autotest',
 303         'cryptodev_dpaa2_sec_autotest',
 304         'cryptodev_null_autotest',
 305         'cryptodev_openssl_autotest',
 306         'cryptodev_openssl_asym_autotest',
 307         'cryptodev_qat_autotest',
 308         'cryptodev_sw_armv8_autotest',
 309         'cryptodev_sw_kasumi_autotest',
 310         'cryptodev_sw_mvsam_autotest',
 311         'cryptodev_sw_snow3g_autotest',
 312         'cryptodev_sw_zuc_autotest',
 313         'dmadev_autotest',
 314         'eventdev_selftest_octeontx',
 315         'eventdev_selftest_sw',
 316         'rawdev_autotest',
 317 ]
 318
 319 dump_test_names = [
 320         'dump_struct_sizes',
 321         'dump_mempool',
 322         'dump_malloc_stats',
 323         'dump_devargs',
 324         'dump_log_types',
 325         'dump_ring',
 326         'dump_physmem',
 327         'dump_memzone',
 328 ]
 329
 330 # The following linkages are an exception to allow running the
 331 # unit tests without requiring that the developer install the
 332 # DPDK libraries.  Explicit linkage of drivers (plugin libraries)
 333 # in applications should not be used.
 334 if dpdk_conf.has('RTE_MEMPOOL_RING')
 335     test_deps += 'mempool_ring'
 336 endif
 337 if dpdk_conf.has('RTE_MEMPOOL_STACK')
 338     test_deps += 'mempool_stack'
 339 endif
 340 if dpdk_conf.has('RTE_EVENT_SKELETON')
 341     test_deps += 'event_skeleton'
 342 endif
 343
 344 if dpdk_conf.has('RTE_LIB_FLOW_CLASSIFY')
 345     test_sources += 'test_flow_classify.c'
 346     fast_tests += [['flow_classify_autotest', false]]
 347 endif
 348 if dpdk_conf.has('RTE_LIB_METRICS')
 349     test_sources += ['test_metrics.c']
 350     fast_tests += [['metrics_autotest', true]]
 351 endif
 352 if dpdk_conf.has('RTE_LIB_TELEMETRY')
 353     test_sources += ['test_telemetry_json.c', 'test_telemetry_data.c']
 354     fast_tests += [['telemetry_json_autotest', true], ['telemetry_data_autotest', true]]
 355 endif
 356 if dpdk_conf.has('RTE_LIB_PIPELINE')
 357 # pipeline lib depends on port and table libs, so those must be present
 358 # if pipeline library is.
 359     test_sources += [
 360             'test_table.c',
 361             'test_table_acl.c',
 362             'test_table_combined.c',
 363             'test_table_pipeline.c',
 364             'test_table_ports.c',
 365             'test_table_tables.c',
 366     ]
 367     fast_tests += [['table_autotest', true]]
 368 endif
 369
 370 # The following linkages of drivers are required because
 371 # they are used via a driver-specific API.
 372 if dpdk_conf.has('RTE_NET_BOND')
 373     test_deps += 'net_bond'
 374     test_sources += ['test_link_bonding.c', 'test_link_bonding_rssconf.c']
 375     driver_test_names += ['link_bonding_autotest', 'link_bonding_rssconf_autotest']
 376     if dpdk_conf.has('RTE_NET_RING')
 377         test_sources += 'test_link_bonding_mode4.c'
 378         driver_test_names += 'link_bonding_mode4_autotest'
 379     endif
 380 endif
 381 if dpdk_conf.has('RTE_NET_RING')
 382     test_deps += 'net_ring'
 383     test_sources += 'test_pmd_ring_perf.c'
 384     test_sources += 'test_pmd_ring.c'
 385     test_sources += 'test_event_eth_tx_adapter.c'
 386     test_sources += 'sample_packet_forward.c'
 387     fast_tests += [['ring_pmd_autotest', true]]
 388     perf_test_names += 'ring_pmd_perf_autotest'
 389     fast_tests += [['event_eth_tx_adapter_autotest', false]]
 390     if dpdk_conf.has('RTE_LIB_BITRATESTATS')
 391         test_sources += 'test_bitratestats.c'
 392         fast_tests += [['bitratestats_autotest', true]]
 393     endif
 394     if dpdk_conf.has('RTE_LIB_LATENCYSTATS')
 395         test_sources += 'test_latencystats.c'
 396         fast_tests += [['latencystats_autotest', true]]
 397     endif
 398     if dpdk_conf.has('RTE_LIB_PDUMP')
 399         test_sources += 'test_pdump.c'
 400         fast_tests += [['pdump_autotest', true]]
 401     endif
 402 endif
 403 if dpdk_conf.has('RTE_NET_NULL')
 404     test_deps += 'net_null'
 405     test_sources += 'test_vdev.c'
 406     fast_tests += [['vdev_autotest', true]]
 407 endif
 408
 409 if dpdk_conf.has('RTE_HAS_LIBPCAP')
 410     ext_deps += pcap_dep
 411     if dpdk_conf.has('RTE_LIB_PCAPNG')
 412         test_sources += 'test_pcapng.c'
 413     endif
 414 endif
 415
 416 if cc.has_argument('-Wno-format-truncation')
 417     cflags += '-Wno-format-truncation'
 418 endif
 419
 420 # Strict-aliasing rules are violated by uint8_t[] to context size casts.
 421 cflags += '-fno-strict-aliasing'
 422
 423 # Enable using internal APIs in unit tests
 424 cflags += ['-DALLOW_INTERNAL_API']
 425
 426 test_dep_objs = []
 427 if dpdk_conf.has('RTE_LIB_COMPRESSDEV')
 428     compress_test_dep = dependency('zlib', required: false, method: 'pkg-config')
 429     if compress_test_dep.found()
 430         test_dep_objs += compress_test_dep
 431         test_sources += 'test_compressdev.c'
 432         fast_tests += [['compressdev_autotest', false]]
 433     endif
 434 endif
 435
 436 if dpdk_conf.has('RTE_CRYPTO_SCHEDULER')
 437     driver_test_names += 'cryptodev_scheduler_autotest'
 438     test_deps += 'crypto_scheduler'
 439 endif
 440
 441 foreach d:test_deps
 442     def_lib = get_option('default_library')
 443     test_dep_objs += get_variable(def_lib + '_rte_' + d)
 444 endforeach
 445
 446 link_libs = []
 447 if get_option('default_library') == 'static'
 448     link_libs = dpdk_static_libraries + dpdk_drivers
 449 endif
 450
 451 dpdk_test = executable('dpdk-test',
 452         test_sources,
 453         link_whole: link_libs,
 454         dependencies: test_dep_objs + ext_deps,
 455         c_args: cflags,
 456         install_rpath: join_paths(get_option('prefix'),
 457              driver_install_path),
 458         install: true)
 459
 460 has_hugepage = run_command(py3, 'has_hugepage.py', check: true).stdout().strip() != '0'
 461 message('hugepage availability: @0@'.format(has_hugepage))
 462
 463 # some perf tests (eg: memcpy perf autotest)take very long
 464 # to complete, so timeout to 10 minutes
 465 timeout_seconds = 600
 466 timeout_seconds_fast = 10
 467
 468 foreach arg : fast_tests
 469     test_args = []
 470     run_test = true
 471     if not has_hugepage
 472         if arg[1]
 473             test_args += ['--no-huge', '-m', '2048']
 474         else
 475             run_test = false
 476         endif
 477     endif
 478
 479     if (get_option('default_library') == 'shared' and
 480         arg[0] == 'event_eth_tx_adapter_autotest')
 481         foreach drv:dpdk_drivers
 482             test_args += ['-d', drv.full_path().split('.a')[0] + '.so']
 483         endforeach
 484     endif
 485     if is_linux
 486         test_args += ['--file-prefix=@0@'.format(arg[0])]
 487     endif
 488
 489     if run_test
 490         test(arg[0], dpdk_test,
 491                 env : ['DPDK_TEST=' + arg[0]],
 492                 args : test_args,
 493                 timeout : timeout_seconds_fast,
 494                 is_parallel : false,
 495                 suite : 'fast-tests')
 496     endif
 497 endforeach
 498
 499 foreach arg : perf_test_names
 500     test(arg, dpdk_test,
 501             env : ['DPDK_TEST=' + arg],
 502             timeout : timeout_seconds,
 503             is_parallel : false,
 504             suite : 'perf-tests')
 505 endforeach
 506
 507 foreach arg : driver_test_names
 508     test(arg, dpdk_test,
 509             env : ['DPDK_TEST=' + arg],
 510             timeout : timeout_seconds,
 511             is_parallel : false,
 512             suite : 'driver-tests')
 513 endforeach
 514
 515 foreach arg : dump_test_names
 516     test(arg, dpdk_test,
 517             env : ['DPDK_TEST=' + arg],
 518             timeout : timeout_seconds,
 519             is_parallel : false,
 520             suite : 'debug-tests')
 521 endforeach
 522
 523 foreach arg : extra_test_names
 524     test(arg, dpdk_test,
 525             env : ['DPDK_TEST=' + arg],
 526             timeout : timeout_seconds,
 527             is_parallel : false,
 528             suite : 'extra-tests')
 529 endforeach