config/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 # check the OS is supported, rather than going any further
   5 supported_exec_envs = ['freebsd', 'linux', 'windows']
   6 exec_env = host_machine.system()
   7 if not supported_exec_envs.contains(exec_env)
   8     error('unsupported system type "@0@"'.format(exec_env))
   9 endif
  10
  11 # define a handy variable for checking which OS we have.
  12 # gives us "is_windows", "is_freebsd" and "is_linux"
  13 foreach env:supported_exec_envs
  14     set_variable('is_' + env, exec_env == env)
  15 endforeach
  16
  17 # MS linker requires special treatment.
  18 # TODO: use cc.get_linker_id() with Meson >= 0.54
  19 is_ms_linker = is_windows and (cc.get_id() == 'clang')
  20
  21 # set the major version, which might be used by drivers and libraries
  22 # depending on the configuration options
  23 pver = meson.project_version().split('.')
  24 major_version = '@0@.@1@'.format(pver.get(0), pver.get(1))
  25 abi_version = run_command(find_program('cat', 'more'), abi_version_file).stdout().strip()
  26
  27 # Libraries have the abi_version as the filename extension
  28 # and have the soname be all but the final part of the abi_version.
  29 # e.g. v20.1 => librte_foo.so.20.1
  30 #    sonames => librte_foo.so.20
  31 so_version = abi_version.split('.')[0]
  32
  33 # extract all version information into the build configuration
  34 dpdk_conf.set('RTE_VER_YEAR', pver.get(0).to_int())
  35 dpdk_conf.set('RTE_VER_MONTH', pver.get(1).to_int())
  36 if pver.get(2).contains('-rc')
  37     rc_ver = pver.get(2).split('-rc')
  38     dpdk_conf.set('RTE_VER_MINOR', rc_ver.get(0).to_int())
  39     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '-rc')
  40     dpdk_conf.set('RTE_VER_RELEASE', rc_ver.get(1).to_int())
  41 else
  42     dpdk_conf.set('RTE_VER_MINOR', pver.get(2).to_int())
  43     dpdk_conf.set_quoted('RTE_VER_SUFFIX', '')
  44 # for actual, non-rc releases, set the release value to 99 to ensure releases
  45 # have higher version numbers than their respective release candidates
  46     dpdk_conf.set('RTE_VER_RELEASE', 99)
  47 endif
  48
  49 pmd_subdir_opt = get_option('drivers_install_subdir')
  50 if pmd_subdir_opt.contains('<VERSION>')
  51     pmd_subdir_opt = abi_version.join(pmd_subdir_opt.split('<VERSION>'))
  52 endif
  53 driver_install_path = join_paths(get_option('libdir'), pmd_subdir_opt)
  54 eal_pmd_path = join_paths(get_option('prefix'), driver_install_path)
  55
  56 # driver .so files often depend upon the bus drivers for their connect bus,
  57 # e.g. ixgbe depends on librte_bus_pci. This means that the bus drivers need
  58 # to be in the library path, so symlink the drivers from the main lib directory.
  59 if not is_windows
  60     meson.add_install_script('../buildtools/symlink-drivers-solibs.sh',
  61             get_option('libdir'), pmd_subdir_opt)
  62 endif
  63
  64 # init disable/enable driver lists that will be populated in different places
  65 disable_drivers = ''
  66 enable_drivers = ''
  67
  68 platform = get_option('platform')
  69
  70 # set the cpu_instruction_set and cflags for it
  71 if meson.is_cross_build()
  72     cpu_instruction_set = host_machine.cpu()
  73 else
  74     cpu_instruction_set = get_option('cpu_instruction_set')
  75     machine = get_option('machine')
  76     if machine != 'auto'
  77         warning('The "machine" option is deprecated. ' +
  78                 'Please use "cpu_instruction_set" instead.')
  79         if cpu_instruction_set != 'auto'
  80             error('Setting both "machine" and ' +
  81                 '"cpu_instruction_set" is unsupported.')
  82         endif
  83         cpu_instruction_set = machine
  84         if cpu_instruction_set == 'default'
  85             cpu_instruction_set = 'generic'
  86         endif
  87     endif
  88 endif
  89
  90 if platform == 'native'
  91     if cpu_instruction_set == 'auto'
  92         cpu_instruction_set = 'native'
  93     endif
  94 elif platform == 'generic'
  95     if cpu_instruction_set == 'auto'
  96         cpu_instruction_set = 'generic'
  97     endif
  98 endif
  99
 100 # cpu_instruction_set 'generic' is special, it selects the per arch agreed
 101 # common minimal baseline needed for DPDK. cpu_instruction_set 'default' is
 102 # also supported with the same meaning for backwards compatibility.
 103 # That might not be the most optimized, but the most portable version while
 104 # still being able to support the CPU features required for DPDK.
 105 # This can be bumped up by the DPDK project, but it can never be an
 106 # invariant like 'native'
 107 if cpu_instruction_set == 'generic'
 108     if host_machine.cpu_family().startswith('x86')
 109         # matches the old pre-meson build systems generic cpu_instruction_set
 110         cpu_instruction_set = 'corei7'
 111     elif host_machine.cpu_family().startswith('arm')
 112         cpu_instruction_set = 'armv7-a'
 113     elif host_machine.cpu_family().startswith('aarch')
 114         # arm64 manages generic config in config/arm/meson.build
 115         cpu_instruction_set = 'generic'
 116     elif host_machine.cpu_family().startswith('ppc')
 117         cpu_instruction_set = 'power8'
 118     endif
 119 endif
 120
 121 dpdk_conf.set('RTE_MACHINE', cpu_instruction_set)
 122 machine_args = []
 123
 124 # ppc64 does not support -march= at all, use -mcpu and -mtune for that
 125 if host_machine.cpu_family().startswith('ppc')
 126     machine_args += '-mcpu=' + cpu_instruction_set
 127     machine_args += '-mtune=' + cpu_instruction_set
 128 else
 129     machine_args += '-march=' + cpu_instruction_set
 130 endif
 131
 132 toolchain = cc.get_id()
 133 dpdk_conf.set_quoted('RTE_TOOLCHAIN', toolchain)
 134 dpdk_conf.set('RTE_TOOLCHAIN_' + toolchain.to_upper(), 1)
 135
 136 dpdk_conf.set('RTE_ARCH_64', cc.sizeof('void *') == 8)
 137 dpdk_conf.set('RTE_ARCH_32', cc.sizeof('void *') == 4)
 138
 139 if not is_windows
 140     add_project_link_arguments('-Wl,--no-as-needed', language: 'c')
 141 endif
 142
 143 # use pthreads if available for the platform
 144 if not is_windows
 145     add_project_link_arguments('-pthread', language: 'c')
 146     dpdk_extra_ldflags += '-pthread'
 147 endif
 148
 149 # on some OS, maths functions are in a separate library
 150 if cc.find_library('m', required : false).found()
 151     # some libs depend on maths lib
 152     add_project_link_arguments('-lm', language: 'c')
 153     dpdk_extra_ldflags += '-lm'
 154 endif
 155
 156 if is_linux
 157     link_lib = 'dl'
 158 else
 159     link_lib = ''
 160 endif
 161
 162 # if link_lib is empty, do not add it to project properties
 163 if link_lib != ''
 164     add_project_link_arguments('-l' + link_lib, language: 'c')
 165     dpdk_extra_ldflags += '-l' + link_lib
 166 endif
 167
 168 # check for libraries used in multiple places in DPDK
 169 has_libnuma = 0
 170 find_libnuma = true
 171 if meson.is_cross_build() and not meson.get_cross_property('numa', true)
 172     # don't look for libnuma if explicitly disabled in cross build
 173     find_libnuma = false
 174 endif
 175 if find_libnuma
 176     numa_dep = cc.find_library('numa', required: false)
 177     if numa_dep.found() and cc.has_header('numaif.h')
 178         dpdk_conf.set10('RTE_HAS_LIBNUMA', true)
 179         has_libnuma = 1
 180         add_project_link_arguments('-lnuma', language: 'c')
 181         dpdk_extra_ldflags += '-lnuma'
 182     endif
 183 endif
 184
 185 has_libfdt = 0
 186 fdt_dep = cc.find_library('libfdt', required: false)
 187 if fdt_dep.found() and cc.has_header('fdt.h')
 188     dpdk_conf.set10('RTE_HAS_LIBFDT', true)
 189     has_libfdt = 1
 190     add_project_link_arguments('-lfdt', language: 'c')
 191     dpdk_extra_ldflags += '-lfdt'
 192 endif
 193
 194 libexecinfo = cc.find_library('libexecinfo', required: false)
 195 if libexecinfo.found() and cc.has_header('execinfo.h')
 196     add_project_link_arguments('-lexecinfo', language: 'c')
 197     dpdk_extra_ldflags += '-lexecinfo'
 198 endif
 199
 200 libarchive = dependency('libarchive', required: false, method: 'pkg-config')
 201 if libarchive.found()
 202     dpdk_conf.set('RTE_HAS_LIBARCHIVE', 1)
 203     # Push libarchive link dependency at the project level to support
 204     # statically linking dpdk apps. Details at:
 205     # https://inbox.dpdk.org/dev/20210605004024.660267a1@sovereign/
 206     add_project_link_arguments('-larchive', language: 'c')
 207     dpdk_extra_ldflags += '-larchive'
 208 endif
 209
 210 # check for libbsd
 211 libbsd = dependency('libbsd', required: false, method: 'pkg-config')
 212 if libbsd.found()
 213     dpdk_conf.set('RTE_USE_LIBBSD', 1)
 214 endif
 215
 216 # check for pcap
 217 pcap_dep = dependency('libpcap', required: false, method: 'pkg-config')
 218 pcap_lib = is_windows ? 'wpcap' : 'pcap'
 219 if not pcap_dep.found()
 220     # pcap got a pkg-config file only in 1.9.0
 221     pcap_dep = cc.find_library(pcap_lib, required: false)
 222 endif
 223 if pcap_dep.found() and cc.has_header('pcap.h', dependencies: pcap_dep)
 224     dpdk_conf.set('RTE_PORT_PCAP', 1)
 225     dpdk_extra_ldflags += '-l@0@'.format(pcap_lib)
 226 endif
 227
 228 # for clang 32-bit compiles we need libatomic for 64-bit atomic ops
 229 if cc.get_id() == 'clang' and dpdk_conf.get('RTE_ARCH_64') == false
 230     atomic_dep = cc.find_library('atomic', required: true)
 231     add_project_link_arguments('-latomic', language: 'c')
 232     dpdk_extra_ldflags += '-latomic'
 233 endif
 234
 235 # add -include rte_config to cflags
 236 add_project_arguments('-include', 'rte_config.h', language: 'c')
 237
 238 # enable extra warnings and disable any unwanted warnings
 239 warning_flags = [
 240         # -Wall is added by meson by default, so add -Wextra only
 241         '-Wextra',
 242
 243         # additional warnings in alphabetical order
 244         '-Wcast-qual',
 245         '-Wdeprecated',
 246         '-Wformat',
 247         '-Wformat-nonliteral',
 248         '-Wformat-security',
 249         '-Wmissing-declarations',
 250         '-Wmissing-prototypes',
 251         '-Wnested-externs',
 252         '-Wold-style-definition',
 253         '-Wpointer-arith',
 254         '-Wsign-compare',
 255         '-Wstrict-prototypes',
 256         '-Wundef',
 257         '-Wwrite-strings',
 258
 259         # globally disabled warnings
 260         '-Wno-address-of-packed-member',
 261         '-Wno-packed-not-aligned',
 262         '-Wno-missing-field-initializers',
 263 ]
 264 if cc.get_id() == 'gcc' and cc.version().version_compare('>=10.0')
 265 # FIXME: Bugzilla 396
 266     warning_flags += '-Wno-zero-length-bounds'
 267 endif
 268 if not dpdk_conf.get('RTE_ARCH_64')
 269 # for 32-bit, don't warn about casting a 32-bit pointer to 64-bit int - it's fine!!
 270     warning_flags += '-Wno-pointer-to-int-cast'
 271 endif
 272 if cc.get_id() == 'intel'
 273     warning_ids = [181, 188, 2203, 2279, 2557, 3179, 3656]
 274     foreach i:warning_ids
 275         warning_flags += '-diag-disable=@0@'.format(i)
 276     endforeach
 277 endif
 278 foreach arg: warning_flags
 279     if cc.has_argument(arg)
 280         add_project_arguments(arg, language: 'c')
 281     endif
 282 endforeach
 283
 284 # set other values pulled from the build options
 285 dpdk_conf.set('RTE_MAX_LCORE', get_option('max_lcores'))
 286 dpdk_conf.set('RTE_MAX_NUMA_NODES', get_option('max_numa_nodes'))
 287 dpdk_conf.set('RTE_MAX_ETHPORTS', get_option('max_ethports'))
 288 dpdk_conf.set('RTE_LIBEAL_USE_HPET', get_option('use_hpet'))
 289 dpdk_conf.set('RTE_ENABLE_TRACE_FP', get_option('enable_trace_fp'))
 290 # values which have defaults which may be overridden
 291 dpdk_conf.set('RTE_MAX_VFIO_GROUPS', 64)
 292 dpdk_conf.set('RTE_DRIVER_MEMPOOL_BUCKET_SIZE_KB', 64)
 293 dpdk_conf.set('RTE_LIBRTE_DPAA2_USE_PHYS_IOVA', true)
 294 if dpdk_conf.get('RTE_ARCH_64')
 295     dpdk_conf.set('RTE_MAX_MEM_MB', 524288)
 296 else # for 32-bit we need smaller reserved memory areas
 297     dpdk_conf.set('RTE_MAX_MEM_MB', 2048)
 298 endif
 299
 300
 301 compile_time_cpuflags = []
 302 subdir(arch_subdir)
 303 dpdk_conf.set('RTE_COMPILE_TIME_CPUFLAGS', ','.join(compile_time_cpuflags))
 304
 305 # apply cross-specific options
 306 if meson.is_cross_build()
 307     # configure RTE_MAX_LCORE and RTE_MAX_NUMA_NODES from cross file
 308     cross_max_lcores = meson.get_cross_property('max_lcores', 0)
 309     if cross_max_lcores != 0
 310         message('Setting RTE_MAX_LCORE from cross file')
 311         dpdk_conf.set('RTE_MAX_LCORE', cross_max_lcores)
 312     endif
 313     cross_max_numa_nodes = meson.get_cross_property('max_numa_nodes', 0)
 314     if cross_max_numa_nodes != 0
 315         message('Setting RTE_MAX_NUMA_NODES from cross file')
 316         dpdk_conf.set('RTE_MAX_NUMA_NODES', cross_max_numa_nodes)
 317     endif
 318 endif
 319
 320 # set the install path for the drivers
 321 dpdk_conf.set_quoted('RTE_EAL_PMD_PATH', eal_pmd_path)
 322
 323 install_headers(['rte_config.h'],
 324         subdir: get_option('include_subdir_arch'))
 325
 326 # enable VFIO only if it is linux OS
 327 dpdk_conf.set('RTE_EAL_VFIO', is_linux)
 328
 329 # specify -D_GNU_SOURCE unconditionally
 330 add_project_arguments('-D_GNU_SOURCE', language: 'c')
 331
 332 # specify -D__BSD_VISIBLE for FreeBSD
 333 if is_freebsd
 334     add_project_arguments('-D__BSD_VISIBLE', language: 'c')
 335 endif
 336
 337 if is_windows
 338     # VirtualAlloc2() is available since Windows 10 / Server 2016.
 339     add_project_arguments('-D_WIN32_WINNT=0x0A00', language: 'c')
 340
 341     # Use MinGW-w64 stdio, because DPDK assumes ANSI-compliant formatting.
 342     if cc.get_id() == 'gcc'
 343         add_project_arguments('-D__USE_MINGW_ANSI_STDIO', language: 'c')
 344     endif
 345
 346     # Disable secure CRT deprecated warnings for clang
 347     if cc.get_id() == 'clang'
 348         add_project_arguments('-D_CRT_SECURE_NO_WARNINGS', language: 'c')
 349     endif
 350
 351     add_project_link_arguments('-lws2_32', language: 'c')
 352
 353     # Contrary to docs, VirtualAlloc2() is exported by mincore.lib
 354     # in Windows SDK, while MinGW exports it by advapi32.a.
 355     if is_ms_linker
 356         add_project_link_arguments('-lmincore', language: 'c')
 357     endif
 358
 359     add_project_link_arguments('-ladvapi32', '-lsetupapi', language: 'c')
 360     add_project_link_arguments('-ldbghelp', language: 'c')
 361 endif
 362
 363 if get_option('b_lto')
 364     if cc.has_argument('-ffat-lto-objects')
 365         add_project_arguments('-ffat-lto-objects', language: 'c')
 366     else
 367         error('compiler does not support fat LTO objects - please turn LTO off')
 368     endif
 369     # workaround for gcc bug 81440
 370     if cc.get_id() == 'gcc' and cc.version().version_compare('<8.0')
 371         add_project_arguments('-Wno-lto-type-mismatch', language: 'c')
 372         add_project_link_arguments('-Wno-lto-type-mismatch', language: 'c')
 373     endif
 374 endif
 375
 376 if get_option('default_library') == 'both'
 377     error( '''
 378  Unsupported value "both" for "default_library" option.
 379
 380  NOTE: DPDK always builds both shared and static libraries.  Please set
 381  "default_library" to either "static" or "shared" to select default linkage
 382  for apps and any examples.''')
 383 endif