lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool',
  18         'mbuf',
  19         'net',
  20         'meter',
  21         'ethdev',
  22         'pci', # core
  23         'cmdline',
  24         'metrics', # bitrate/latency stats depends on this
  25         'hash',    # efd depends on this
  26         'timer',   # eventdev depends on this
  27         'acl',
  28         'bbdev',
  29         'bitratestats',
  30         'cfgfile',
  31         'compressdev',
  32         'cryptodev',
  33         'distributor',
  34         'efd',
  35         'eventdev',
  36         'gro',
  37         'gso',
  38         'ip_frag',
  39         'jobstats',
  40         'kni',
  41         'latencystats',
  42         'lpm',
  43         'member',
  44         'power',
  45         'pdump',
  46         'rawdev',
  47         'regexdev',
  48         'rib',
  49         'reorder',
  50         'sched',
  51         'security',
  52         'stack',
  53         'vhost',
  54         'ipsec', # ipsec lib depends on net, crypto and security
  55         'fib', #fib lib depends on rib
  56         'port', # pkt framework libs which use other libs from above
  57         'table',
  58         'pipeline',
  59         'flow_classify', # flow_classify lib depends on pkt framework table lib
  60         'bpf',
  61         'graph',
  62         'node',
  63 ]
  64
  65 if is_windows
  66     libraries = [
  67             'kvargs',
  68             'telemetry',
  69             'eal',
  70             'ring',
  71             'rcu',
  72             'mempool',
  73             'mbuf',
  74             'net',
  75             'meter',
  76             'ethdev',
  77             'pci',
  78             'cmdline',
  79             'hash',
  80             'cfgfile',
  81     ] # only supported libraries for windows
  82 endif
  83
  84 optional_libs = [
  85         'kni',
  86         'power',
  87         'vhost',
  88 ]
  89
  90 disabled_libs = []
  91 opt_disabled_libs = run_command(list_dir_globs, get_option('disable_libs'),
  92         check: true).stdout().split()
  93 foreach l:opt_disabled_libs
  94     if not optional_libs.contains(l)
  95         warning('Cannot disable mandatory library "@0@"'.format(l))
  96         continue
  97     endif
  98     disabled_libs += l
  99 endforeach
 100
 101
 102 default_cflags = machine_args
 103 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
 104 default_cflags += ['-DALLOW_INTERNAL_API']
 105
 106 if cc.has_argument('-Wno-format-truncation')
 107     default_cflags += '-Wno-format-truncation'
 108 endif
 109
 110 enabled_libs = [] # used to print summary at the end
 111
 112 foreach l:libraries
 113     build = true
 114     reason = '<unknown reason>' # set if build == false to explain why
 115     name = l
 116     use_function_versioning = false
 117     sources = []
 118     headers = []
 119     indirect_headers = [] # public headers not directly included by apps
 120     driver_sdk_headers = [] # public headers included by drivers
 121     includes = []
 122     cflags = default_cflags
 123     objs = [] # other object files to link against, used e.g. for
 124               # instruction-set optimized versions of code
 125
 126     # use "deps" for internal DPDK dependencies, and "ext_deps" for
 127     # external package/library requirements
 128     ext_deps = []
 129     deps = []
 130     # eal is standard dependency once built
 131     if dpdk_conf.has('RTE_LIB_EAL')
 132         deps += ['eal']
 133     endif
 134
 135     if disabled_libs.contains(l)
 136         build = false
 137         reason = 'explicitly disabled via build config'
 138     else
 139         subdir(l)
 140     endif
 141     if name != l
 142         warning('Library name, "@0@", and directory name, "@1@", do not match'.format(name, l))
 143     endif
 144
 145     if not build
 146         dpdk_libs_disabled += name
 147         set_variable(name.underscorify() + '_disable_reason', reason)
 148         continue
 149     endif
 150
 151     shared_deps = ext_deps
 152     static_deps = ext_deps
 153     foreach d:deps
 154         if not is_variable('shared_rte_' + d)
 155             error('Missing internal dependency "@0@" for @1@ [@2@]'
 156                     .format(d, name, 'lib/' + l))
 157         endif
 158         shared_deps += [get_variable('shared_rte_' + d)]
 159         static_deps += [get_variable('static_rte_' + d)]
 160     endforeach
 161
 162     enabled_libs += name
 163     dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1)
 164     install_headers(headers)
 165     install_headers(indirect_headers)
 166     if get_option('enable_driver_sdk')
 167         install_headers(driver_sdk_headers)
 168     endif
 169     dpdk_chkinc_headers += headers
 170
 171     libname = 'rte_' + name
 172     includes += include_directories(l)
 173
 174     if developer_mode and is_windows and use_function_versioning
 175         message('@0@: Function versioning is not supported by Windows.'.format(name))
 176     endif
 177
 178     if use_function_versioning
 179         cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 180     endif
 181     cflags += '-DRTE_LOG_DEFAULT_LOGTYPE=lib.' + l
 182
 183     # first build static lib
 184     static_lib = static_library(libname,
 185             sources,
 186             objects: objs,
 187             c_args: cflags,
 188             dependencies: static_deps,
 189             include_directories: includes,
 190             install: true)
 191     static_dep = declare_dependency(
 192             include_directories: includes,
 193             dependencies: static_deps)
 194
 195     if not use_function_versioning or is_windows
 196         # use pre-build objects to build shared lib
 197         sources = []
 198         objs += static_lib.extract_all_objects(recursive: false)
 199     else
 200         # for compat we need to rebuild with
 201         # RTE_BUILD_SHARED_LIB defined
 202         cflags += '-DRTE_BUILD_SHARED_LIB'
 203     endif
 204     version_map = '@0@/@1@/version.map'.format(
 205             meson.current_source_dir(), l)
 206     implib = 'librte_' + l + '.dll.a'
 207
 208     def_file = custom_target(libname + '_def',
 209             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 210             input: version_map,
 211             output: '@0@_exports.def'.format(libname))
 212
 213     mingw_map = custom_target(libname + '_mingw',
 214             command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 215             input: version_map,
 216             output: '@0@_mingw.map'.format(libname))
 217
 218     if is_ms_linker
 219         lk_args = ['-Wl,/def:' + def_file.full_path()]
 220         if meson.version().version_compare('<0.54.0')
 221             lk_args += ['-Wl,/implib:lib\\' + implib]
 222         endif
 223     else
 224         if is_windows
 225             lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 226         else
 227             lk_args = ['-Wl,--version-script=' + version_map]
 228         endif
 229     endif
 230
 231     lk_deps = [version_map, def_file, mingw_map]
 232     if developer_mode and not is_windows
 233         # on unix systems check the output of the
 234         # check-symbols.sh script, using it as a
 235         # dependency of the .so build
 236         lk_deps += custom_target(name + '.sym_chk',
 237                 command: [check_symbols,
 238                     version_map, '@INPUT@'],
 239                 capture: true,
 240                 input: static_lib,
 241                 output: name + '.sym_chk')
 242     endif
 243
 244     shared_lib = shared_library(libname,
 245             sources,
 246             objects: objs,
 247             c_args: cflags,
 248             dependencies: shared_deps,
 249             include_directories: includes,
 250             link_args: lk_args,
 251             link_depends: lk_deps,
 252             version: abi_version,
 253             soversion: so_version,
 254             install: true)
 255     shared_dep = declare_dependency(link_with: shared_lib,
 256             include_directories: includes,
 257             dependencies: shared_deps)
 258
 259     dpdk_libraries = [shared_lib] + dpdk_libraries
 260     dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 261
 262     set_variable('shared_rte_' + name, shared_dep)
 263     set_variable('static_rte_' + name, static_dep)
 264     if developer_mode
 265         message('lib/@0@: Defining dependency "@1@"'.format(l, name))
 266     endif
 267 endforeach