drivers/net/mlx4/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright 2018 6WIND S.A.
   3 # Copyright 2018 Mellanox Technologies, Ltd
   4
   5 if not is_linux
   6         build = false
   7         reason = 'only supported on Linux'
   8         subdir_done()
   9 endif
  10
  11 static_ibverbs = (get_option('ibverbs_link') == 'static')
  12 pmd_dlopen = (get_option('ibverbs_link') == 'dlopen')
  13 LIB_GLUE_BASE = 'librte_pmd_mlx4_glue.so'
  14 LIB_GLUE_VERSION = '18.02.0'
  15 LIB_GLUE = LIB_GLUE_BASE + '.' + LIB_GLUE_VERSION
  16 if pmd_dlopen
  17         dpdk_conf.set('RTE_IBVERBS_LINK_DLOPEN', 1)
  18         cflags += [
  19                 '-DMLX4_GLUE="@0@"'.format(LIB_GLUE),
  20                 '-DMLX4_GLUE_VERSION="@0@"'.format(LIB_GLUE_VERSION),
  21         ]
  22 endif
  23
  24 libnames = [ 'mlx4', 'ibverbs' ]
  25 libs = []
  26 foreach libname:libnames
  27         lib = dependency('lib' + libname, static:static_ibverbs, required:false)
  28         if not lib.found() and not static_ibverbs
  29                 lib = cc.find_library(libname, required:false)
  30         endif
  31         if lib.found()
  32                 libs += lib
  33                 if not static_ibverbs
  34                         ext_deps += lib
  35                 endif
  36         else
  37                 build = false
  38                 reason = 'missing dependency, "' + libname + '"'
  39                 subdir_done()
  40         endif
  41 endforeach
  42 if static_ibverbs
  43         # Build without adding shared libs to Requires.private
  44         ibv_cflags = run_command(pkgconf, '--cflags', 'libibverbs').stdout()
  45         ext_deps += declare_dependency(compile_args: ibv_cflags.split())
  46         # Add static deps ldflags to internal apps and Libs.private
  47         ibv_ldflags = run_command(ldflags_ibverbs_static, check:true).stdout()
  48         ext_deps += declare_dependency(link_args:ibv_ldflags.split())
  49 endif
  50
  51 allow_experimental_apis = true
  52 sources = files(
  53         'mlx4.c',
  54         'mlx4_ethdev.c',
  55         'mlx4_flow.c',
  56         'mlx4_intr.c',
  57         'mlx4_mp.c',
  58         'mlx4_mr.c',
  59         'mlx4_rxq.c',
  60         'mlx4_rxtx.c',
  61         'mlx4_txq.c',
  62         'mlx4_utils.c',
  63 )
  64 if not pmd_dlopen
  65         sources += files('mlx4_glue.c')
  66 endif
  67 cflags_options = [
  68         '-std=c11',
  69         '-Wno-strict-prototypes',
  70         '-D_BSD_SOURCE',
  71         '-D_DEFAULT_SOURCE',
  72         '-D_XOPEN_SOURCE=600'
  73 ]
  74 foreach option:cflags_options
  75         if cc.has_argument(option)
  76                 cflags += option
  77         endif
  78 endforeach
  79 if get_option('buildtype').contains('debug')
  80         cflags += [ '-pedantic', '-DPEDANTIC' ]
  81 else
  82         cflags += [ '-UPEDANTIC' ]
  83 endif
  84 # To maintain the compatibility with the make build system
  85 # mlx4_autoconf.h file is still generated.
  86 # input array for meson member search:
  87 # [ "MACRO to define if found", "header for the search",
  88 #   "symbol to search", "struct member to search" ]
  89 #
  90 has_member_args = [
  91         [ 'HAVE_IBV_MLX4_WQE_LSO_SEG', 'infiniband/mlx4dv.h',
  92         'struct mlx4_wqe_lso_seg', 'mss_hdr_size' ],
  93 ]
  94 # input array for meson symbol search:
  95 # [ "MACRO to define if found", "header for the search",
  96 #   "symbol to search" ]
  97 has_sym_args = [
  98         [ 'HAVE_IBV_MLX4_BUF_ALLOCATORS', 'infiniband/mlx4dv.h',
  99         'MLX4DV_SET_CTX_ATTR_BUF_ALLOCATORS' ],
 100         [ 'HAVE_IBV_MLX4_UAR_MMAP_OFFSET', 'infiniband/mlx4dv.h',
 101         'MLX4DV_QP_MASK_UAR_MMAP_OFFSET' ],
 102 ]
 103 config = configuration_data()
 104 foreach arg:has_sym_args
 105         config.set(arg[0], cc.has_header_symbol(arg[1], arg[2],
 106                 dependencies: libs))
 107 endforeach
 108 foreach arg:has_member_args
 109         file_prefix = '#include <' + arg[1] + '>'
 110         config.set(arg[0], cc.has_member(arg[2], arg[3],
 111                 prefix: file_prefix, dependencies: libs))
 112 endforeach
 113 configure_file(output : 'mlx4_autoconf.h', configuration : config)
 114
 115 # Build Glue Library
 116 if pmd_dlopen
 117         dlopen_name = 'mlx4_glue'
 118         dlopen_lib_name = driver_name_fmt.format(dlopen_name)
 119         dlopen_so_version = LIB_GLUE_VERSION
 120         dlopen_sources = files('mlx4_glue.c')
 121         dlopen_install_dir = [ eal_pmd_path + '-glue' ]
 122         shared_lib = shared_library(
 123                 dlopen_lib_name,
 124                 dlopen_sources,
 125                 include_directories: global_inc,
 126                 c_args: cflags,
 127                 dependencies: libs,
 128                 link_args: [
 129                 '-Wl,-export-dynamic',
 130                 '-Wl,-h,@0@'.format(LIB_GLUE),
 131                 ],
 132                 soversion: dlopen_so_version,
 133                 install: true,
 134                 install_dir: dlopen_install_dir,
 135         )
 136 endif