lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017-2019 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [
  12         'kvargs', # eal depends on kvargs
  13         'telemetry', # basic info querying
  14         'eal', # everything depends on eal
  15         'ring',
  16         'rcu', # rcu depends on ring
  17         'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci', # core
  18         'cmdline',
  19         'metrics', # bitrate/latency stats depends on this
  20         'hash',    # efd depends on this
  21         'timer',   # eventdev depends on this
  22         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  23         'compressdev', 'cryptodev',
  24         'distributor', 'efd', 'eventdev',
  25         'gro', 'gso', 'ip_frag', 'jobstats',
  26         'kni', 'latencystats', 'lpm', 'member',
  27         'power', 'pdump', 'rawdev', 'regexdev',
  28         'rib', 'reorder', 'sched', 'security', 'stack', 'vhost',
  29         # ipsec lib depends on net, crypto and security
  30         'ipsec',
  31         #fib lib depends on rib
  32         'fib',
  33         # add pkt framework libs which use other libs from above
  34         'port', 'table', 'pipeline',
  35         # flow_classify lib depends on pkt framework table lib
  36         'flow_classify', 'bpf', 'graph', 'node']
  37
  38 if is_windows
  39         libraries = [
  40                 'kvargs',
  41                 'telemetry',
  42                 'eal',
  43                 'ring',
  44                 'rcu',
  45                 'mempool', 'mbuf', 'net', 'meter', 'ethdev', 'pci',
  46                 'cmdline',
  47                 'hash',
  48                 'cfgfile',
  49         ] # only supported libraries for windows
  50 endif
  51
  52 default_cflags = machine_args
  53 default_cflags += ['-DALLOW_EXPERIMENTAL_API']
  54 default_cflags += ['-DALLOW_INTERNAL_API']
  55
  56 if cc.has_argument('-Wno-format-truncation')
  57         default_cflags += '-Wno-format-truncation'
  58 endif
  59
  60 enabled_libs = [] # used to print summary at the end
  61
  62 foreach l:libraries
  63         build = true
  64         reason = '<unknown reason>' # set if build == false to explain why
  65         name = l
  66         use_function_versioning = false
  67         sources = []
  68         headers = []
  69         indirect_headers = [] # public headers not directly included by apps
  70         includes = []
  71         cflags = default_cflags
  72         objs = [] # other object files to link against, used e.g. for
  73                   # instruction-set optimized versions of code
  74
  75         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  76         # external package/library requirements
  77         ext_deps = []
  78         deps = []
  79         # eal is standard dependency once built
  80         if dpdk_conf.has('RTE_LIB_EAL')
  81                 deps += ['eal']
  82         endif
  83
  84         dir_name = 'librte_' + l
  85         subdir(dir_name)
  86
  87         if build
  88                 shared_deps = ext_deps
  89                 static_deps = ext_deps
  90                 foreach d:deps
  91                         if not is_variable('shared_rte_' + d)
  92                                 error('Missing internal dependency "@0@" for @1@ [@2@]'
  93                                                 .format(d, name, 'lib/' + dir_name))
  94                         endif
  95                         shared_deps += [get_variable('shared_rte_' + d)]
  96                         static_deps += [get_variable('static_rte_' + d)]
  97                 endforeach
  98         endif
  99
 100         if not build
 101                 dpdk_libs_disabled += name
 102                 set_variable(name.underscorify() + '_disable_reason', reason)
 103         else
 104                 enabled_libs += name
 105                 dpdk_conf.set('RTE_LIB_' + name.to_upper(), 1)
 106                 install_headers(headers)
 107                 install_headers(indirect_headers)
 108                 dpdk_chkinc_headers += headers
 109
 110                 libname = 'rte_' + name
 111                 includes += include_directories(dir_name)
 112
 113                 if sources.length() == 0
 114                         # if no C files, just set a dependency on header path
 115                         shared_dep = declare_dependency(include_directories: includes)
 116                         static_dep = shared_dep
 117                 else
 118                         if is_windows and use_function_versioning
 119                                 message('@0@: Function versioning is not supported by Windows.'
 120                                 .format(name))
 121                         endif
 122
 123                         if use_function_versioning
 124                                 cflags += '-DRTE_USE_FUNCTION_VERSIONING'
 125                         endif
 126
 127                         # first build static lib
 128                         static_lib = static_library(libname,
 129                                         sources,
 130                                         objects: objs,
 131                                         c_args: cflags,
 132                                         dependencies: static_deps,
 133                                         include_directories: includes,
 134                                         install: true)
 135                         static_dep = declare_dependency(
 136                                         include_directories: includes,
 137                                         dependencies: static_deps)
 138
 139                         if not use_function_versioning or is_windows
 140                                 # use pre-build objects to build shared lib
 141                                 sources = []
 142                                 objs += static_lib.extract_all_objects(recursive: false)
 143                         else
 144                                 # for compat we need to rebuild with
 145                                 # RTE_BUILD_SHARED_LIB defined
 146                                 cflags += '-DRTE_BUILD_SHARED_LIB'
 147                         endif
 148                         version_map = '@0@/@1@/version.map'.format(
 149                                         meson.current_source_dir(), dir_name)
 150                         implib = dir_name + '.dll.a'
 151
 152                         def_file = custom_target(libname + '_def',
 153                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 154                                 input: version_map,
 155                                 output: '@0@_exports.def'.format(libname))
 156
 157                         mingw_map = custom_target(libname + '_mingw',
 158                                 command: [map_to_win_cmd, '@INPUT@', '@OUTPUT@'],
 159                                 input: version_map,
 160                                 output: '@0@_mingw.map'.format(libname))
 161
 162                         if is_ms_linker
 163                                 lk_args = ['-Wl,/def:' + def_file.full_path()]
 164                                 if meson.version().version_compare('<0.54.0')
 165                                         lk_args += ['-Wl,/implib:lib\\' + implib]
 166                                 endif
 167                         else
 168                                 if is_windows
 169                                         lk_args = ['-Wl,--version-script=' + mingw_map.full_path()]
 170                                 else
 171                                         lk_args = ['-Wl,--version-script=' + version_map]
 172                                 endif
 173                         endif
 174
 175                         lk_deps = [version_map, def_file, mingw_map]
 176                         if not is_windows
 177                                 # on unix systems check the output of the
 178                                 # check-symbols.sh script, using it as a
 179                                 # dependency of the .so build
 180                                 lk_deps += custom_target(name + '.sym_chk',
 181                                         command: [check_symbols,
 182                                                 version_map, '@INPUT@'],
 183                                         capture: true,
 184                                         input: static_lib,
 185                                         output: name + '.sym_chk')
 186                         endif
 187
 188                         shared_lib = shared_library(libname,
 189                                         sources,
 190                                         objects: objs,
 191                                         c_args: cflags,
 192                                         dependencies: shared_deps,
 193                                         include_directories: includes,
 194                                         link_args: lk_args,
 195                                         link_depends: lk_deps,
 196                                         version: abi_version,
 197                                         soversion: so_version,
 198                                         install: true)
 199                         shared_dep = declare_dependency(link_with: shared_lib,
 200                                         include_directories: includes,
 201                                         dependencies: shared_deps)
 202
 203                         dpdk_libraries = [shared_lib] + dpdk_libraries
 204                         dpdk_static_libraries = [static_lib] + dpdk_static_libraries
 205                 endif # sources.length() > 0
 206
 207                 set_variable('shared_rte_' + name, shared_dep)
 208                 set_variable('static_rte_' + name, static_dep)
 209                 message('lib/@0@: Defining dependency "@1@"'.format(
 210                                 dir_name, name))
 211         endif # if build
 212 endforeach