config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'),
  26         abi_version_file).stdout().strip()
  27
  28 # Libraries have the abi_version as the filename extension
  29 # and have the soname be all but the final part of the abi_version.
  30 # e.g. v20.1 => librte_foo.so.20.1
  31 #    sonames => librte_foo.so.20
  32 so_version = abi_version.split('.')[0]
  33
  34 # extract all version information into the build configuration
  35 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  36 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  37 if pver.get(2).contains('-rc')
  38         rc_ver = pver.get(2).split('-rc')
  39         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  40         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  41         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  42 else
  43         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  44         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  45 # for actual, non-rc releases, set the release value to 99 to ensure releases
  46 # have higher version numbers than their respective release candidates
  47         dpdk_conf.set('RTE_VER_RELEASE', 99)
  48 endif
  49
  50 pmd_subdir_opt = get_option('drivers_install_subdir')
  51 if pmd_subdir_opt.contains('<VERSION>')
  52         pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  53 endif
  54 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  55 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  56
  57 # driver .so files often depend upon the bus drivers for their connect bus,
  58 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  59 # to be in the library path, so symlink the drivers from the main lib directory.
  60 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  61                 get_option('libdir'),
  62                 pmd_subdir_opt)
  63
  64 # set the machine type and cflags for it
  65 if meson.is_cross_build()
  66         machine = host_machine.cpu()
  67 else
  68         machine = get_option('machine')
  69 endif
  70
  71 # machine type 'default' is special, it defaults to the per arch agreed common
  72 # minimal baseline needed for DPDK.
  73 # That might not be the most optimized, but the most portable version while
  74 # still being able to support the CPU features required for DPDK.
  75 # This can be bumped up by the DPDK project, but it can never be an
  76 # invariant like 'native'
  77 if machine == 'default'
  78         if host_machine.cpu_family().startswith('x86')
  79                 # matches the old pre-meson build systems default
  80                 machine = 'corei7'
  81         elif host_machine.cpu_family().startswith('arm')
  82                 machine = 'armv7-a'
  83         elif host_machine.cpu_family().startswith('aarch')
  84                 # arm64 manages defaults in config/arm/meson.build
  85                 machine = 'default'
  86         elif host_machine.cpu_family().startswith('ppc')
  87                 machine = 'power8'
  88         endif
  89 endif
  90
  91 dpdk_conf.set('RTE_MACHINE', machine)
  92 machine_args = []
  93
  94 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  95 if host_machine.cpu_family().startswith('ppc')
  96         machine_args += '-mcpu=' + machine
  97         machine_args += '-mtune=' + machine
  98 else
  99         machine_args += '-march=' + machine
 100 endif
 101
 102 toolchain = cc.get_id()
 103 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 104 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 105
 106 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 107
 108 if not is_windows
 109         add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 110 endif
 111
 112 # use pthreads if available for the platform
 113 if not is_windows
 114         add_project_link_arguments('-pthread', language: 'c')
 115         dpdk_extra_ldflags += '-pthread'
 116 endif
 117
 118 # on some OS, maths functions are in a separate library
 119 if cc.find_library('m', required : false).found()
 120         # some libs depend on maths lib
 121         add_project_link_arguments('-lm', language: 'c')
 122         dpdk_extra_ldflags += '-lm'
 123 endif
 124
 125 # for linux link against dl, for bsd execinfo
 126 if is_linux
 127         link_lib = 'dl'
 128 elif is_freebsd
 129         link_lib = 'execinfo'
 130 else
 131         link_lib = ''
 132 endif
 133
 134 # if link_lib is empty, do not add it to project properties
 135 if link_lib != ''
 136         add_project_link_arguments('-l' + link_lib, language: 'c')
 137         dpdk_extra_ldflags += '-l' + link_lib
 138 endif
 139
 140 # check for libraries used in multiple places in DPDK
 141 has_libnuma = 0
 142 numa_dep = cc.find_library('numa', required: false)
 143 if numa_dep.found() and cc.has_header('numaif.h')
 144         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 145         has_libnuma = 1
 146         add_project_link_arguments('-lnuma', language: 'c')
 147         dpdk_extra_ldflags += '-lnuma'
 148 endif
 149
 150 has_libfdt = 0
 151 fdt_dep = cc.find_library('libfdt', required: false)
 152 if fdt_dep.found() and cc.has_header('fdt.h')
 153         dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 154         has_libfdt = 1
 155         add_project_link_arguments('-lfdt', language: 'c')
 156         dpdk_extra_ldflags += '-lfdt'
 157 endif
 158
 159 # check for libbsd
 160 libbsd = dependency('libbsd', required: false)
 161 if libbsd.found()
 162         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 163 endif
 164
 165 # check for pcap
 166 pcap_dep = dependency('pcap', required: false)
 167 if pcap_dep.found()
 168         # pcap got a pkg-config file only in 1.9.0 and before that meson uses
 169         # an internal pcap-config finder, which is not compatible with
 170         # cross-compilation, so try to fallback to find_library
 171         pcap_dep = cc.find_library('pcap', required: false)
 172 endif
 173 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 174         dpdk_conf.set('RTE_PORT_PCAP', 1)
 175         dpdk_extra_ldflags += '-lpcap'
 176 endif
 177
 178 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 179 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 180         atomic_dep = cc.find_library('atomic', required: true)
 181         add_project_link_arguments('-latomic', language: 'c')
 182         dpdk_extra_ldflags += '-latomic'
 183 endif
 184
 185 # add -include rte_config to cflags
 186 add_project_arguments('-include', 'rte_config.h', language: 'c')
 187
 188 # enable extra warnings and disable any unwanted warnings
 189 warning_flags = [
 190         # -Wall is added by meson by default, so add -Wextra only
 191         '-Wextra',
 192
 193         # additional warnings in alphabetical order
 194         '-Wcast-qual',
 195         '-Wdeprecated',
 196         '-Wformat-nonliteral',
 197         '-Wformat-security',
 198         '-Wmissing-declarations',
 199         '-Wmissing-prototypes',
 200         '-Wnested-externs',
 201         '-Wold-style-definition',
 202         '-Wpointer-arith',
 203         '-Wsign-compare',
 204         '-Wstrict-prototypes',
 205         '-Wundef',
 206         '-Wwrite-strings',
 207
 208         # globally disabled warnings
 209         '-Wno-address-of-packed-member',
 210         '-Wno-packed-not-aligned',
 211         '-Wno-missing-field-initializers'
 212 ]
 213 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 214 # FIXME: Bugzilla 396
 215         warning_flags += '-Wno-zero-length-bounds'
 216 endif
 217 if not dpdk_conf.get('RTE_ARCH_64')
 218 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 219         warning_flags += '-Wno-pointer-to-int-cast'
 220 endif
 221 if cc.get_id() == 'intel'
 222         warning_ids = [188, 2203, 2279, 2557, 3179, 3656]
 223         foreach i:warning_ids
 224                 warning_flags += '-diag-disable=@0@'.format(i)
 225         endforeach
 226 endif
 227 foreach arg: warning_flags
 228         if cc.has_argument(arg)
 229                 add_project_arguments(arg, language: 'c')
 230         endif
 231 endforeach
 232
 233 # set other values pulled from the build options
 234 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 235 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 236 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 237 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 238 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 239 # values which have defaults which may be overridden
 240 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 241 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 242 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 243 if dpdk_conf.get('RTE_ARCH_64')
 244         dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 245 else # for 32-bit we need smaller reserved memory areas
 246         dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 247 endif
 248
 249
 250 compile_time_cpuflags = []
 251 subdir(arch_subdir)
 252 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 253
 254 # set the install path for the drivers
 255 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 256
 257 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 258
 259 # enable VFIO only if it is linux OS
 260 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 261
 262 # specify -D_GNU_SOURCE unconditionally
 263 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 264
 265 # specify -D__BSD_VISIBLE for FreeBSD
 266 if is_freebsd
 267         add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 268 endif
 269
 270 if is_windows
 271         # VirtualAlloc2() is available since Windows 10 / Server 2016.
 272         add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 273
 274         # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 275         if cc.get_id() == 'gcc'
 276                 add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 277         endif
 278
 279         # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 280         # in Windows SDK, while MinGW exports it by advapi32.a.
 281         if is_ms_linker
 282                 add_project_link_arguments('-lmincore', language: 'c')
 283         endif
 284
 285         add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 286         add_project_link_arguments('-ldbghelp', language: 'c')
 287 endif
 288
 289 if get_option('b_lto')
 290         if cc.has_argument('-ffat-lto-objects')
 291                 add_project_arguments('-ffat-lto-objects', language: 'c')
 292         else
 293                 error('compiler does not support fat LTO objects - please turn LTO off')
 294         endif
 295         # workaround for gcc bug 81440
 296         if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 297                 add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 298                 add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 299         endif
 300 endif