examples/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4 driver_libs = []
   5 if get_option('default_library') == 'static'
   6         driver_libs = dpdk_drivers
   7 endif
   8
   9 execinfo = cc.find_library('execinfo', required: false)
  10
  11 # list of all example apps. Keep 1-3 per line, in alphabetical order.
  12 all_examples = [
  13         'bbdev_app', 'bond',
  14         'cmdline',
  15         'distributor', 'ethtool',
  16         'eventdev_pipeline',
  17         'fips_validation', 'flow_classify',
  18         'flow_filtering', 'helloworld',
  19         'ip_fragmentation', 'ip_pipeline',
  20         'ip_reassembly', 'ipsec-secgw',
  21         'ipv4_multicast', 'kni',
  22         'l2fwd', 'l2fwd-cat',
  23         'l2fwd-crypto', 'l2fwd-jobstats',
  24         'l2fwd-keepalive', 'l3fwd',
  25         'l3fwd-acl', 'l3fwd-power',
  26         'link_status_interrupt',
  27         'multi_process/client_server_mp/mp_client',
  28         'multi_process/client_server_mp/mp_server',
  29         'multi_process/hotplug_mp',
  30         'multi_process/simple_mp',
  31         'multi_process/symmetric_mp',
  32         'ntb', 'packet_ordering',
  33         'performance-thread/l3fwd-thread',
  34         'performance-thread/pthread_shim',
  35         'ptpclient',
  36         'qos_meter', 'qos_sched',
  37         'rxtx_callbacks',
  38         'server_node_efd/node',
  39         'service_cores',
  40         'skeleton', 'tep_termination',
  41         'timer', 'vdpa',
  42         'vhost', 'vhost_crypto',
  43         'vm_power_manager',
  44         'vmdq', 'vmdq_dcb',
  45 ]
  46 # install all example code on install - irrespective of whether the example in
  47 # question is to be built as part of this build or not.
  48 foreach ex:all_examples
  49         install_subdir(ex,
  50                         install_dir: get_option('datadir') + '/dpdk/examples',
  51                         exclude_files: 'meson.build')
  52 endforeach
  53
  54 if get_option('examples') == ''
  55         subdir_done()
  56 endif
  57
  58 if get_option('examples').to_lower() == 'all'
  59         examples = all_examples
  60         allow_skips = true # don't flag an error if we can't build an app
  61 else
  62         examples = get_option('examples').split(',')
  63         allow_skips = false # error out if we can't build a requested app
  64 endif
  65 default_cflags = machine_args
  66 if cc.has_argument('-Wno-format-truncation')
  67         default_cflags += '-Wno-format-truncation'
  68 endif
  69
  70 foreach example: examples
  71         name = example.split('/')[-1]
  72         build = true
  73         sources = []
  74         allow_experimental_apis = false
  75         cflags = default_cflags
  76
  77         ext_deps = [execinfo]
  78         includes = [include_directories(example)]
  79         deps = ['eal', 'mempool', 'net', 'mbuf', 'ethdev', 'cmdline']
  80         if is_windows
  81                 deps = ['eal'] # only supported lib on Windows currently
  82         endif
  83         subdir(example)
  84
  85         if build
  86                 dep_objs = ext_deps
  87                 foreach d:deps
  88                         var_name = get_option('default_library') + '_rte_' + d
  89                         if not is_variable(var_name)
  90                                 error('Missing dependency "@0@" for example "@1@"'.format(d, name))
  91                         endif
  92                         dep_objs += [get_variable(var_name)]
  93                 endforeach
  94                 if allow_experimental_apis
  95                         cflags += '-DALLOW_EXPERIMENTAL_API'
  96                 endif
  97                 executable('dpdk-' + name, sources,
  98                         include_directories: includes,
  99                         link_whole: driver_libs,
 100                         link_args: dpdk_extra_ldflags,
 101                         c_args: cflags,
 102                         dependencies: dep_objs)
 103         elif not allow_skips
 104                 error('Cannot build requested example "' + name + '"')
 105         else
 106                 message('Skipping example "' + name + '"')
 107         endif
 108 endforeach