drivers/net/iavf/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2018 Luca Boccassi <bluca@debian.org>
   3
   4 if is_windows
   5         build = false
   6         reason = 'not supported on Windows'
   7         subdir_done()
   8 endif
   9
  10 cflags += ['-Wno-strict-aliasing']
  11
  12 includes += include_directories('../../common/iavf')
  13 deps += ['common_iavf']
  14
  15 sources = files(
  16         'iavf_ethdev.c',
  17         'iavf_rxtx.c',
  18         'iavf_vchnl.c',
  19         'iavf_generic_flow.c',
  20         'iavf_fdir.c',
  21         'iavf_hash.c',
  22 )
  23
  24 if arch_subdir == 'x86'
  25         sources += files('iavf_rxtx_vec_sse.c')
  26
  27         # compile AVX2 version if either:
  28         # a. we have AVX supported in minimum instruction set baseline
  29         # b. it's not minimum instruction set, but supported by compiler
  30         if cc.get_define('__AVX2__', args: machine_args) != ''
  31                 cflags += ['-DCC_AVX2_SUPPORT']
  32                 sources += files('iavf_rxtx_vec_avx2.c')
  33         elif cc.has_argument('-mavx2')
  34                 cflags += ['-DCC_AVX2_SUPPORT']
  35                 iavf_avx2_lib = static_library('iavf_avx2_lib',
  36                                 'iavf_rxtx_vec_avx2.c',
  37                                 dependencies: [static_rte_ethdev,
  38                                         static_rte_kvargs, static_rte_hash],
  39                                 include_directories: includes,
  40                                 c_args: [cflags, '-mavx2'])
  41                 objs += iavf_avx2_lib.extract_objects('iavf_rxtx_vec_avx2.c')
  42         endif
  43
  44         iavf_avx512_cpu_support = (
  45                 cc.get_define('__AVX512F__', args: machine_args) != '' and
  46                 cc.get_define('__AVX512BW__', args: machine_args) != '')
  47
  48         iavf_avx512_cc_support = (
  49                 not machine_args.contains('-mno-avx512f') and
  50                 cc.has_argument('-mavx512f') and
  51                 cc.has_argument('-mavx512bw'))
  52
  53         if iavf_avx512_cpu_support == true or iavf_avx512_cc_support == true
  54                 cflags += ['-DCC_AVX512_SUPPORT']
  55                 avx512_args = [cflags, '-mavx512f', '-mavx512bw']
  56                 if cc.has_argument('-march=skylake-avx512')
  57                         avx512_args += '-march=skylake-avx512'
  58                 endif
  59                 iavf_avx512_lib = static_library('iavf_avx512_lib',
  60                                 'iavf_rxtx_vec_avx512.c',
  61                                 dependencies: [static_rte_ethdev,
  62                                         static_rte_kvargs, static_rte_hash],
  63                                 include_directories: includes,
  64                                 c_args: avx512_args)
  65                 objs += iavf_avx512_lib.extract_objects('iavf_rxtx_vec_avx512.c')
  66         endif
  67 endif
  68
  69 headers = files('rte_pmd_iavf.h')