lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [ 'compat', # just a header, used for versioning
  12         'kvargs',
  13         'eal', 'ring', 'mempool', 'mbuf', 'net', 'ethdev', 'pci', # core
  14         'metrics', # bitrate/latency stats depends on this
  15         'hash',    # efd depends on this
  16         'timer',   # eventdev depends on this
  17         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  18         'cmdline', 'compressdev', 'cryptodev',
  19         'distributor', 'efd', 'eventdev',
  20         'gro', 'gso', 'ip_frag', 'jobstats',
  21         'kni', 'latencystats', 'lpm', 'member',
  22         'meter', 'power', 'pdump', 'rawdev',
  23         'reorder', 'sched', 'security', 'vhost',
  24         # add pkt framework libs which use other libs from above
  25         'port', 'table', 'pipeline',
  26         # flow_classify lib depends on pkt framework table lib
  27         'flow_classify', 'bpf']
  28
  29 foreach l:libraries
  30         build = true
  31         name = l
  32         version = 1
  33         allow_experimental_apis = false
  34         sources = []
  35         headers = []
  36         includes = []
  37         cflags = machine_args
  38         if cc.has_argument('-Wno-format-truncation')
  39             cflags += '-Wno-format-truncation'
  40         endif
  41
  42         objs = [] # other object files to link against, used e.g. for
  43                   # instruction-set optimized versions of code
  44
  45         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  46         # external package/library requirements
  47         ext_deps = []
  48         deps = ['eal']   # eal is standard dependency except for itself
  49         if l == 'kvargs'
  50                 deps = []
  51         endif
  52         if l == 'eal'
  53                 deps = ['kvargs']
  54         endif
  55
  56         dir_name = 'librte_' + l
  57         subdir(dir_name)
  58
  59         if build
  60                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1)
  61                 install_headers(headers)
  62
  63                 libname = 'rte_' + name
  64                 includes += include_directories(dir_name)
  65
  66                 if sources.length() == 0
  67                         # if no C files, just set a dependency on header path
  68                         shared_dep = declare_dependency(include_directories: includes)
  69                         static_dep = shared_dep
  70                 else
  71                         shared_deps = ext_deps
  72                         static_deps = ext_deps
  73                         foreach d:deps
  74                                 shared_deps += [get_variable('shared_rte_' + d)]
  75                                 static_deps += [get_variable('static_rte_' + d)]
  76                         endforeach
  77
  78                         if allow_experimental_apis
  79                                 cflags += '-DALLOW_EXPERIMENTAL_API'
  80                         endif
  81
  82                         if get_option('per_library_versions')
  83                                 lib_version = '@0@.1'.format(version)
  84                                 so_version = '@0@'.format(version)
  85                         else
  86                                 prj_ver = meson.project_version().split('.')
  87                                 lib_version = '@0@.@1@'.format(
  88                                                 prj_ver.get(0), prj_ver.get(1))
  89                                 so_version = lib_version
  90                         endif
  91
  92                         # first build static lib
  93                         static_lib = static_library(libname,
  94                                         sources,
  95                                         objects: objs,
  96                                         c_args: cflags,
  97                                         dependencies: static_deps,
  98                                         include_directories: includes,
  99                                         install: true)
 100                         static_dep = declare_dependency(link_with: static_lib,
 101                                         include_directories: includes,
 102                                         dependencies: static_deps)
 103
 104                         # then use pre-build objects to build shared lib
 105                         sources = []
 106                         objs += static_lib.extract_all_objects(recursive: false)
 107                         version_map = '@0@/@1@/rte_@2@_version.map'.format(
 108                                         meson.current_source_dir(), dir_name, name)
 109                         shared_lib = shared_library(libname,
 110                                         sources,
 111                                         objects: objs,
 112                                         c_args: cflags,
 113                                         dependencies: shared_deps,
 114                                         include_directories: includes,
 115                                         link_args: '-Wl,--version-script=' + version_map,
 116                                         link_depends: version_map,
 117                                         version: lib_version,
 118                                         soversion: so_version,
 119                                         install: true)
 120                         shared_dep = declare_dependency(link_with: shared_lib,
 121                                         include_directories: includes,
 122                                         dependencies: shared_deps)
 123
 124                         dpdk_libraries = [shared_lib] + dpdk_libraries
 125                 endif # sources.length() > 0
 126
 127                 set_variable('shared_' + libname, shared_dep)
 128                 set_variable('static_' + libname, static_dep)
 129         endif # if build
 130 endforeach