buildtools/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 pkgconf = find_program('pkg-config', 'pkgconf', required: false)
   5 check_symbols = find_program('check-symbols.sh')
   6 ldflags_ibverbs_static = find_program('options-ibverbs-static.sh')
   7 binutils_avx512_check = find_program('binutils-avx512-check.sh')
   8
   9 python3 = import('python').find_installation(required: false)
  10 if python3.found()
  11     py3 = [python3]
  12 else
  13     py3 = ['meson', 'runpython']
  14 endif
  15 echo = py3 + ['-c', 'import sys; print(*sys.argv[1:])']
  16 list_dir_globs = py3 + files('list-dir-globs.py')
  17 map_to_win_cmd = py3 + files('map_to_win.py')
  18 sphinx_wrapper = py3 + files('call-sphinx-build.py')
  19 get_cpu_count_cmd = py3 + files('get-cpu-count.py')
  20 get_numa_count_cmd = py3 + files('get-numa-count.py')
  21
  22 # select library and object file format
  23 pmdinfo = py3 + files('gen-pmdinfo-cfile.py') + [meson.current_build_dir()]
  24 pmdinfogen = py3 + files('pmdinfogen.py')
  25 if host_machine.system() == 'windows'
  26     if cc.get_id() == 'gcc'
  27         pmdinfo += 'ar'
  28     else
  29         pmdinfo += 'llvm-ar'
  30     endif
  31     pmdinfogen += 'coff'
  32 else
  33     pmdinfo += 'ar'
  34     pmdinfogen += 'elf'
  35 endif
  36
  37 # TODO: starting from Meson 0.51.0 use
  38 #     python3 = import('python').find_installation('python',
  39 #        modules : python3_required_modules)
  40 python3_required_modules = []
  41 if host_machine.system() != 'windows'
  42     python3_required_modules = ['elftools']
  43 endif
  44 foreach module : python3_required_modules
  45     script = 'import importlib.util; import sys; exit(importlib.util.find_spec("@0@") is None)'
  46     if run_command(py3, '-c', script.format(module)).returncode() != 0
  47         error('missing python module: @0@'.format(module))
  48     endif
  49 endforeach