drivers/common/mlx5/linux/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2020 Mellanox Technologies, Ltd
   3
   4 includes += include_directories('.')
   5
   6 static_ibverbs = (get_option('ibverbs_link') == 'static')
   7 dlopen_ibverbs = (get_option('ibverbs_link') == 'dlopen')
   8 LIB_GLUE_BASE = 'librte_common_mlx5_glue.so'
   9 LIB_GLUE_VERSION = abi_version
  10 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  11 if dlopen_ibverbs
  12     dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  13     cflags += [
  14             '-DMLX5_GLUE="@0@"'.format(LIB_GLUE),
  15             '-DMLX5_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  16     ]
  17 endif
  18
  19 libnames = [ 'mlx5', 'ibverbs' ]
  20 libs = []
  21 foreach libname:libnames
  22     lib = dependency('lib' + libname, static:static_ibverbs, required:false, method: 'pkg-config')
  23     if not lib.found() and not static_ibverbs
  24         lib = cc.find_library(libname, required:false)
  25     endif
  26     if lib.found()
  27         libs += lib
  28         if not static_ibverbs and not dlopen_ibverbs
  29             ext_deps += lib
  30         endif
  31     else
  32         build = false
  33         reason = 'missing dependency, "' + libname + '"'
  34         subdir_done()
  35     endif
  36 endforeach
  37 if static_ibverbs or dlopen_ibverbs
  38     # Build without adding shared libs to Requires.private
  39     ibv_cflags = run_command(pkgconf, '--cflags', 'libibverbs').stdout()
  40     ext_deps += declare_dependency(compile_args: ibv_cflags.split())
  41 endif
  42 if static_ibverbs
  43     # Add static deps ldflags to internal apps and Libs.private
  44     ibv_ldflags = run_command(ldflags_ibverbs_static, check:true).stdout()
  45     ext_deps += declare_dependency(link_args:ibv_ldflags.split())
  46 endif
  47
  48 sources += files('mlx5_nl.c')
  49 sources += files('mlx5_common_auxiliary.c')
  50 sources += files('mlx5_common_os.c')
  51 sources += files('mlx5_common_verbs.c')
  52 if not dlopen_ibverbs
  53     sources += files('mlx5_glue.c')
  54 endif
  55
  56 deps += ['bus_auxiliary']
  57
  58 # To maintain the compatibility with the make build system
  59 # mlx5_autoconf.h file is still generated.
  60 # input array for meson member search:
  61 # [ "MACRO to define if found", "header for the search",
  62 #   "symbol to search", "struct member to search" ]
  63 has_member_args = [
  64         [ 'HAVE_IBV_MLX5_MOD_SWP', 'infiniband/mlx5dv.h',
  65             'struct mlx5dv_sw_parsing_caps', 'sw_parsing_offloads' ],
  66         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V42', 'infiniband/verbs.h',
  67             'struct ibv_counter_set_init_attr', 'counter_set_id' ],
  68         [ 'HAVE_IBV_DEVICE_COUNTERS_SET_V45', 'infiniband/verbs.h',
  69             'struct ibv_counters_init_attr', 'comp_mask' ],
  70         [ 'HAVE_MLX5DV_DEVX_UAR_OFFSET', 'infiniband/mlx5dv.h',
  71             'struct mlx5dv_devx_uar', 'mmap_off' ],
  72 ]
  73 # input array for meson symbol search:
  74 # [ "MACRO to define if found", "header for the search",
  75 #   "symbol to search" ]
  76 has_sym_args = [
  77         [ 'HAVE_IBV_RELAXED_ORDERING', 'infiniband/verbs.h',
  78             'IBV_ACCESS_RELAXED_ORDERING ' ],
  79         [ 'HAVE_IBV_DEVICE_STRIDING_RQ_SUPPORT', 'infiniband/mlx5dv.h',
  80             'MLX5DV_CQE_RES_FORMAT_CSUM_STRIDX' ],
  81         [ 'HAVE_IBV_DEVICE_TUNNEL_SUPPORT', 'infiniband/mlx5dv.h',
  82             'MLX5DV_CONTEXT_MASK_TUNNEL_OFFLOADS' ],
  83         [ 'HAVE_IBV_MLX5_MOD_MPW', 'infiniband/mlx5dv.h',
  84             'MLX5DV_CONTEXT_FLAGS_MPW_ALLOWED' ],
  85         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_COMP', 'infiniband/mlx5dv.h',
  86             'MLX5DV_CONTEXT_FLAGS_CQE_128B_COMP' ],
  87         [ 'HAVE_IBV_MLX5_MOD_CQE_128B_PAD', 'infiniband/mlx5dv.h',
  88             'MLX5DV_CQ_INIT_ATTR_FLAGS_CQE_PAD' ],
  89         [ 'HAVE_IBV_FLOW_DV_SUPPORT', 'infiniband/mlx5dv.h',
  90             'mlx5dv_create_flow_action_packet_reformat' ],
  91         [ 'HAVE_IBV_DEVICE_MPLS_SUPPORT', 'infiniband/verbs.h',
  92             'IBV_FLOW_SPEC_MPLS' ],
  93         [ 'HAVE_IBV_WQ_FLAGS_PCI_WRITE_END_PADDING', 'infiniband/verbs.h',
  94             'IBV_WQ_FLAGS_PCI_WRITE_END_PADDING' ],
  95         [ 'HAVE_IBV_WQ_FLAG_RX_END_PADDING', 'infiniband/verbs.h',
  96             'IBV_WQ_FLAG_RX_END_PADDING' ],
  97         [ 'HAVE_MLX5DV_DR_DEVX_PORT', 'infiniband/mlx5dv.h',
  98             'mlx5dv_query_devx_port' ],
  99         [ 'HAVE_MLX5DV_DR_DEVX_PORT_V35', 'infiniband/mlx5dv.h',
 100             'mlx5dv_query_port' ],
 101         [ 'HAVE_MLX5DV_DR_CREATE_DEST_IB_PORT', 'infiniband/mlx5dv.h',
 102             'mlx5dv_dr_action_create_dest_ib_port' ],
 103         [ 'HAVE_IBV_DEVX_OBJ', 'infiniband/mlx5dv.h',
 104             'mlx5dv_devx_obj_create' ],
 105         [ 'HAVE_IBV_FLOW_DEVX_COUNTERS', 'infiniband/mlx5dv.h',
 106             'MLX5DV_FLOW_ACTION_COUNTERS_DEVX' ],
 107         [ 'HAVE_MLX5_DR_CREATE_ACTION_DEFAULT_MISS', 'infiniband/mlx5dv.h',
 108             'MLX5DV_FLOW_ACTION_DEFAULT_MISS' ],
 109         [ 'HAVE_IBV_DEVX_ASYNC', 'infiniband/mlx5dv.h',
 110             'mlx5dv_devx_obj_query_async' ],
 111         [ 'HAVE_IBV_DEVX_QP', 'infiniband/mlx5dv.h',
 112             'mlx5dv_devx_qp_query' ],
 113         [ 'HAVE_MLX5DV_PP_ALLOC', 'infiniband/mlx5dv.h',
 114             'mlx5dv_pp_alloc' ],
 115         [ 'HAVE_MLX5DV_DR_ACTION_DEST_DEVX_TIR', 'infiniband/mlx5dv.h',
 116             'mlx5dv_dr_action_create_dest_devx_tir' ],
 117         [ 'HAVE_IBV_DEVX_EVENT', 'infiniband/mlx5dv.h',
 118             'mlx5dv_devx_get_event' ],
 119         [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_METER', 'infiniband/mlx5dv.h',
 120             'mlx5dv_dr_action_create_flow_meter' ],
 121         [ 'HAVE_MLX5DV_MMAP_GET_NC_PAGES_CMD', 'infiniband/mlx5dv.h',
 122             'MLX5_MMAP_GET_NC_PAGES_CMD' ],
 123         [ 'HAVE_MLX5DV_DR', 'infiniband/mlx5dv.h',
 124             'MLX5DV_DR_DOMAIN_TYPE_NIC_RX' ],
 125         [ 'HAVE_MLX5DV_DR_ESWITCH', 'infiniband/mlx5dv.h',
 126             'MLX5DV_DR_DOMAIN_TYPE_FDB' ],
 127         [ 'HAVE_MLX5DV_DR_VLAN', 'infiniband/mlx5dv.h',
 128             'mlx5dv_dr_action_create_push_vlan' ],
 129         [ 'HAVE_IBV_VAR', 'infiniband/mlx5dv.h', 'mlx5dv_alloc_var' ],
 130         [ 'HAVE_MLX5_OPCODE_ENHANCED_MPSW', 'infiniband/mlx5dv.h',
 131             'MLX5_OPCODE_ENHANCED_MPSW' ],
 132         [ 'HAVE_MLX5_OPCODE_SEND_EN', 'infiniband/mlx5dv.h',
 133             'MLX5_OPCODE_SEND_EN' ],
 134         [ 'HAVE_MLX5_OPCODE_WAIT', 'infiniband/mlx5dv.h',
 135             'MLX5_OPCODE_WAIT' ],
 136         [ 'HAVE_MLX5_OPCODE_ACCESS_ASO', 'infiniband/mlx5dv.h',
 137             'MLX5_OPCODE_ACCESS_ASO' ],
 138         [ 'HAVE_SUPPORTED_40000baseKR4_Full', 'linux/ethtool.h',
 139             'SUPPORTED_40000baseKR4_Full' ],
 140         [ 'HAVE_SUPPORTED_40000baseCR4_Full', 'linux/ethtool.h',
 141             'SUPPORTED_40000baseCR4_Full' ],
 142         [ 'HAVE_SUPPORTED_40000baseSR4_Full', 'linux/ethtool.h',
 143             'SUPPORTED_40000baseSR4_Full' ],
 144         [ 'HAVE_SUPPORTED_40000baseLR4_Full', 'linux/ethtool.h',
 145             'SUPPORTED_40000baseLR4_Full' ],
 146         [ 'HAVE_SUPPORTED_56000baseKR4_Full', 'linux/ethtool.h',
 147             'SUPPORTED_56000baseKR4_Full' ],
 148         [ 'HAVE_SUPPORTED_56000baseCR4_Full', 'linux/ethtool.h',
 149             'SUPPORTED_56000baseCR4_Full' ],
 150         [ 'HAVE_SUPPORTED_56000baseSR4_Full', 'linux/ethtool.h',
 151             'SUPPORTED_56000baseSR4_Full' ],
 152         [ 'HAVE_SUPPORTED_56000baseLR4_Full', 'linux/ethtool.h',
 153             'SUPPORTED_56000baseLR4_Full' ],
 154         [ 'HAVE_ETHTOOL_LINK_MODE_25G', 'linux/ethtool.h',
 155             'ETHTOOL_LINK_MODE_25000baseCR_Full_BIT' ],
 156         [ 'HAVE_ETHTOOL_LINK_MODE_50G', 'linux/ethtool.h',
 157             'ETHTOOL_LINK_MODE_50000baseCR2_Full_BIT' ],
 158         [ 'HAVE_ETHTOOL_LINK_MODE_100G', 'linux/ethtool.h',
 159             'ETHTOOL_LINK_MODE_100000baseKR4_Full_BIT' ],
 160         [ 'HAVE_IFLA_NUM_VF', 'linux/if_link.h',
 161             'IFLA_NUM_VF' ],
 162         [ 'HAVE_IFLA_EXT_MASK', 'linux/if_link.h',
 163             'IFLA_EXT_MASK' ],
 164         [ 'HAVE_IFLA_PHYS_SWITCH_ID', 'linux/if_link.h',
 165             'IFLA_PHYS_SWITCH_ID' ],
 166         [ 'HAVE_IFLA_PHYS_PORT_NAME', 'linux/if_link.h',
 167             'IFLA_PHYS_PORT_NAME' ],
 168         [ 'HAVE_RDMA_NL_NLDEV', 'rdma/rdma_netlink.h',
 169             'RDMA_NL_NLDEV' ],
 170         [ 'HAVE_RDMA_NLDEV_CMD_GET', 'rdma/rdma_netlink.h',
 171             'RDMA_NLDEV_CMD_GET' ],
 172         [ 'HAVE_RDMA_NLDEV_CMD_PORT_GET', 'rdma/rdma_netlink.h',
 173             'RDMA_NLDEV_CMD_PORT_GET' ],
 174         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_INDEX', 'rdma/rdma_netlink.h',
 175             'RDMA_NLDEV_ATTR_DEV_INDEX' ],
 176         [ 'HAVE_RDMA_NLDEV_ATTR_DEV_NAME', 'rdma/rdma_netlink.h',
 177             'RDMA_NLDEV_ATTR_DEV_NAME' ],
 178         [ 'HAVE_RDMA_NLDEV_ATTR_PORT_INDEX', 'rdma/rdma_netlink.h',
 179             'RDMA_NLDEV_ATTR_PORT_INDEX' ],
 180         [ 'HAVE_RDMA_NLDEV_ATTR_NDEV_INDEX', 'rdma/rdma_netlink.h',
 181             'RDMA_NLDEV_ATTR_NDEV_INDEX' ],
 182         [ 'HAVE_MLX5_DR_FLOW_DUMP', 'infiniband/mlx5dv.h',
 183             'mlx5dv_dump_dr_domain'],
 184         [ 'HAVE_MLX5_DR_CREATE_ACTION_FLOW_SAMPLE', 'infiniband/mlx5dv.h',
 185             'mlx5dv_dr_action_create_flow_sampler'],
 186         [ 'HAVE_MLX5DV_DR_MEM_RECLAIM', 'infiniband/mlx5dv.h',
 187             'mlx5dv_dr_domain_set_reclaim_device_memory'],
 188         [ 'HAVE_MLX5_DR_CREATE_ACTION_DEST_ARRAY', 'infiniband/mlx5dv.h',
 189             'mlx5dv_dr_action_create_dest_array'],
 190         [ 'HAVE_DEVLINK', 'linux/devlink.h', 'DEVLINK_GENL_NAME' ],
 191         [ 'HAVE_MLX5_DR_CREATE_ACTION_ASO', 'infiniband/mlx5dv.h',
 192             'mlx5dv_dr_action_create_aso' ],
 193         [ 'HAVE_INFINIBAND_VERBS_H', 'infiniband/verbs.h',
 194             'INFINIBAND_VERBS_H' ],
 195         [ 'HAVE_MLX5_UMR_IMKEY', 'infiniband/mlx5dv.h',
 196             'MLX5_WQE_UMR_CTRL_FLAG_INLINE' ],
 197         [ 'HAVE_MLX5_DR_FLOW_DUMP_RULE', 'infiniband/mlx5dv.h',
 198             'mlx5dv_dump_dr_rule' ],
 199         [ 'HAVE_MLX5_DR_ACTION_ASO_CT', 'infiniband/mlx5dv.h',
 200             'MLX5DV_DR_ACTION_FLAGS_ASO_CT_DIRECTION_INITIATOR' ],
 201         [ 'HAVE_MLX5_DR_ALLOW_DUPLICATE', 'infiniband/mlx5dv.h',
 202             'mlx5dv_dr_domain_allow_duplicate_rules' ],
 203 ]
 204 config = configuration_data()
 205 foreach arg:has_sym_args
 206     config.set(arg[0], cc.has_header_symbol(arg[1], arg[2], dependencies: libs))
 207 endforeach
 208 foreach arg:has_member_args
 209     file_prefix = '#include <' + arg[1] + '>'
 210     config.set(arg[0], cc.has_member(arg[2], arg[3], prefix : file_prefix, dependencies: libs))
 211 endforeach
 212 configure_file(output : 'mlx5_autoconf.h', configuration : config)
 213
 214 # Build Glue Library
 215 if dlopen_ibverbs
 216     dlopen_name = 'mlx5_glue'
 217     dlopen_lib_name = 'rte_common_' + dlopen_name
 218     dlopen_so_version = LIB_GLUE_VERSION
 219     dlopen_sources = files('mlx5_glue.c')
 220     dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 221     dlopen_includes = [global_inc]
 222     dlopen_includes += include_directories('../../../../lib/eal/include/generic')
 223     shared_lib = shared_library(
 224             dlopen_lib_name,
 225             dlopen_sources,
 226             include_directories: dlopen_includes,
 227             c_args: cflags,
 228             dependencies: libs,
 229             link_args: [
 230                 '-Wl,-export-dynamic',
 231                 '-Wl,-h,@0@'.format(LIB_GLUE),
 232             ],
 233             soversion: dlopen_so_version,
 234             install: true,
 235             install_dir: dlopen_install_dir,
 236     )
 237 endif