drivers/net/i40e/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 cflags += ['-DPF_DRIVER',
   5         '-DVF_DRIVER',
   6         '-DINTEGRATED_VF',
   7         '-DX722_A0_SUPPORT']
   8
   9 subdir('base')
  10 objs = [base_objs]
  11
  12 sources = files(
  13         'i40e_ethdev.c',
  14         'i40e_rxtx.c',
  15         'i40e_ethdev_vf.c',
  16         'i40e_pf.c',
  17         'i40e_fdir.c',
  18         'i40e_flow.c',
  19         'i40e_tm.c',
  20         'i40e_hash.c',
  21         'i40e_vf_representor.c',
  22         'rte_pmd_i40e.c'
  23         )
  24
  25 deps += ['hash']
  26 includes += include_directories('base')
  27
  28 if arch_subdir == 'x86'
  29         dpdk_conf.set('RTE_LIBRTE_I40E_INC_VECTOR', 1)
  30         sources += files('i40e_rxtx_vec_sse.c')
  31
  32         # compile AVX2 version if either:
  33         # a. we have AVX supported in minimum instruction set baseline
  34         # b. it's not minimum instruction set, but supported by compiler
  35         if cc.get_define('__AVX2__', args: machine_args) != ''
  36                 cflags += ['-DCC_AVX2_SUPPORT']
  37                 sources += files('i40e_rxtx_vec_avx2.c')
  38         elif cc.has_argument('-mavx2')
  39                 cflags += ['-DCC_AVX2_SUPPORT']
  40                 i40e_avx2_lib = static_library('i40e_avx2_lib',
  41                                 'i40e_rxtx_vec_avx2.c',
  42                                 dependencies: [static_rte_ethdev,
  43                                         static_rte_kvargs, static_rte_hash],
  44                                 include_directories: includes,
  45                                 c_args: [cflags, '-mavx2'])
  46                 objs += i40e_avx2_lib.extract_objects('i40e_rxtx_vec_avx2.c')
  47         endif
  48 elif arch_subdir == 'ppc'
  49        dpdk_conf.set('RTE_LIBRTE_I40E_INC_VECTOR', 1)
  50        sources += files('i40e_rxtx_vec_altivec.c')
  51 elif arch_subdir == 'arm'
  52        dpdk_conf.set('RTE_LIBRTE_I40E_INC_VECTOR', 1)
  53        sources += files('i40e_rxtx_vec_neon.c')
  54 endif
  55
  56 headers = files('rte_pmd_i40e.h')