config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # set the major version, which might be used by drivers and libraries
  18 # depending on the configuration options
  19 pver = meson.project_version().split('.')
  20 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  21
  22 # extract all version information into the build configuration
  23 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  24 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  25 if pver.get(2).contains('-rc')
  26         rc_ver = pver.get(2).split('-rc')
  27         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  28         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  29         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  30 else
  31         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  32         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  33 # for actual, non-rc releases, set the release value to 99 to ensure releases
  34 # have higher version numbers than their respective release candidates
  35         dpdk_conf.set('RTE_VER_RELEASE', 99)
  36 endif
  37
  38 pmd_subdir_opt = get_option('drivers_install_subdir')
  39 if pmd_subdir_opt.contains('<VERSION>')
  40         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  41 endif
  42 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  43 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  44
  45 # driver .so files often depend upon the bus drivers for their connect bus,
  46 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  47 # to be in the library path, so symlink the drivers from the main lib directory.
  48 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  49                 get_option('libdir'),
  50                 pmd_subdir_opt)
  51
  52 # set the machine type and cflags for it
  53 if meson.is_cross_build()
  54         machine = host_machine.cpu()
  55 else
  56         machine = get_option('machine')
  57 endif
  58
  59 # machine type 'default' is special, it defaults to the per arch agreed common
  60 # minimal baseline needed for DPDK.
  61 # That might not be the most optimized, but the most portable version while
  62 # still being able to support the CPU features required for DPDK.
  63 # This can be bumped up by the DPDK project, but it can never be an
  64 # invariant like 'native'
  65 if machine == 'default'
  66         if host_machine.cpu_family().startswith('x86')
  67                 # matches the old pre-meson build systems default
  68                 machine = 'corei7'
  69         elif host_machine.cpu_family().startswith('arm')
  70                 machine = 'armv7-a'
  71         elif host_machine.cpu_family().startswith('aarch')
  72                 # arm64 manages defaults in config/arm/meson.build
  73                 machine = 'default'
  74         elif host_machine.cpu_family().startswith('ppc')
  75                 machine = 'power8'
  76         endif
  77 endif
  78
  79 dpdk_conf.set('RTE_MACHINE', machine)
  80 machine_args = []
  81
  82 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  83 if host_machine.cpu_family().startswith('ppc')
  84         machine_args += '-mcpu=' + machine
  85         machine_args += '-mtune=' + machine
  86 else
  87         machine_args += '-march=' + machine
  88 endif
  89
  90 toolchain = cc.get_id()
  91 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  92 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  93
  94 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
  95
  96 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  97
  98 # use pthreads
  99 add_project_link_arguments('-pthread', language: 'c')
 100 dpdk_extra_ldflags += '-pthread'
 101
 102 # on some OS, maths functions are in a separate library
 103 if cc.find_library('libm', required : false).found()
 104         # some libs depend on maths lib
 105         add_project_link_arguments('-lm', language: 'c')
 106         dpdk_extra_ldflags += '-lm'
 107 endif
 108
 109 # for linux link against dl, for bsd execinfo
 110 if is_linux
 111         link_lib = 'dl'
 112 elif is_freebsd
 113         link_lib = 'execinfo'
 114 else
 115         link_lib = ''
 116 endif
 117
 118 # if link_lib is empty, do not add it to project properties
 119 if link_lib != ''
 120         add_project_link_arguments('-l' + link_lib, language: 'c')
 121         dpdk_extra_ldflags += '-l' + link_lib
 122 endif
 123
 124 # check for libraries used in multiple places in DPDK
 125 has_libnuma = 0
 126 numa_dep = cc.find_library('numa', required: false)
 127 if numa_dep.found() and cc.has_header('numaif.h')
 128         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 129         has_libnuma = 1
 130         add_project_link_arguments('-lnuma', language: 'c')
 131         dpdk_extra_ldflags += '-lnuma'
 132 endif
 133
 134 # check for libbsd
 135 libbsd = dependency('libbsd', required: false)
 136 if libbsd.found()
 137         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 138 endif
 139
 140 # check for pcap
 141 pcap_dep = dependency('pcap', required: false)
 142 if pcap_dep.found()
 143         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 144         # an internal pcap-config finder, which is not compatible with
 145         # cross-compilation, so try to fallback to find_library
 146         pcap_dep = cc.find_library('pcap', required: false)
 147 endif
 148 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 149         dpdk_conf.set('RTE_PORT_PCAP', 1)
 150         dpdk_extra_ldflags += '-lpcap'
 151 endif
 152
 153 # add -include rte_config to cflags
 154 add_project_arguments('-include', 'rte_config.h', language: 'c')
 155
 156 # enable extra warnings and disable any unwanted warnings
 157 warning_flags = [
 158         # -Wall is added by meson by default, so add -Wextra only
 159         '-Wextra',
 160
 161         # additional warnings in alphabetical order
 162         '-Wcast-qual',
 163         '-Wdeprecated',
 164         '-Wformat-nonliteral',
 165         '-Wformat-security',
 166         '-Wmissing-declarations',
 167         '-Wmissing-prototypes',
 168         '-Wnested-externs',
 169         '-Wold-style-definition',
 170         '-Wpointer-arith',
 171         '-Wsign-compare',
 172         '-Wstrict-prototypes',
 173         '-Wundef',
 174         '-Wwrite-strings',
 175
 176         # globally disabled warnings
 177         '-Wno-address-of-packed-member',
 178         '-Wno-packed-not-aligned',
 179         '-Wno-missing-field-initializers'
 180 ]
 181 if not dpdk_conf.get('RTE_ARCH_64')
 182 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 183         warning_flags += '-Wno-pointer-to-int-cast'
 184 endif
 185 foreach arg: warning_flags
 186         if cc.has_argument(arg)
 187                 add_project_arguments(arg, language: 'c')
 188         endif
 189 endforeach
 190
 191 # set other values pulled from the build options
 192 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 193 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 194 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 195 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 196 # values which have defaults which may be overridden
 197 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 198 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 199 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 200
 201
 202 compile_time_cpuflags = []
 203 if host_machine.cpu_family().startswith('x86')
 204         arch_subdir = 'x86'
 205 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 206         arch_subdir = 'arm'
 207 elif host_machine.cpu_family().startswith('ppc')
 208         arch_subdir = 'ppc_64'
 209 endif
 210 subdir(arch_subdir)
 211 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 212
 213 # set the install path for the drivers
 214 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 215
 216 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 217
 218 # enable VFIO only if it is linux OS
 219 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 220
 221 # specify -D_GNU_SOURCE unconditionally
 222 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 223
 224 # specify -D__BSD_VISIBLE for FreeBSD
 225 if is_freebsd
 226         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 227 endif
 228
 229 if get_option('b_lto')
 230         if cc.has_argument('-ffat-lto-objects')
 231                 add_project_arguments('-ffat-lto-objects', language: 'c')
 232         else
 233                 error('compiler does not support fat LTO objects - please turn LTO off')
 234         endif
 235         # workaround for gcc bug 81440
 236         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 237                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 238                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 239         endif
 240 endif