config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # for checking defines we need to use the correct compiler flags
   6 march_opt = '-march=@0@'.format(machine)
   7
   8 machine_args_generic = [
   9         ['default', ['-march=armv8-a+crc+crypto']]]
  10 machine_args_cavium = [
  11         ['default', ['-march=armv8-a+crc+crypto','-mcpu=thunderx']],
  12         ['0xa1', ['-mcpu=thunderxt88']],
  13         ['0xa2', ['-mcpu=thunderxt81']],
  14         ['0xa3', ['-mcpu=thunderxt83']]]
  15
  16 flags_generic = [[]]
  17 flags_cavium = [
  18         ['RTE_MACHINE', '"thunderx"'],
  19         ['RTE_CACHE_LINE_SIZE', 128],
  20         ['RTE_MAX_NUMA_NODES', 2],
  21         ['RTE_MAX_LCORE', 96],
  22         ['RTE_MAX_VFIO_GROUPS', 128],
  23         ['RTE_RING_USE_C11_MEM_MODEL', false]]
  24
  25 impl_generic = ['Generic armv8', flags_generic, machine_args_generic]
  26 impl_0x43 = ['Cavium', flags_cavium, machine_args_cavium]
  27
  28 if cc.get_define('__clang__') != ''
  29         dpdk_conf.set_quoted('RTE_TOOLCHAIN', 'clang')
  30         dpdk_conf.set('RTE_TOOLCHAIN_CLANG', 1)
  31 else
  32         dpdk_conf.set_quoted('RTE_TOOLCHAIN', 'gcc')
  33         dpdk_conf.set('RTE_TOOLCHAIN_GCC', 1)
  34 endif
  35
  36 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
  37
  38 if cc.sizeof('void *') != 8
  39         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
  40         dpdk_conf.set('RTE_ARCH_ARM', 1)
  41         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
  42 else
  43         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 128)
  44         dpdk_conf.set('RTE_ARCH_ARM64', 1)
  45         dpdk_conf.set('RTE_ARCH_64', 1)
  46
  47         machine = []
  48         cmd_generic = ['generic', '', '', 'default', '']
  49         cmd_output = cmd_generic # Set generic by default
  50         machine_args = [] # Clear previous machine args
  51         if not meson.is_cross_build()
  52                 # The script returns ['Implementer', 'Variant', 'Architecture',
  53                 # 'Primary Part number', 'Revision']
  54                 detect_vendor = find_program(join_paths(
  55                                 meson.current_source_dir(), 'armv8_machine.py'))
  56                 cmd = run_command(detect_vendor.path())
  57                 if cmd.returncode() == 0
  58                         cmd_output = cmd.stdout().strip().split(' ')
  59                 endif
  60                 # Set to generic if variable is not found
  61                 machine = get_variable('impl_' + cmd_output[0], 'generic')
  62         else
  63                 impl_id = meson.get_cross_property('implementor_id', 'generic')
  64                 machine = get_variable('impl_' + impl_id)
  65         endif
  66
  67         if machine == 'generic'
  68                 machine = impl_generic
  69                 cmd_output = cmd_generic
  70         endif
  71
  72         message('Implementer : ' + machine[0])
  73         foreach flag: machine[1]
  74                 if flag.length() > 0
  75                         dpdk_conf.set(flag[0], flag[1])
  76                 endif
  77         endforeach
  78         # Primary part number based mcpu flags are supported
  79         # for gcc versions > 7
  80         if cc.version().version_compare(
  81                         '<7.0') or cmd_output.length() == 0
  82                 foreach marg: machine[2]
  83                         if marg[0] == 'default'
  84                                 foreach f: marg[1]
  85                                         machine_args += f
  86                                 endforeach
  87                         endif
  88                 endforeach
  89         else
  90                 foreach marg: machine[2]
  91                         if marg[0] == cmd_output[3]
  92                                 foreach f: marg[1]
  93                                         machine_args += f
  94                                 endforeach
  95                         endif
  96                 endforeach
  97         endif
  98 endif
  99 message(machine_args)
 100
 101 if cc.get_define('__ARM_NEON', args: machine_args) != ''
 102         dpdk_conf.set('RTE_MACHINE_CPUFLAG_NEON', 1)
 103         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 104 endif
 105
 106 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 107         dpdk_conf.set('RTE_MACHINE_CPUFLAG_CRC32', 1)
 108         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 109 endif
 110
 111 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 112         dpdk_conf.set('RTE_MACHINE_CPUFLAG_AES', 1)
 113         dpdk_conf.set('RTE_MACHINE_CPUFLAG_PMULL', 1)
 114         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA1', 1)
 115         dpdk_conf.set('RTE_MACHINE_CPUFLAG_SHA2', 1)
 116         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 117         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 118 endif