config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8         error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14         set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # set the major version, which might be used by drivers and libraries
  18 # depending on the configuration options
  19 pver = meson.project_version().split('.')
  20 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  21
  22 # extract all version information into the build configuration
  23 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  24 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  25 if pver.get(2).contains('-rc')
  26         rc_ver = pver.get(2).split('-rc')
  27         dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  28         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  29         dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  30 else
  31         dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  32         dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  33 # for actual, non-rc releases, set the release value to 99 to ensure releases
  34 # have higher version numbers than their respective release candidates
  35         dpdk_conf.set('RTE_VER_RELEASE', 99)
  36 endif
  37
  38 pmd_subdir_opt = get_option('drivers_install_subdir')
  39 if pmd_subdir_opt.contains('<VERSION>')
  40         pmd_subdir_opt = major_version.join(pmd_subdir_opt.split('<VERSION>'))
  41 endif
  42 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  43 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  44
  45 # driver .so files often depend upon the bus drivers for their connect bus,
  46 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  47 # to be in the library path, so symlink the drivers from the main lib directory.
  48 meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  49                 get_option('libdir'),
  50                 pmd_subdir_opt)
  51
  52 # set the machine type and cflags for it
  53 if meson.is_cross_build()
  54         machine = host_machine.cpu()
  55 else
  56         machine = get_option('machine')
  57 endif
  58
  59 # machine type 'default' is special, it defaults to the per arch agreed common
  60 # minimal baseline needed for DPDK.
  61 # That might not be the most optimized, but the most portable version while
  62 # still being able to support the CPU features required for DPDK.
  63 # This can be bumped up by the DPDK project, but it can never be an
  64 # invariant like 'native'
  65 if machine == 'default'
  66         if host_machine.cpu_family().startswith('x86')
  67                 # matches the old pre-meson build systems default
  68                 machine = 'corei7'
  69         elif host_machine.cpu_family().startswith('arm')
  70                 machine = 'armv7-a'
  71         elif host_machine.cpu_family().startswith('aarch')
  72                 # arm64 manages defaults in config/arm/meson.build
  73                 machine = 'default'
  74         elif host_machine.cpu_family().startswith('ppc')
  75                 machine = 'power8'
  76         endif
  77 endif
  78
  79 dpdk_conf.set('RTE_MACHINE', machine)
  80 machine_args = []
  81
  82 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
  83 if host_machine.cpu_family().startswith('ppc')
  84         machine_args += '-mcpu=' + machine
  85         machine_args += '-mtune=' + machine
  86 else
  87         machine_args += '-march=' + machine
  88 endif
  89
  90 toolchain = cc.get_id()
  91 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
  92 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
  93
  94 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
  95
  96 add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
  97 dpdk_extra_ldflags += '-Wl,--no-as-needed'
  98
  99 # use pthreads
 100 add_project_link_arguments('-pthread', language: 'c')
 101 dpdk_extra_ldflags += '-pthread'
 102
 103 # on some OS, maths functions are in a separate library
 104 if cc.find_library('libm', required : false).found()
 105         # some libs depend on maths lib
 106         add_project_link_arguments('-lm', language: 'c')
 107         dpdk_extra_ldflags += '-lm'
 108 endif
 109
 110 # for linux link against dl, for bsd execinfo
 111 if is_linux
 112         link_lib = 'dl'
 113 elif is_freebsd
 114         link_lib = 'execinfo'
 115 else
 116         link_lib = ''
 117 endif
 118
 119 # if link_lib is empty, do not add it to project properties
 120 if link_lib != ''
 121         add_project_link_arguments('-l' + link_lib, language: 'c')
 122         dpdk_extra_ldflags += '-l' + link_lib
 123 endif
 124
 125 # check for libraries used in multiple places in DPDK
 126 has_libnuma = 0
 127 numa_dep = cc.find_library('numa', required: false)
 128 if numa_dep.found() and cc.has_header('numaif.h')
 129         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 130         has_libnuma = 1
 131         add_project_link_arguments('-lnuma', language: 'c')
 132         dpdk_extra_ldflags += '-lnuma'
 133 endif
 134
 135 # check for libbsd
 136 libbsd = dependency('libbsd', required: false)
 137 if libbsd.found()
 138         dpdk_conf.set('RTE_USE_LIBBSD', 1)
 139 endif
 140
 141 # add -include rte_config to cflags
 142 add_project_arguments('-include', 'rte_config.h', language: 'c')
 143
 144 # enable extra warnings and disable any unwanted warnings
 145 warning_flags = [
 146         '-Wunused-parameter',
 147         '-Wsign-compare',
 148         '-Wcast-qual',
 149         '-Wno-address-of-packed-member'
 150 ]
 151 if not dpdk_conf.get('RTE_ARCH_64')
 152 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 153         warning_flags += '-Wno-pointer-to-int-cast'
 154 endif
 155 foreach arg: warning_flags
 156         if cc.has_argument(arg)
 157                 add_project_arguments(arg, language: 'c')
 158         endif
 159 endforeach
 160
 161 # set other values pulled from the build options
 162 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 163 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 164 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 165 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 166 dpdk_conf.set('RTE_EAL_ALLOW_INV_SOCKET_ID', get_option('allow_invalid_socket_id'))
 167 # values which have defaults which may be overridden
 168 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 169 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 170 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 171
 172
 173 compile_time_cpuflags = []
 174 if host_machine.cpu_family().startswith('x86')
 175         arch_subdir = 'x86'
 176 elif host_machine.cpu_family().startswith('arm') or host_machine.cpu_family().startswith('aarch')
 177         arch_subdir = 'arm'
 178 elif host_machine.cpu_family().startswith('ppc')
 179         arch_subdir = 'ppc_64'
 180 endif
 181 subdir(arch_subdir)
 182 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 183
 184 # set the install path for the drivers
 185 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 186
 187 install_headers('rte_config.h', subdir: get_option('include_subdir_arch'))
 188
 189 # enable VFIO only if it is linux OS
 190 dpdk_conf.set('RTE_EAL_VFIO', is_linux)