buildtools/chkincs/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2021 Intel Corporation
   3
   4 if not get_option('check_includes')
   5     build = false
   6     subdir_done()
   7 endif
   8
   9 gen_c_file_for_header = find_program('gen_c_file_for_header.py')
  10 gen_c_files = generator(gen_c_file_for_header,
  11         output: '@BASENAME@.c',
  12         arguments: ['@INPUT@', '@OUTPUT@'])
  13
  14 cflags = machine_args
  15 cflags += '-DALLOW_EXPERIMENTAL_API'
  16
  17 sources = files('main.c')
  18 sources += gen_c_files.process(dpdk_chkinc_headers)
  19
  20 deps = []
  21 foreach l:enabled_libs
  22     deps += get_variable('shared_rte_' + l)
  23 endforeach
  24
  25 executable('chkincs', sources,
  26         c_args: cflags,
  27         include_directories: includes,
  28         dependencies: deps,
  29         install: false)
  30
  31 # run tests for c++ builds also
  32 if not add_languages('cpp', required: false)
  33     subdir_done()
  34 endif
  35
  36 gen_cpp_files = generator(gen_c_file_for_header,
  37         output: '@BASENAME@.cpp',
  38         arguments: ['@INPUT@', '@OUTPUT@'])
  39
  40 cpp_sources = files('main.cpp')
  41 cpp_sources += gen_cpp_files.process(dpdk_chkinc_headers)
  42
  43 executable('chkincs-cpp', cpp_sources,
  44         cpp_args: ['-include', 'rte_config.h', cflags],
  45         include_directories: includes,
  46         dependencies: deps,
  47         install: false)