config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # for checking defines we need to use the correct compiler flags
   6 march_opt = '-march=@0@'.format(machine)
   7
   8 arm_force_native_march = false
   9 arm_force_default_march = (machine == 'default')
  10
  11 flags_common_default = [
  12         # Accelarate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
  13         # to determine the best threshold in code. Refer to notes in source file
  14         # (lib/librte_eal/common/include/arch/arm/rte_memcpy_64.h) for more info.
  15         ['RTE_ARCH_ARM64_MEMCPY', false],
  16         #       ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  17         #       ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  18         # Leave below RTE_ARM64_MEMCPY_xxx options commented out, unless there're
  19         # strong reasons.
  20         #       ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  21         #       ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  22         #       ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  23
  24         ['RTE_LIBRTE_FM10K_PMD', false],
  25         ['RTE_LIBRTE_SFC_EFX_PMD', false],
  26         ['RTE_LIBRTE_AVP_PMD', false],
  27
  28         ['RTE_SCHED_VECTOR', false],
  29 ]
  30
  31 flags_generic = [
  32         ['RTE_MACHINE', '"armv8a"'],
  33         ['RTE_MAX_LCORE', 256],
  34         ['RTE_USE_C11_MEM_MODEL', true],
  35         ['RTE_CACHE_LINE_SIZE', 128]]
  36 flags_cavium = [
  37         ['RTE_CACHE_LINE_SIZE', 128],
  38         ['RTE_MAX_NUMA_NODES', 2],
  39         ['RTE_MAX_LCORE', 96],
  40         ['RTE_MAX_VFIO_GROUPS', 128]]
  41 flags_dpaa = [
  42         ['RTE_MACHINE', '"dpaa"'],
  43         ['RTE_USE_C11_MEM_MODEL', true],
  44         ['RTE_CACHE_LINE_SIZE', 64],
  45         ['RTE_MAX_NUMA_NODES', 1],
  46         ['RTE_MAX_LCORE', 16]]
  47 flags_dpaa2 = [
  48         ['RTE_MACHINE', '"dpaa2"'],
  49         ['RTE_USE_C11_MEM_MODEL', true],
  50         ['RTE_CACHE_LINE_SIZE', 64],
  51         ['RTE_MAX_NUMA_NODES', 1],
  52         ['RTE_MAX_LCORE', 16],
  53         ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false]]
  54 flags_default_extra = []
  55 flags_thunderx_extra = [
  56         ['RTE_MACHINE', '"thunderx"'],
  57         ['RTE_USE_C11_MEM_MODEL', false]]
  58 flags_thunderx2_extra = [
  59         ['RTE_MACHINE', '"thunderx2"'],
  60         ['RTE_CACHE_LINE_SIZE', 64],
  61         ['RTE_MAX_NUMA_NODES', 2],
  62         ['RTE_MAX_LCORE', 256],
  63         ['RTE_USE_C11_MEM_MODEL', true]]
  64 flags_octeontx2_extra = [
  65         ['RTE_MACHINE', '"octeontx2"'],
  66         ['RTE_MAX_NUMA_NODES', 1],
  67         ['RTE_MAX_LCORE', 24],
  68         ['RTE_EAL_IGB_UIO', false],
  69         ['RTE_USE_C11_MEM_MODEL', true]]
  70
  71 machine_args_generic = [
  72         ['default', ['-march=armv8-a+crc+crypto']],
  73         ['native', ['-march=native']],
  74         ['0xd03', ['-mcpu=cortex-a53']],
  75         ['0xd04', ['-mcpu=cortex-a35']],
  76         ['0xd07', ['-mcpu=cortex-a57']],
  77         ['0xd08', ['-mcpu=cortex-a72']],
  78         ['0xd09', ['-mcpu=cortex-a73']],
  79         ['0xd0a', ['-mcpu=cortex-a75']]]
  80
  81 machine_args_cavium = [
  82         ['default', ['-march=armv8-a+crc+crypto','-mcpu=thunderx']],
  83         ['native', ['-march=native']],
  84         ['0xa1', ['-mcpu=thunderxt88'], flags_thunderx_extra],
  85         ['0xa2', ['-mcpu=thunderxt81'], flags_thunderx_extra],
  86         ['0xa3', ['-mcpu=thunderxt83'], flags_thunderx_extra],
  87         ['0xaf', ['-mcpu=thunderx2t99'], flags_thunderx2_extra],
  88         ['0xb2', ['-mcpu=octeontx2'], flags_octeontx2_extra]]
  89
  90 ## Arm implementer ID (ARM DDI 0487C.a, Section G7.2.106, Page G7-5321)
  91 impl_generic = ['Generic armv8', flags_generic, machine_args_generic]
  92 impl_0x41 = ['Arm', flags_generic, machine_args_generic]
  93 impl_0x42 = ['Broadcom', flags_generic, machine_args_generic]
  94 impl_0x43 = ['Cavium', flags_cavium, machine_args_cavium]
  95 impl_0x44 = ['DEC', flags_generic, machine_args_generic]
  96 impl_0x49 = ['Infineon', flags_generic, machine_args_generic]
  97 impl_0x4d = ['Motorola', flags_generic, machine_args_generic]
  98 impl_0x4e = ['NVIDIA', flags_generic, machine_args_generic]
  99 impl_0x50 = ['AppliedMicro', flags_generic, machine_args_generic]
 100 impl_0x51 = ['Qualcomm', flags_generic, machine_args_generic]
 101 impl_0x53 = ['Samsung', flags_generic, machine_args_generic]
 102 impl_0x56 = ['Marvell', flags_generic, machine_args_generic]
 103 impl_0x69 = ['Intel', flags_generic, machine_args_generic]
 104 impl_dpaa = ['NXP DPAA', flags_dpaa, machine_args_generic]
 105 impl_dpaa2 = ['NXP DPAA2', flags_dpaa2, machine_args_generic]
 106
 107 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 108
 109 if not dpdk_conf.get('RTE_ARCH_64')
 110         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 111         dpdk_conf.set('RTE_ARCH_ARM', 1)
 112         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 113         # the minimum architecture supported, armv7-a, needs the following,
 114         # mk/machine/armv7a/rte.vars.mk sets it too
 115         machine_args += '-mfpu=neon'
 116 else
 117         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)
 118         dpdk_conf.set('RTE_ARCH_ARM64', 1)
 119
 120         machine = []
 121         cmd_generic = ['generic', '', '', 'default', '']
 122         cmd_output = cmd_generic # Set generic by default
 123         machine_args = [] # Clear previous machine args
 124         if arm_force_default_march and not meson.is_cross_build()
 125                 machine = impl_generic
 126                 impl_pn = 'default'
 127         elif not meson.is_cross_build()
 128                 # The script returns ['Implementer', 'Variant', 'Architecture',
 129                 # 'Primary Part number', 'Revision']
 130                 detect_vendor = find_program(join_paths(
 131                                 meson.current_source_dir(), 'armv8_machine.py'))
 132                 cmd = run_command(detect_vendor.path())
 133                 if cmd.returncode() == 0
 134                         cmd_output = cmd.stdout().to_lower().strip().split(' ')
 135                 endif
 136                 # Set to generic if variable is not found
 137                 machine = get_variable('impl_' + cmd_output[0], ['generic'])
 138                 if machine[0] == 'generic'
 139                         machine = impl_generic
 140                         cmd_output = cmd_generic
 141                 endif
 142                 impl_pn = cmd_output[3]
 143                 if arm_force_native_march == true
 144                         impl_pn = 'native'
 145                 endif
 146         else
 147                 impl_id = meson.get_cross_property('implementor_id', 'generic')
 148                 impl_pn = meson.get_cross_property('implementor_pn', 'default')
 149                 machine = get_variable('impl_' + impl_id)
 150         endif
 151
 152         # Apply Common Defaults. These settings may be overwritten by machine
 153         # settings later.
 154         foreach flag: flags_common_default
 155                 if flag.length() > 0
 156                         dpdk_conf.set(flag[0], flag[1])
 157                 endif
 158         endforeach
 159
 160         message('Implementer : ' + machine[0])
 161         foreach flag: machine[1]
 162                 if flag.length() > 0
 163                         dpdk_conf.set(flag[0], flag[1])
 164                 endif
 165         endforeach
 166
 167         foreach marg: machine[2]
 168                 if marg[0] == impl_pn
 169                         foreach flag: marg[1]
 170                                 if cc.has_argument(flag)
 171                                         machine_args += flag
 172                                 endif
 173                         endforeach
 174                         # Apply any extra machine specific flags.
 175                         foreach flag: marg.get(2, flags_default_extra)
 176                                 if flag.length() > 0
 177                                         dpdk_conf.set(flag[0], flag[1])
 178                                 endif
 179                         endforeach
 180                 endif
 181         endforeach
 182 endif
 183 message(machine_args)
 184
 185 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 186     cc.get_define('__aarch64__', args: machine_args) != '')
 187         dpdk_conf.set('RTE_MACHINE_CPUFLAG_NEON', 1)
 188         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 189 endif
 190
 191 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 192         dpdk_conf.set('RTE_MACHINE_CPUFLAG_CRC32', 1)
 193         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 194 endif
 195
 196 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 197         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
 198         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PMULL', 1)
 199         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA1', 1)
 200         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA2', 1)
 201         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 202         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 203 endif