drivers/net/i40e/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4 cflags += ['-DPF_DRIVER',
   5         '-DVF_DRIVER',
   6         '-DINTEGRATED_VF',
   7         '-DX722_A0_SUPPORT']
   8
   9 subdir('base')
  10 objs = [base_objs]
  11
  12 sources = files(
  13         'i40e_ethdev.c',
  14         'i40e_rxtx.c',
  15         'i40e_ethdev_vf.c',
  16         'i40e_pf.c',
  17         'i40e_fdir.c',
  18         'i40e_flow.c',
  19         'i40e_tm.c',
  20         'i40e_hash.c',
  21         'i40e_vf_representor.c',
  22         'rte_pmd_i40e.c'
  23         )
  24
  25 deps += ['hash']
  26 includes += include_directories('base')
  27
  28 if arch_subdir == 'x86'
  29         sources += files('i40e_rxtx_vec_sse.c')
  30
  31         # compile AVX2 version if either:
  32         # a. we have AVX supported in minimum instruction set baseline
  33         # b. it's not minimum instruction set, but supported by compiler
  34         if cc.get_define('__AVX2__', args: machine_args) != ''
  35                 cflags += ['-DCC_AVX2_SUPPORT']
  36                 sources += files('i40e_rxtx_vec_avx2.c')
  37         elif cc.has_argument('-mavx2')
  38                 cflags += ['-DCC_AVX2_SUPPORT']
  39                 i40e_avx2_lib = static_library('i40e_avx2_lib',
  40                                 'i40e_rxtx_vec_avx2.c',
  41                                 dependencies: [static_rte_ethdev,
  42                                         static_rte_kvargs, static_rte_hash],
  43                                 include_directories: includes,
  44                                 c_args: [cflags, '-mavx2'])
  45                 objs += i40e_avx2_lib.extract_objects('i40e_rxtx_vec_avx2.c')
  46         endif
  47
  48         i40e_avx512_cpu_support = (
  49                 cc.get_define('__AVX512F__', args: machine_args) != '' and
  50                 cc.get_define('__AVX512BW__', args: machine_args) != '')
  51
  52         i40e_avx512_cc_support = (
  53                 not machine_args.contains('-mno-avx512f') and
  54                 cc.has_argument('-mavx512f') and
  55                 cc.has_argument('-mavx512bw'))
  56
  57         if is_windows and cc.get_id() != 'clang'
  58                 i40e_avx512_cc_support = false
  59         endif
  60
  61         if i40e_avx512_cpu_support == true or i40e_avx512_cc_support == true
  62                 cflags += ['-DCC_AVX512_SUPPORT']
  63                 avx512_args = [cflags, '-mavx512f', '-mavx512bw']
  64                 if cc.has_argument('-march=skylake-avx512')
  65                         avx512_args += '-march=skylake-avx512'
  66                 endif
  67                 i40e_avx512_lib = static_library('i40e_avx512_lib',
  68                                 'i40e_rxtx_vec_avx512.c',
  69                                 dependencies: [static_rte_ethdev,
  70                                         static_rte_kvargs, static_rte_hash],
  71                                 include_directories: includes,
  72                                 c_args: avx512_args)
  73                 objs += i40e_avx512_lib.extract_objects('i40e_rxtx_vec_avx512.c')
  74         endif
  75 elif arch_subdir == 'ppc'
  76        sources += files('i40e_rxtx_vec_altivec.c')
  77 elif arch_subdir == 'arm'
  78        sources += files('i40e_rxtx_vec_neon.c')
  79 endif
  80
  81 headers = files('rte_pmd_i40e.h')