config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4 # Copyright(c) 2021 PANTHEON.tech s.r.o.
   5
   6 # common flags to all aarch64 builds, with lowest priority
   7 flags_common = [
   8         # Accelerate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
   9         # to determine the best threshold in code. Refer to notes in source file
  10         # (lib/eal/arm/include/rte_memcpy_64.h) for more info.
  11         ['RTE_ARCH_ARM64_MEMCPY', false],
  12         #    ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  13         #    ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  14         # Leave below RTE_ARM64_MEMCPY_xxx options commented out,
  15         # unless there are strong reasons.
  16         #    ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  17         #    ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  18         #    ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  19
  20         ['RTE_SCHED_VECTOR', false],
  21         ['RTE_ARM_USE_WFE', false],
  22         ['RTE_ARCH_ARM64', true],
  23         ['RTE_CACHE_LINE_SIZE', 128]
  24 ]
  25
  26 ## Part numbers are specific to Arm implementers
  27 # implementer specific aarch64 flags have middle priority
  28 #     (will overwrite common flags)
  29 # part number specific aarch64 flags have higher priority
  30 #     (will overwrite both common and implementer specific flags)
  31 implementer_generic = {
  32     'description': 'Generic armv8',
  33     'flags': [
  34         ['RTE_MACHINE', '"armv8a"'],
  35         ['RTE_USE_C11_MEM_MODEL', true],
  36         ['RTE_MAX_LCORE', 256],
  37         ['RTE_MAX_NUMA_NODES', 4]
  38     ],
  39     'part_number_config': {
  40         'generic': {'machine_args': ['-march=armv8-a+crc', '-moutline-atomics']}
  41     }
  42 }
  43
  44 part_number_config_arm = {
  45     '0xd03': {'machine_args':  ['-mcpu=cortex-a53']},
  46     '0xd04': {'machine_args':  ['-mcpu=cortex-a35']},
  47     '0xd07': {'machine_args':  ['-mcpu=cortex-a57']},
  48     '0xd08': {'machine_args':  ['-mcpu=cortex-a72']},
  49     '0xd09': {'machine_args':  ['-mcpu=cortex-a73']},
  50     '0xd0a': {'machine_args':  ['-mcpu=cortex-a75']},
  51     '0xd0b': {'machine_args':  ['-mcpu=cortex-a76']},
  52     '0xd0c': {
  53         'machine_args':  ['-march=armv8.2-a+crypto', '-mcpu=neoverse-n1'],
  54         'flags': [
  55             ['RTE_MACHINE', '"neoverse-n1"'],
  56             ['RTE_ARM_FEATURE_ATOMICS', true],
  57             ['RTE_MAX_MEM_MB', 1048576],
  58             ['RTE_MAX_LCORE', 160],
  59             ['RTE_MAX_NUMA_NODES', 2]
  60         ]
  61     },
  62     '0xd49': {
  63         'machine_args':  ['-march=armv8.5-a+crypto+sve2'],
  64         'flags': [
  65             ['RTE_MACHINE', '"neoverse-n2"'],
  66             ['RTE_ARM_FEATURE_ATOMICS', true],
  67             ['RTE_MAX_LCORE', 64],
  68             ['RTE_MAX_NUMA_NODES', 1]
  69         ]
  70     }
  71 }
  72 implementer_arm = {
  73     'description': 'Arm',
  74     'flags': [
  75         ['RTE_MACHINE', '"armv8a"'],
  76         ['RTE_USE_C11_MEM_MODEL', true],
  77         ['RTE_CACHE_LINE_SIZE', 64],
  78         ['RTE_MAX_LCORE', 64],
  79         ['RTE_MAX_NUMA_NODES', 4]
  80     ],
  81     'part_number_config': part_number_config_arm
  82 }
  83
  84 flags_part_number_thunderx = [
  85     ['RTE_MACHINE', '"thunderx"'],
  86     ['RTE_USE_C11_MEM_MODEL', false]
  87 ]
  88 implementer_cavium = {
  89     'description': 'Cavium',
  90     'flags': [
  91         ['RTE_MAX_VFIO_GROUPS', 128],
  92         ['RTE_MAX_LCORE', 96],
  93         ['RTE_MAX_NUMA_NODES', 2]
  94     ],
  95     'part_number_config': {
  96         '0xa1': {
  97             'machine_args': ['-mcpu=thunderxt88'],
  98             'flags': flags_part_number_thunderx
  99         },
 100         '0xa2': {
 101             'machine_args': ['-mcpu=thunderxt81'],
 102             'flags': flags_part_number_thunderx
 103         },
 104         '0xa3': {
 105             'machine_args': ['-mcpu=thunderxt83'],
 106             'flags': flags_part_number_thunderx
 107         },
 108         '0xaf': {
 109             'machine_args': ['-march=armv8.1-a+crc+crypto', '-mcpu=thunderx2t99'],
 110             'flags': [
 111                 ['RTE_MACHINE', '"thunderx2"'],
 112                 ['RTE_ARM_FEATURE_ATOMICS', true],
 113                 ['RTE_USE_C11_MEM_MODEL', true],
 114                 ['RTE_CACHE_LINE_SIZE', 64],
 115                 ['RTE_MAX_LCORE', 256]
 116             ]
 117         },
 118         '0xb2': {
 119             'machine_args': ['-march=armv8.2-a+crc+crypto+lse', '-mcpu=octeontx2'],
 120             'flags': [
 121                 ['RTE_MACHINE', '"octeontx2"'],
 122                 ['RTE_ARM_FEATURE_ATOMICS', true],
 123                 ['RTE_USE_C11_MEM_MODEL', true],
 124                 ['RTE_MAX_LCORE', 36],
 125                 ['RTE_MAX_NUMA_NODES', 1]
 126             ]
 127         }
 128     }
 129 }
 130
 131 implementer_ampere = {
 132     'description': 'Ampere Computing',
 133     'flags': [
 134         ['RTE_MACHINE', '"emag"'],
 135         ['RTE_CACHE_LINE_SIZE', 64],
 136         ['RTE_MAX_LCORE', 32],
 137         ['RTE_MAX_NUMA_NODES', 1]
 138     ],
 139     'part_number_config': {
 140         '0x0': {'machine_args':  ['-march=armv8-a+crc+crypto', '-mtune=emag']}
 141     }
 142 }
 143
 144 implementer_hisilicon = {
 145     'description': 'HiSilicon',
 146     'flags': [
 147         ['RTE_USE_C11_MEM_MODEL', true],
 148         ['RTE_CACHE_LINE_SIZE', 128]
 149     ],
 150     'part_number_config': {
 151         '0xd01': {
 152             'machine_args': ['-march=armv8.2-a+crypto', '-mtune=tsv110'],
 153             'flags': [
 154                 ['RTE_MACHINE', '"Kunpeng 920"'],
 155                 ['RTE_ARM_FEATURE_ATOMICS', true],
 156                 ['RTE_MAX_LCORE', 256],
 157                 ['RTE_MAX_NUMA_NODES', 8]
 158             ]
 159         },
 160         '0xd02': {
 161             'machine_args': ['-march=armv8.2-a+crypto+sve'],
 162             'flags': [
 163                 ['RTE_MACHINE', '"Kunpeng 930"'],
 164                 ['RTE_ARM_FEATURE_ATOMICS', true],
 165                 ['RTE_MAX_LCORE', 1280],
 166                 ['RTE_MAX_NUMA_NODES', 16]
 167             ]
 168         }
 169     }
 170 }
 171
 172 implementer_qualcomm = {
 173     'description': 'Qualcomm',
 174     'flags': [
 175         ['RTE_MACHINE', '"armv8a"'],
 176         ['RTE_USE_C11_MEM_MODEL', true],
 177         ['RTE_CACHE_LINE_SIZE', 64],
 178         ['RTE_MAX_LCORE', 64],
 179         ['RTE_MAX_NUMA_NODES', 1]
 180     ],
 181     'part_number_config': {
 182         '0x800': {'machine_args':  ['-march=armv8-a+crc']},
 183         '0xc00': {'machine_args':  ['-march=armv8-a+crc']},
 184     }
 185 }
 186
 187 ## Arm implementers (ID from MIDR in Arm Architecture Reference Manual)
 188 implementers = {
 189     'generic': implementer_generic,
 190     '0x41': implementer_arm,
 191     '0x43': implementer_cavium,
 192     '0x48': implementer_hisilicon,
 193     '0x50': implementer_ampere,
 194     '0x51': implementer_qualcomm
 195 }
 196
 197 # SoC specific aarch64 flags have the highest priority
 198 #     (will overwrite all other flags)
 199 soc_generic = {
 200     'description': 'Generic un-optimized build for all aarch64 machines',
 201     'implementer': 'generic',
 202     'part_number': 'generic'
 203 }
 204
 205 soc_armada = {
 206     'description': 'Marvell ARMADA',
 207     'implementer': '0x41',
 208     'part_number': '0xd08',
 209     'flags': [
 210         ['RTE_MAX_LCORE', 16],
 211         ['RTE_MAX_NUMA_NODES', 1]
 212     ],
 213     'numa': false
 214 }
 215
 216 soc_bluefield = {
 217     'description': 'NVIDIA BlueField',
 218     'implementer': '0x41',
 219     'part_number': '0xd08',
 220     'flags': [
 221         ['RTE_MAX_LCORE', 16],
 222         ['RTE_MAX_NUMA_NODES', 1]
 223     ],
 224     'numa': false
 225 }
 226
 227 soc_centriq2400 = {
 228     'description': 'Qualcomm Centriq 2400',
 229     'implementer': '0x51',
 230     'part_number': '0xc00',
 231     'numa': false
 232 }
 233
 234 soc_cn10k = {
 235     'description' : 'Marvell OCTEON 10',
 236     'implementer' : '0x41',
 237     'flags': [
 238         ['RTE_MAX_LCORE', 24],
 239         ['RTE_MAX_NUMA_NODES', 1]
 240     ],
 241     'part_number': '0xd49',
 242     'numa': false
 243 }
 244
 245 soc_dpaa = {
 246     'description': 'NXP DPAA',
 247     'implementer': '0x41',
 248     'part_number': '0xd08',
 249     'flags': [
 250         ['RTE_MACHINE', '"dpaa"'],
 251         ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false],
 252         ['RTE_MAX_LCORE', 16],
 253         ['RTE_MAX_NUMA_NODES', 1]
 254     ],
 255     'numa': false
 256 }
 257
 258 soc_emag = {
 259     'description': 'Ampere eMAG',
 260     'implementer': '0x50',
 261     'part_number': '0x0'
 262 }
 263
 264 soc_graviton2 = {
 265     'description': 'AWS Graviton2',
 266     'implementer': '0x41',
 267     'part_number': '0xd0c',
 268     'numa': false
 269 }
 270
 271 soc_kunpeng920 = {
 272     'description': 'HiSilicon Kunpeng 920',
 273     'implementer': '0x48',
 274     'part_number': '0xd01',
 275     'numa': true
 276 }
 277
 278 soc_kunpeng930 = {
 279     'description': 'HiSilicon Kunpeng 930',
 280     'implementer': '0x48',
 281     'part_number': '0xd02',
 282     'numa': true
 283 }
 284
 285 soc_n1sdp = {
 286     'description': 'Arm Neoverse N1SDP',
 287     'implementer': '0x41',
 288     'part_number': '0xd0c',
 289     'flags': [
 290         ['RTE_MAX_LCORE', 4]
 291     ],
 292     'numa': false
 293 }
 294
 295 soc_n2 = {
 296     'description': 'Arm Neoverse N2',
 297     'implementer': '0x41',
 298     'part_number': '0xd49',
 299     'numa': false
 300 }
 301
 302 soc_octeontx2 = {
 303     'description': 'Marvell OCTEON TX2',
 304     'implementer': '0x43',
 305     'part_number': '0xb2',
 306     'numa': false
 307 }
 308
 309 soc_stingray = {
 310     'description': 'Broadcom Stingray',
 311     'implementer': '0x41',
 312     'flags': [
 313         ['RTE_MAX_LCORE', 16],
 314         ['RTE_MAX_NUMA_NODES', 1]
 315     ],
 316     'part_number': '0xd08',
 317     'numa': false
 318 }
 319
 320 soc_thunderx2 = {
 321     'description': 'Marvell ThunderX2 T99',
 322     'implementer': '0x43',
 323     'part_number': '0xaf'
 324 }
 325
 326 soc_thunderxt88 = {
 327     'description': 'Marvell ThunderX T88',
 328     'implementer': '0x43',
 329     'part_number': '0xa1'
 330 }
 331
 332 '''
 333 Start of SoCs list
 334 generic:     Generic un-optimized build for all aarch64 machines.
 335 armada:      Marvell ARMADA
 336 bluefield:   NVIDIA BlueField
 337 centriq2400: Qualcomm Centriq 2400
 338 cn10k:       Marvell OCTEON 10
 339 dpaa:        NXP DPAA
 340 emag:        Ampere eMAG
 341 graviton2:   AWS Graviton2
 342 kunpeng920:  HiSilicon Kunpeng 920
 343 kunpeng930:  HiSilicon Kunpeng 930
 344 n1sdp:       Arm Neoverse N1SDP
 345 n2:          Arm Neoverse N2
 346 octeontx2:   Marvell OCTEON TX2
 347 stingray:    Broadcom Stingray
 348 thunderx2:   Marvell ThunderX2 T99
 349 thunderxt88: Marvell ThunderX T88
 350 End of SoCs list
 351 '''
 352 # The string above is included in the documentation, keep it in sync with the
 353 # SoCs list below.
 354 socs = {
 355     'generic': soc_generic,
 356     'armada': soc_armada,
 357     'bluefield': soc_bluefield,
 358     'centriq2400': soc_centriq2400,
 359     'cn10k' : soc_cn10k,
 360     'dpaa': soc_dpaa,
 361     'emag': soc_emag,
 362     'graviton2': soc_graviton2,
 363     'kunpeng920': soc_kunpeng920,
 364     'kunpeng930': soc_kunpeng930,
 365     'n1sdp': soc_n1sdp,
 366     'n2': soc_n2,
 367     'octeontx2': soc_octeontx2,
 368     'stingray': soc_stingray,
 369     'thunderx2': soc_thunderx2,
 370     'thunderxt88': soc_thunderxt88
 371 }
 372
 373 dpdk_conf.set('RTE_ARCH_ARM', 1)
 374 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 375
 376 if dpdk_conf.get('RTE_ARCH_32')
 377     # armv7 build
 378     dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 379     dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 380     # the minimum architecture supported, armv7-a, needs the following,
 381     machine_args += '-mfpu=neon'
 382 else
 383     # aarch64 build
 384     soc_config = {}
 385     if not meson.is_cross_build()
 386         # for backwards compatibility:
 387         #   machine=native is the same behavior as soc=native
 388         #   machine=generic/default is the same as soc=generic
 389         # cpu_instruction_set holds the proper value - native, generic or cpu
 390         # the old behavior only distinguished between generic and native build
 391         if machine != 'auto'
 392             if cpu_instruction_set == 'generic'
 393                 soc = 'generic'
 394             else
 395                 soc = 'native'
 396             endif
 397         else
 398             soc = platform
 399         endif
 400         if soc == 'native'
 401             # native build
 402             # The script returns ['Implementer', 'Variant', 'Architecture',
 403             # 'Primary Part number', 'Revision']
 404             detect_vendor = find_program(join_paths(meson.current_source_dir(),
 405                                                     'armv8_machine.py'))
 406             cmd = run_command(detect_vendor.path())
 407             if cmd.returncode() == 0
 408                 cmd_output = cmd.stdout().to_lower().strip().split(' ')
 409                 implementer_id = cmd_output[0]
 410                 part_number = cmd_output[3]
 411             else
 412                 error('Error when getting Arm Implementer ID and part number.')
 413             endif
 414         else
 415             # SoC build
 416             soc_config = socs.get(soc, {'not_supported': true})
 417         endif
 418     else
 419         # cross build
 420         soc = meson.get_cross_property('platform', '')
 421         if soc == ''
 422             error('Arm SoC must be specified in the cross file.')
 423         endif
 424         soc_config = socs.get(soc, {'not_supported': true})
 425     endif
 426
 427     soc_flags = []
 428     if soc_config.has_key('not_supported')
 429         error('SoC @0@ not supported.'.format(soc))
 430     elif soc_config != {}
 431         implementer_id = soc_config['implementer']
 432         implementer_config = implementers[implementer_id]
 433         part_number = soc_config['part_number']
 434         soc_flags = soc_config.get('flags', [])
 435         if not soc_config.get('numa', true)
 436             has_libnuma = 0
 437         endif
 438
 439         disable_drivers += ',' + soc_config.get('disable_drivers', '')
 440         enable_drivers += ',' + soc_config.get('enable_drivers', '')
 441     endif
 442
 443     if implementers.has_key(implementer_id)
 444         implementer_config = implementers[implementer_id]
 445     else
 446         error('Unsupported Arm implementer: @0@. '.format(implementer_id) +
 447               'Please add support for it or use the generic ' +
 448               '(-Dplatform=generic) build.')
 449     endif
 450
 451     message('Arm implementer: ' + implementer_config['description'])
 452     message('Arm part number: ' + part_number)
 453
 454     part_number_config = implementer_config['part_number_config']
 455     if part_number_config.has_key(part_number)
 456         # use the specified part_number machine args if found
 457         part_number_config = part_number_config[part_number]
 458     else
 459         # unknown part number
 460         error('Unsupported part number @0@ of implementer @1@. '
 461               .format(part_number, implementer_id) +
 462               'Please add support for it or use the generic ' +
 463               '(-Dplatform=generic) build.')
 464     endif
 465
 466     # add/overwrite flags in the proper order
 467     dpdk_flags = flags_common + implementer_config['flags'] + part_number_config.get('flags', []) + soc_flags
 468
 469     # apply supported machine args
 470     machine_args = [] # Clear previous machine args
 471     foreach flag: part_number_config['machine_args']
 472         if cc.has_argument(flag)
 473             machine_args += flag
 474         endif
 475     endforeach
 476
 477     # apply flags
 478     foreach flag: dpdk_flags
 479         if flag.length() > 0
 480             dpdk_conf.set(flag[0], flag[1])
 481         endif
 482     endforeach
 483 endif
 484 message('Using machine args: @0@'.format(machine_args))
 485
 486 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 487     cc.get_define('__aarch64__', args: machine_args) != '')
 488     compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 489 endif
 490
 491 if cc.get_define('__ARM_FEATURE_SVE', args: machine_args) != ''
 492     compile_time_cpuflags += ['RTE_CPUFLAG_SVE']
 493 endif
 494
 495 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 496     compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 497 endif
 498
 499 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 500     compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 501     'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 502 endif