config/arm/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation.
   3 # Copyright(c) 2017 Cavium, Inc
   4
   5 # common flags to all aarch64 builds, with lowest priority
   6 flags_common = [
   7         # Accelerate rte_memcpy. Be sure to run unit test (memcpy_perf_autotest)
   8         # to determine the best threshold in code. Refer to notes in source file
   9         # (lib/librte_eal/arm/include/rte_memcpy_64.h) for more info.
  10         ['RTE_ARCH_ARM64_MEMCPY', false],
  11         #       ['RTE_ARM64_MEMCPY_ALIGNED_THRESHOLD', 2048],
  12         #       ['RTE_ARM64_MEMCPY_UNALIGNED_THRESHOLD', 512],
  13         # Leave below RTE_ARM64_MEMCPY_xxx options commented out,
  14         # unless there are strong reasons.
  15         #       ['RTE_ARM64_MEMCPY_SKIP_GCC_VER_CHECK', false],
  16         #       ['RTE_ARM64_MEMCPY_ALIGN_MASK', 0xF],
  17         #       ['RTE_ARM64_MEMCPY_STRICT_ALIGN', false],
  18
  19         ['RTE_NET_FM10K', false],
  20         ['RTE_NET_AVP', false],
  21
  22         ['RTE_SCHED_VECTOR', false],
  23         ['RTE_ARM_USE_WFE', false],
  24         ['RTE_ARCH_ARM64', true],
  25         ['RTE_CACHE_LINE_SIZE', 128]
  26 ]
  27 native_machine_args = ['-mcpu=native']
  28
  29 ## Part numbers are specific to Arm implementers
  30 # implementer specific aarch64 flags have middle priority
  31 #     (will overwrite common flags)
  32 # part number specific aarch64 flags have the highest priority
  33 #     (will overwrite both common and implementer specific flags)
  34 implementer_generic = {
  35         'description': 'Generic armv8',
  36         'flags': [
  37                 ['RTE_MACHINE', '"armv8a"'],
  38                 ['RTE_USE_C11_MEM_MODEL', true],
  39                 ['RTE_MAX_LCORE', 256],
  40                 ['RTE_MAX_NUMA_NODES', 4]
  41         ],
  42         'part_number_config': {
  43                 'generic': {'machine_args': ['-march=armv8-a+crc',
  44                                              '-moutline-atomics']}
  45         }
  46 }
  47
  48 part_number_config_arm = {
  49         '0xd03': {'machine_args':  ['-mcpu=cortex-a53']},
  50         '0xd04': {'machine_args':  ['-mcpu=cortex-a35']},
  51         '0xd07': {'machine_args':  ['-mcpu=cortex-a57']},
  52         '0xd08': {'machine_args':  ['-mcpu=cortex-a72']},
  53         '0xd09': {'machine_args':  ['-mcpu=cortex-a73']},
  54         '0xd0a': {'machine_args':  ['-mcpu=cortex-a75']},
  55         '0xd0b': {'machine_args':  ['-mcpu=cortex-a76']},
  56         '0xd0c': {
  57                 'machine_args':  ['-march=armv8.2-a+crypto',
  58                                   '-mcpu=neoverse-n1'],
  59                 'flags': [
  60                         ['RTE_MACHINE', '"neoverse-n1"'],
  61                         ['RTE_ARM_FEATURE_ATOMICS', true],
  62                         ['RTE_MAX_MEM_MB', 1048576],
  63                         ['RTE_MAX_LCORE', 80]
  64                 ]
  65         },
  66         '0xd49': {
  67                 'machine_args':  ['-march=armv8.5-a+crypto+sve2'],
  68                 'flags': [
  69                         ['RTE_MACHINE', '"neoverse-n2"'],
  70                         ['RTE_ARM_FEATURE_ATOMICS', true],
  71                         ['RTE_MAX_LCORE', 64]
  72                 ]
  73         }
  74 }
  75 implementer_arm = {
  76         'description': 'Arm',
  77         'flags': [
  78                 ['RTE_MACHINE', '"armv8a"'],
  79                 ['RTE_USE_C11_MEM_MODEL', true],
  80                 ['RTE_CACHE_LINE_SIZE', 64],
  81                 ['RTE_MAX_LCORE', 16],
  82                 ['RTE_MAX_NUMA_NODES', 1]
  83         ],
  84         'part_number_config': part_number_config_arm
  85 }
  86
  87 flags_part_number_thunderx = [
  88         ['RTE_MACHINE', '"thunderx"'],
  89         ['RTE_USE_C11_MEM_MODEL', false]
  90 ]
  91 implementer_cavium = {
  92         'description': 'Cavium',
  93         'flags': [
  94                 ['RTE_MAX_VFIO_GROUPS', 128],
  95                 ['RTE_MAX_LCORE', 96],
  96                 ['RTE_MAX_NUMA_NODES', 2]
  97         ],
  98         'part_number_config': {
  99                 '0xa1': {
 100                         'machine_args': ['-mcpu=thunderxt88'],
 101                         'flags': flags_part_number_thunderx
 102                 },
 103                 '0xa2': {
 104                         'machine_args': ['-mcpu=thunderxt81'],
 105                         'flags': flags_part_number_thunderx
 106                 },
 107                 '0xa3': {
 108                         'machine_args': ['-mcpu=thunderxt83'],
 109                         'flags': flags_part_number_thunderx
 110                 },
 111                 '0xaf': {
 112                         'machine_args': ['-march=armv8.1-a+crc+crypto',
 113                                          '-mcpu=thunderx2t99'],
 114                         'flags': [
 115                                 ['RTE_MACHINE', '"thunderx2"'],
 116                                 ['RTE_ARM_FEATURE_ATOMICS', true],
 117                                 ['RTE_USE_C11_MEM_MODEL', true],
 118                                 ['RTE_CACHE_LINE_SIZE', 64],
 119                                 ['RTE_MAX_LCORE', 256]
 120                         ]
 121                 },
 122                 '0xb2': {
 123                         'machine_args': ['-march=armv8.2-a+crc+crypto+lse',
 124                                          '-mcpu=octeontx2'],
 125                         'flags': [
 126                                 ['RTE_MACHINE', '"octeontx2"'],
 127                                 ['RTE_ARM_FEATURE_ATOMICS', true],
 128                                 ['RTE_USE_C11_MEM_MODEL', true],
 129                                 ['RTE_EAL_IGB_UIO', false],
 130                                 ['RTE_MAX_LCORE', 36],
 131                                 ['RTE_MAX_NUMA_NODES', 1]
 132                         ]
 133                 }
 134         }
 135 }
 136
 137 implementer_ampere = {
 138         'description': 'Ampere Computing',
 139         'flags': [
 140                 ['RTE_MACHINE', '"emag"'],
 141                 ['RTE_CACHE_LINE_SIZE', 64],
 142                 ['RTE_MAX_LCORE', 32],
 143                 ['RTE_MAX_NUMA_NODES', 1]
 144         ],
 145         'part_number_config': {
 146                 '0x0': {'machine_args':  ['-march=armv8-a+crc+crypto',
 147                                           '-mtune=emag']}
 148         }
 149 }
 150
 151 implementer_marvell = {
 152         'description': 'Marvell ARMADA',
 153         'flags': [
 154                 ['RTE_MACHINE', '"armv8a"'],
 155                 ['RTE_CACHE_LINE_SIZE', 64],
 156                 ['RTE_MAX_LCORE', 16],
 157                 ['RTE_MAX_NUMA_NODES', 1]
 158         ],
 159         'part_number_config': part_number_config_arm
 160 }
 161
 162 implementer_dpaa = {
 163         'description': 'NXP DPAA',
 164         'flags': [
 165                 ['RTE_MACHINE', '"dpaa"'],
 166                 ['RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', false],
 167                 ['RTE_USE_C11_MEM_MODEL', true],
 168                 ['RTE_CACHE_LINE_SIZE', 64],
 169                 ['RTE_MAX_LCORE', 16],
 170                 ['RTE_MAX_NUMA_NODES', 1]
 171         ],
 172         'part_number_config': part_number_config_arm
 173 }
 174
 175 ## Arm implementers (ID from MIDR in Arm Architecture Reference Manual)
 176 implementers = {
 177         'generic': implementer_generic,
 178         '0x41': implementer_arm,
 179         '0x43': implementer_cavium,
 180         '0x50': implementer_ampere,
 181         '0x56': implementer_marvell,
 182         'dpaa': implementer_dpaa
 183 }
 184
 185 dpdk_conf.set('RTE_ARCH_ARM', 1)
 186 dpdk_conf.set('RTE_FORCE_INTRINSICS', 1)
 187
 188 if dpdk_conf.get('RTE_ARCH_32')
 189         # armv7 build
 190         dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
 191         dpdk_conf.set('RTE_ARCH_ARMv7', 1)
 192         # the minimum architecture supported, armv7-a, needs the following,
 193         machine_args += '-mfpu=neon'
 194 else
 195         # aarch64 build
 196         use_native_machine_args = false
 197         if not meson.is_cross_build()
 198                 if machine == 'default'
 199                         # default build
 200                         implementer_id = 'generic'
 201                         part_number = 'generic'
 202                 else
 203                         # native build
 204                         # The script returns ['Implementer', 'Variant', 'Architecture',
 205                         # 'Primary Part number', 'Revision']
 206                         detect_vendor = find_program(join_paths(
 207                                         meson.current_source_dir(), 'armv8_machine.py'))
 208                         cmd = run_command(detect_vendor.path())
 209                         if cmd.returncode() == 0
 210                                 cmd_output = cmd.stdout().to_lower().strip().split(' ')
 211                                 implementer_id = cmd_output[0]
 212                                 part_number = cmd_output[3]
 213                         else
 214                                 error('Error when getting Arm Implementer ID and part number.')
 215                         endif
 216                         use_native_machine_args = true
 217                 endif
 218         else
 219                 # cross build
 220                 implementer_id = meson.get_cross_property('implementer_id')
 221                 part_number = meson.get_cross_property('part_number')
 222         endif
 223
 224         if implementers.has_key(implementer_id)
 225                 implementer_config = implementers[implementer_id]
 226         else
 227                 error('Unsupported Arm implementer: @0@. '.format(implementer_id) +
 228                       'Please add support for it or use the generic ' +
 229                       '(-Dmachine=generic) build.')
 230         endif
 231
 232         message('Arm implementer: ' + implementer_config['description'])
 233         message('Arm part number: ' + part_number)
 234
 235         part_number_config = implementer_config['part_number_config']
 236         if part_number_config.has_key(part_number)
 237                 # use the specified part_number machine args if found
 238                 part_number_config = part_number_config[part_number]
 239         else
 240                 # unknown part number
 241                 error('Unsupported part number @0@ of implementer @1@. '
 242                       .format(part_number, implementer_id) +
 243                       'Please add support for it or use the generic ' +
 244                       '(-Dmachine=generic) build.')
 245         endif
 246
 247         # use default flags with implementer flags
 248         dpdk_flags = flags_common + implementer_config['flags'] + part_number_config.get('flags', [])
 249
 250         # apply supported machine args
 251         machine_args = [] # Clear previous machine args
 252         if use_native_machine_args
 253                 candidate_machine_args = native_machine_args
 254         else
 255                 candidate_machine_args = part_number_config['machine_args']
 256         endif
 257         foreach flag: candidate_machine_args
 258                 if cc.has_argument(flag)
 259                         machine_args += flag
 260                 endif
 261         endforeach
 262
 263         # apply flags
 264         foreach flag: dpdk_flags
 265                 if flag.length() > 0
 266                         dpdk_conf.set(flag[0], flag[1])
 267                 endif
 268         endforeach
 269 endif
 270 message('Using machine args: @0@'.format(machine_args))
 271
 272 if (cc.get_define('__ARM_NEON', args: machine_args) != '' or
 273     cc.get_define('__aarch64__', args: machine_args) != '')
 274         compile_time_cpuflags += ['RTE_CPUFLAG_NEON']
 275 endif
 276
 277 if cc.get_define('__ARM_FEATURE_CRC32', args: machine_args) != ''
 278         compile_time_cpuflags += ['RTE_CPUFLAG_CRC32']
 279 endif
 280
 281 if cc.get_define('__ARM_FEATURE_CRYPTO', args: machine_args) != ''
 282         compile_time_cpuflags += ['RTE_CPUFLAG_AES', 'RTE_CPUFLAG_PMULL',
 283         'RTE_CPUFLAG_SHA1', 'RTE_CPUFLAG_SHA2']
 284 endif