config/x86/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2020 Intel Corporation
   3
   4 # get binutils version for the workaround of Bug 97
   5 binutils_ok = true
   6 if is_linux or cc.get_id() == 'gcc'
   7     binutils_ok = run_command(binutils_avx512_check, check: false).returncode() == 0
   8     if not binutils_ok and cc.has_argument('-mno-avx512f')
   9         machine_args += '-mno-avx512f'
  10         warning('Binutils error with AVX512 assembly, disabling AVX512 support')
  11     endif
  12 endif
  13
  14 # check if compiler is working with _mm512_extracti64x4_epi64
  15 # Ref: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=82887
  16 if cc.has_argument('-mavx512f')
  17     code = '''#include <immintrin.h>
  18     void test(__m512i zmm){
  19         __m256i ymm = _mm512_extracti64x4_epi64(zmm, 0);}'''
  20     result = cc.compiles(code, args : '-mavx512f', name : 'AVX512 checking')
  21     if result == false
  22         machine_args += '-mno-avx512f'
  23         warning('Broken _mm512_extracti64x4_epi64, disabling AVX512 support')
  24     endif
  25 endif
  26
  27 # we require SSE4.2 for DPDK
  28 if cc.get_define('__SSE4_2__', args: machine_args) == ''
  29     message('SSE 4.2 not enabled by default, explicitly enabling')
  30     machine_args += '-msse4'
  31 endif
  32
  33 base_flags = ['SSE', 'SSE2', 'SSE3','SSSE3', 'SSE4_1', 'SSE4_2']
  34 foreach f:base_flags
  35     compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  36 endforeach
  37
  38 optional_flags = [
  39         'AES',
  40         'AVX',
  41         'AVX2',
  42         'AVX512BW',
  43         'AVX512CD',
  44         'AVX512DQ',
  45         'AVX512F',
  46         'AVX512VL',
  47         'PCLMUL',
  48         'RDRND',
  49         'RDSEED',
  50         'VPCLMULQDQ',
  51 ]
  52 foreach f:optional_flags
  53     if cc.get_define('__@0@__'.format(f), args: machine_args) == '1'
  54         if f == 'PCLMUL' # special case flags with different defines
  55             f = 'PCLMULQDQ'
  56         elif f == 'RDRND'
  57             f = 'RDRAND'
  58         endif
  59         compile_time_cpuflags += ['RTE_CPUFLAG_' + f]
  60     endif
  61 endforeach
  62
  63
  64 dpdk_conf.set('RTE_ARCH_X86', 1)
  65 if dpdk_conf.get('RTE_ARCH_64')
  66     dpdk_conf.set('RTE_ARCH_X86_64', 1)
  67     dpdk_conf.set('RTE_ARCH', 'x86_64')
  68 else
  69     dpdk_conf.set('RTE_ARCH_I686', 1)
  70     dpdk_conf.set('RTE_ARCH', 'i686')
  71 endif
  72
  73 dpdk_conf.set('RTE_CACHE_LINE_SIZE', 64)
  74 dpdk_conf.set('RTE_MAX_LCORE', 128)
  75 dpdk_conf.set('RTE_MAX_NUMA_NODES', 32)