lib/meson.build

   1 # SPDX-License-Identifier: BSD-3-Clause
   2 # Copyright(c) 2017 Intel Corporation
   3
   4
   5 # process all libraries equally, as far as possible
   6 # "core" libs first, then others alphebetically as far as possible
   7 # NOTE: for speed of meson runs, the dependencies in the subdirectories
   8 # sometimes skip deps that would be implied by others, e.g. if mempool is
   9 # given as a dep, no need to mention ring. This is especially true for the
  10 # core libs which are widely reused, so their deps are kept to a minimum.
  11 libraries = [ 'compat', # just a header, used for versioning
  12         'kvargs',
  13         'eal', 'ring', 'mempool', 'mbuf', 'net', 'ethdev', 'pci', # core
  14         'metrics', # bitrate/latency stats depends on this
  15         'hash',    # efd depends on this
  16         'timer',   # eventdev depends on this
  17         'acl', 'bbdev', 'bitratestats', 'cfgfile',
  18         'cmdline', 'compressdev', 'cryptodev',
  19         'distributor', 'efd', 'eventdev',
  20         'gro', 'gso', 'ip_frag', 'jobstats',
  21         'kni', 'latencystats', 'lpm', 'member',
  22         'meter', 'power', 'pdump', 'rawdev',
  23         'reorder', 'sched', 'security', 'vhost',
  24         # add pkt framework libs which use other libs from above
  25         'port', 'table', 'pipeline',
  26         # flow_classify lib depends on pkt framework table lib
  27         'flow_classify', 'bpf']
  28
  29 default_cflags = machine_args
  30 if cc.has_argument('-Wno-format-truncation')
  31         default_cflags += '-Wno-format-truncation'
  32 endif
  33 foreach l:libraries
  34         build = true
  35         name = l
  36         version = 1
  37         allow_experimental_apis = false
  38         sources = []
  39         headers = []
  40         includes = []
  41         cflags = default_cflags
  42         objs = [] # other object files to link against, used e.g. for
  43                   # instruction-set optimized versions of code
  44
  45         # use "deps" for internal DPDK dependencies, and "ext_deps" for
  46         # external package/library requirements
  47         ext_deps = []
  48         deps = []
  49         # eal is standard dependency once built
  50         if dpdk_conf.has('RTE_LIBRTE_EAL')
  51                 deps += ['eal']
  52         endif
  53
  54         dir_name = 'librte_' + l
  55         subdir(dir_name)
  56
  57         if build
  58                 dpdk_conf.set('RTE_LIBRTE_' + name.to_upper(), 1)
  59                 install_headers(headers)
  60
  61                 libname = 'rte_' + name
  62                 includes += include_directories(dir_name)
  63
  64                 if sources.length() == 0
  65                         # if no C files, just set a dependency on header path
  66                         shared_dep = declare_dependency(include_directories: includes)
  67                         static_dep = shared_dep
  68                 else
  69                         shared_deps = ext_deps
  70                         static_deps = ext_deps
  71                         foreach d:deps
  72                                 if not is_variable('shared_rte_' + d)
  73                                         error('Missing dependency ' + d +
  74                                                 ' for library ' + lib_name)
  75                                 endif
  76                                 shared_deps += [get_variable('shared_rte_' + d)]
  77                                 static_deps += [get_variable('static_rte_' + d)]
  78                         endforeach
  79
  80                         if allow_experimental_apis
  81                                 cflags += '-DALLOW_EXPERIMENTAL_API'
  82                         endif
  83
  84                         if get_option('per_library_versions')
  85                                 lib_version = '@0@.1'.format(version)
  86                                 so_version = '@0@'.format(version)
  87                         else
  88                                 prj_ver = meson.project_version().split('.')
  89                                 lib_version = '@0@.@1@'.format(
  90                                                 prj_ver.get(0), prj_ver.get(1))
  91                                 so_version = lib_version
  92                         endif
  93
  94                         # first build static lib
  95                         static_lib = static_library(libname,
  96                                         sources,
  97                                         objects: objs,
  98                                         c_args: cflags,
  99                                         dependencies: static_deps,
 100                                         include_directories: includes,
 101                                         install: true)
 102                         static_dep = declare_dependency(link_with: static_lib,
 103                                         include_directories: includes,
 104                                         dependencies: static_deps)
 105
 106                         # then use pre-build objects to build shared lib
 107                         sources = []
 108                         objs += static_lib.extract_all_objects(recursive: false)
 109                         version_map = '@0@/@1@/rte_@2@_version.map'.format(
 110                                         meson.current_source_dir(), dir_name, name)
 111                         shared_lib = shared_library(libname,
 112                                         sources,
 113                                         objects: objs,
 114                                         c_args: cflags,
 115                                         dependencies: shared_deps,
 116                                         include_directories: includes,
 117                                         link_args: '-Wl,--version-script=' + version_map,
 118                                         link_depends: version_map,
 119                                         version: lib_version,
 120                                         soversion: so_version,
 121                                         install: true)
 122                         shared_dep = declare_dependency(link_with: shared_lib,
 123                                         include_directories: includes,
 124                                         dependencies: shared_deps)
 125
 126                         dpdk_libraries = [shared_lib] + dpdk_libraries
 127                 endif # sources.length() > 0
 128
 129                 set_variable('shared_' + libname, shared_dep)
 130                 set_variable('static_' + libname, static_dep)
 131         endif # if build
 132 endforeach